gentoo resync : 05.12.2021

1 files changed, 51 insertions, 0 deletions

diff --git a/dev-ruby/rspec-mocks/rspec-mocks-2.99.2-r1.ebuild b/dev-ruby/rspec-mocks/rspec-mocks-2.99.2-r1.ebuild
new file mode 100644
index 000000000000..0a09d4cde658
--- /dev/null
+++ b/dev-ruby/rspec-mocks/rspec-mocks-2.99.2-r1.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+USE_RUBY="ruby26 ruby27"
+
+RUBY_FAKEGEM_RECIPE_TEST="rspec"
+
+RUBY_FAKEGEM_RECIPE_DOC="none"
+RUBY_FAKEGEM_EXTRADOC="Changelog.md README.md"
+
+RUBY_FAKEGEM_GEMSPEC="rspec-mocks.gemspec"
+
+inherit ruby-fakegem
+
+DESCRIPTION="A Behaviour Driven Development (BDD) framework for Ruby"
+HOMEPAGE="http://rspec.rubyforge.org/"
+SRC_URI="https://github.com/rspec/${PN}/archive/v${PV}.tar.gz -> ${P}-git.tgz"
+
+LICENSE="MIT"
+SLOT="2"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE=""
+
+ruby_add_bdepend "
+	test? (
+		>=dev-ruby/rspec-core-2.10.0:2
+		>=dev-ruby/rspec-expectations-2.99.0:2
+	)"
+
+all_ruby_prepare() {
+	# Don't set up bundler: it doesn't understand our setup.
+	sed -i -e '/[Bb]undler/d' Rakefile || die
+
+	# Remove the Gemfile to avoid running through 'bundle exec'
+	rm Gemfile || die
+
+	# Remove .rspec options to avoid dependency on newer rspec when
+	# bootstrapping.
+	rm .rspec || die
+
+	# Avoid a weird, and failing, test testing already installed code.
+	sed -e '/has an up-to-date caller_filter file/,/end/ s:^:#:' -i spec/rspec/mocks_spec.rb || die
+
+	# Psych and Syck are not supported by default anymore on ruby22.
+	rm spec/rspec/mocks/serialization_spec.rb || die
+
+	sed -i -e '/does not affect the ability to access the top-level constant/,/end/ s:^:#:' spec/rspec/mocks/mutate_const_spec.rb || die
+
+	sed -i -e 's/git ls-files --/find/' ${RUBY_FAKEGEM_GEMSPEC} || die
+}