gentoo auto-resync : 12:02:2023 - 09:56:54

1 files changed, 58 insertions, 0 deletions

diff --git a/dev-python/textX/textX-3.1.1.ebuild b/dev-python/textX/textX-3.1.1.ebuild
new file mode 100644
index 000000000000..2ef355c35dfd
--- /dev/null
+++ b/dev-python/textX/textX-3.1.1.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{9..11} )
+
+inherit distutils-r1
+
+DESCRIPTION="Meta-language for DSL implementation inspired by Xtext"
+HOMEPAGE="
+	https://pypi.org/project/textX/
+	https://github.com/textX/textX/
+"
+SRC_URI="
+	https://github.com/textX/textX/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	>=dev-python/Arpeggio-2.0.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/click[${PYTHON_USEDEP}]
+		dev-python/html5lib[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	cp -a "${BUILD_DIR}"/{install,test} || die
+	local -x PATH=${BUILD_DIR}/test/usr/bin:${PATH}
+
+	# Update the shebang
+	sed -e "s:install/usr/bin/${EPYTHON}:test/usr/bin/${EPYTHON}:" \
+		-i "${BUILD_DIR}"/test/usr/bin/textx || die
+
+	# Install necessary plugins
+	local plugins=(
+		tests/functional/subcommands/example_project
+		tests/functional/registration/projects/*
+	)
+	local p
+	for p in "${plugins[@]}"; do
+		pushd "${p}" >/dev/null || die
+		distutils_pep517_install "${BUILD_DIR}"/test
+		popd >/dev/null || die
+	done
+
+	epytest tests/functional
+}