gentoo resync : 15.01.2020

1 files changed, 43 insertions, 0 deletions

diff --git a/dev-python/zipp/zipp-1.0.0.ebuild b/dev-python/zipp/zipp-1.0.0.ebuild
new file mode 100644
index 000000000000..5f9bd554565e
--- /dev/null
+++ b/dev-python/zipp/zipp-1.0.0.ebuild
@@ -0,0 +1,43 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( pypy3 python{2_7,3_{6,7,8}} )
+
+inherit distutils-r1
+
+DESCRIPTION="Backport of pathlib-compatible object wrapper for zip files"
+HOMEPAGE="https://github.com/jaraco/zipp"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha amd64 arm arm64 hppa ia64 ~mips ppc ppc64 s390 sparc x86"
+IUSE="test"
+
+RDEPEND="dev-python/more-itertools[${PYTHON_USEDEP}]"
+BDEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	test? (
+		${RDEPEND}
+		$(python_gen_cond_dep '
+			dev-python/contextlib2[${PYTHON_USEDEP}]
+			dev-python/pathlib2[${PYTHON_USEDEP}]
+			dev-python/unittest2[${PYTHON_USEDEP}]
+		' pypy{,3} python{2_7,3_{5,6,7}})
+	)
+"
+
+distutils_enable_sphinx docs \
+	">=dev-python/jaraco-packaging-3.2" \
+	">=dev-python/rst-linker-1.9"
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	sed -i "s:use_scm_version=True:version='${PV}',name='${PN//-/.}':" setup.py || die
+	sed -r -i "s:setuptools_scm[[:space:]]*([><=]{1,2}[[:space:]]*[0-9.a-zA-Z]+|)[[:space:]]*::" \
+		setup.cfg || die
+	distutils-r1_python_prepare_all
+}