gentoo resync : 25.03.2022

1 files changed, 46 insertions, 0 deletions

diff --git a/dev-python/tqdm/tqdm-4.63.1.ebuild b/dev-python/tqdm/tqdm-4.63.1.ebuild
new file mode 100644
index 000000000000..e8dbfbed9a0d
--- /dev/null
+++ b/dev-python/tqdm/tqdm-4.63.1.ebuild
@@ -0,0 +1,46 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( pypy3 python3_{8..10} )
+
+inherit bash-completion-r1 distutils-r1
+
+DESCRIPTION="Add a progress meter to your loops in a second"
+HOMEPAGE="
+	https://github.com/tqdm/tqdm/
+	https://pypi.org/project/tqdm/
+"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-macos"
+IUSE="examples"
+
+BDEPEND="
+	dev-python/setuptools_scm[${PYTHON_USEDEP}]
+	test? (
+		dev-python/pytest-asyncio[${PYTHON_USEDEP}]
+		dev-python/pytest-timeout[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+EPYTEST_IGNORE=(
+	# Skip unpredictable performance tests
+	tests/tests_perf.py
+)
+
+python_install_all() {
+	doman tqdm/tqdm.1
+	newbashcomp tqdm/completion.sh tqdm
+	if use examples; then
+		dodoc -r examples
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+	distutils-r1_python_install_all
+}