gentoo auto-resync : 11:06:2024 - 00:08:04

1 files changed, 46 insertions, 0 deletions

diff --git a/dev-python/testtools/testtools-2.7.2.ebuild b/dev-python/testtools/testtools-2.7.2.ebuild
new file mode 100644
index 000000000000..ff9231e8d803
--- /dev/null
+++ b/dev-python/testtools/testtools-2.7.2.ebuild
@@ -0,0 +1,46 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{10..13} pypy3 )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Extensions to the Python standard library unit testing framework"
+HOMEPAGE="
+	https://github.com/testing-cabal/testtools/
+	https://pypi.org/project/testtools/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~x64-macos"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+BDEPEND="
+	dev-python/hatch-vcs[${PYTHON_USEDEP}]
+	test? (
+		>=dev-python/fixtures-2.0.0[${PYTHON_USEDEP}]
+		dev-python/testscenarios[${PYTHON_USEDEP}]
+		dev-python/testresources[${PYTHON_USEDEP}]
+		$(python_gen_cond_dep '
+			dev-python/twisted[${PYTHON_USEDEP}]
+		' 3.{10..12})
+	)
+"
+
+distutils_enable_sphinx doc
+
+python_test() {
+	cp testtools/tests/__init__.py test_suite.py || die
+	if ! has_version "dev-python/twisted[${PYTHON_USEDEP}]"; then
+		sed -i -e '/twistedsupport/d' test_suite.py || die
+	fi
+
+	"${EPYTHON}" -m testtools.run test_suite.test_suite ||
+		die "tests failed under ${EPYTHON}"
+}