gentoo auto-resync : 13:05:2023 - 11:51:15

1 files changed, 45 insertions, 0 deletions

diff --git a/dev-python/typeguard/typeguard-4.0.0.ebuild b/dev-python/typeguard/typeguard-4.0.0.ebuild
new file mode 100644
index 000000000000..beefb022add6
--- /dev/null
+++ b/dev-python/typeguard/typeguard-4.0.0.ebuild
@@ -0,0 +1,45 @@
+# Copyright 2021-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{9..11} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Run-time type checker for Python"
+HOMEPAGE="
+	https://pypi.org/project/typeguard/
+	https://github.com/agronholm/typeguard/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	$(python_gen_cond_dep '
+		>=dev-python/importlib-metadata-3.6[${PYTHON_USEDEP}]
+	' 3.9)
+	$(python_gen_cond_dep '
+		>=dev-python/typing-extensions-4.4.0[${PYTHON_USEDEP}]
+	' 3.{9..10})
+"
+BDEPEND="
+	>=dev-python/setuptools-scm-6.4[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	local EPYTEST_IGNORE=(
+		# mypy changes results from version to version
+		tests/mypy
+	)
+
+	local -x PYTHONDONTWRITEBYTECODE=
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	# the XFAIL test pass due to some package being installed
+	epytest -o xfail_strict=False
+}