reinit the tree, so we can have metadata

1 files changed, 51 insertions, 0 deletions

diff --git a/dev-python/spectral-cube/spectral-cube-0.4.0.ebuild b/dev-python/spectral-cube/spectral-cube-0.4.0.ebuild
new file mode 100644
index 000000000000..a3c130ebbf28
--- /dev/null
+++ b/dev-python/spectral-cube/spectral-cube-0.4.0.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python{2_7,3_4,3_5} )
+inherit distutils-r1
+
+DESCRIPTION="Manipulate astronomical data cubes with Python"
+HOMEPAGE="https://spectral-cube.readthedocs.org/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+
+LICENSE="BSD"
+SLOT="0"
+IUSE="doc test"
+
+RDEPEND="dev-python/astropy[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}
+	dev-python/astropy-helpers[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+	test? ( dev-python/pytest[${PYTHON_USEDEP}] )"
+
+PATCHES=( "${FILESDIR}"/${P}-looseversion.patch )
+
+python_prepare_all() {
+	sed -i -e '/auto_use/s/True/False/' setup.cfg || die
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	if use doc; then
+		python_setup
+		PYTHONPATH="${BUILD_DIR}"/lib \
+				  esetup.py build_sphinx --no-intersphinx
+	fi
+}
+
+python_test() {
+	pushd spectral_cube/tests/data > /dev/null
+	"${PYTHON}" make_test_cubes.py
+	popd > /dev/null
+	esetup.py test
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( docs/_build/html/ )
+	distutils-r1_python_install_all
+}