gentoo auto-resync : 07:11:2022 - 09:21:27

1 files changed, 49 insertions, 0 deletions

diff --git a/dev-python/zope-i18nmessageid/zope-i18nmessageid-5.1.0.ebuild b/dev-python/zope-i18nmessageid/zope-i18nmessageid-5.1.0.ebuild
new file mode 100644
index 000000000000..9f8fe11f4a63
--- /dev/null
+++ b/dev-python/zope-i18nmessageid/zope-i18nmessageid-5.1.0.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..11} pypy3 )
+
+inherit distutils-r1
+
+MY_P=${P/-/.}
+DESCRIPTION="Zope support for i18nmessageid (tagging source of i18n strings)"
+HOMEPAGE="
+	https://pypi.org/project/zope.i18nmessageid/
+	https://github.com/zopefoundation/zope.i18nmessageid/
+"
+SRC_URI="
+	https://github.com/zopefoundation/zope.i18nmessageid/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="ZPL"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86"
+
+RDEPEND="
+	dev-python/six[${PYTHON_USEDEP}]
+	!dev-python/namespace-zope
+"
+
+distutils_enable_tests unittest
+
+src_prepare() {
+	# strip rdep specific to namespaces
+	sed -i -e "s:'setuptools',::" setup.py || die
+	distutils-r1_src_prepare
+}
+
+python_compile() {
+	distutils-r1_python_compile
+	find "${BUILD_DIR}" -name '*.pth' -delete || die
+}
+
+python_test() {
+	cd "${BUILD_DIR}/install$(python_get_sitedir)" || die
+	distutils_write_namespace zope
+	eunittest
+}