gentoo resync : 25.11.2020

1 files changed, 42 insertions, 0 deletions

diff --git a/dev-python/rope/rope-0.18.0.ebuild b/dev-python/rope/rope-0.18.0.ebuild
new file mode 100644
index 000000000000..212968e98367
--- /dev/null
+++ b/dev-python/rope/rope-0.18.0.ebuild
@@ -0,0 +1,42 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+# Not yet ready for py3.9: https://github.com/python-rope/rope/issues/299
+PYTHON_COMPAT=( python3_{7,8} )
+
+inherit distutils-r1
+
+DESCRIPTION="Python refactoring library"
+HOMEPAGE="https://github.com/python-rope/rope"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="LGPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86 ~amd64-linux ~x86-linux"
+
+IUSE="doc"
+
+# Dependency for docbuild documentation which is not noted in
+# setup.py, using standard docutils builds docs successfully.
+DEPEND="doc? ( dev-python/docutils[${PYTHON_USEDEP}] )"
+
+distutils_enable_tests pytest
+
+python_compile_all() {
+	if use doc; then
+		pushd docs > /dev/null || die
+		mkdir build || die
+		local i
+		for i in ./*.rst; do
+			rst2html.py $i > ./build/${i/rst/html} || die
+		done
+		popd > /dev/null || die
+	fi
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( docs/build/. )
+	distutils-r1_python_install_all
+}