gentoo resync : 02.02.2022

1 files changed, 33 insertions, 0 deletions

diff --git a/dev-python/url-normalize/url-normalize-1.4.3-r1.ebuild b/dev-python/url-normalize/url-normalize-1.4.3-r1.ebuild
new file mode 100644
index 000000000000..8ede2a4e84e6
--- /dev/null
+++ b/dev-python/url-normalize/url-normalize-1.4.3-r1.ebuild
@@ -0,0 +1,33 @@
+# Copyright 2021-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=poetry
+PYTHON_COMPAT=( python3_{8..10} )
+inherit distutils-r1
+
+DESCRIPTION="URL normalization for Python"
+HOMEPAGE="
+	https://github.com/niksite/url-normalize/
+	https://pypi.org/project/url-normalize/"
+SRC_URI="
+	https://github.com/niksite/url-normalize/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="dev-python/six[${PYTHON_USEDEP}]"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	# remove problematic pytest options
+	rm tox.ini || die
+	sed -e '/requires/s:poetry:&-core:' \
+		-e '/backend/s:poetry:&.core:' \
+		-i pyproject.toml || die
+	distutils-r1_src_prepare
+}