reinit the tree, so we can have metadata

1 files changed, 38 insertions, 0 deletions

diff --git a/dev-ruby/nio4r/nio4r-2.0.0.ebuild b/dev-ruby/nio4r/nio4r-2.0.0.ebuild
new file mode 100644
index 000000000000..baab5d7a4789
--- /dev/null
+++ b/dev-ruby/nio4r/nio4r-2.0.0.ebuild
@@ -0,0 +1,38 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=5
+
+USE_RUBY="ruby22 ruby23"
+
+RUBY_FAKEGEM_RECIPE_TEST="rspec3"
+
+RUBY_FAKEGEM_TASK_DOC=""
+RUBY_FAKEGEM_EXTRADOC="CHANGES.md README.md"
+
+inherit ruby-fakegem
+
+DESCRIPTION="A high performance selector API for monitoring IO objects"
+HOMEPAGE="https://github.com/celluloid/nio4r"
+
+LICENSE="MIT"
+SLOT="2"
+KEYWORDS="~amd64 ~arm ~ppc64 ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE=""
+
+# Note that nio4r bundles a patched copy of libev, and without these
+# patches the tests fail: https://github.com/celluloid/nio4r/issues/15
+
+all_ruby_prepare() {
+	sed -i -e '/[Cc]overalls/d' -e '/[Bb]undler/d' spec/spec_helper.rb || die
+	sed -e '/extension/ s:^:#:' -i Rakefile || die
+}
+
+each_ruby_configure() {
+	${RUBY} -Cext/${PN} extconf.rb || die
+}
+
+each_ruby_compile() {
+	emake V=1 -Cext/${PN}
+	cp ext/${PN}/*$(get_modname) lib/ || die
+}