gentoo auto-resync : 01:06:2024 - 00:07:06

4 files changed, 125 insertions, 4 deletions

diff --git a/dev-python/qiskit-aer/Manifest b/dev-python/qiskit-aer/Manifest
index 80ff2887e415..33b0dad65d98 100644
--- a/dev-python/qiskit-aer/Manifest
+++ b/dev-python/qiskit-aer/Manifest
@@ -1,6 +1,8 @@
 AUX qiskit-aer-0.12.0-remove-cmake-dependency.patch 504 BLAKE2B 3b64e7cc3e8b3144fc6983e1c5e99cb25197a555d76a79f4d3f32afca017d43c82c96ce4cdd9fe847eb95b3a0ded1fe9efa7569e23ce0032495c1aaedc460c7c SHA512 927715515b98e617648afa869aef56a5d86607c3ef829b7fd01bc7e9df0a626827f576d0ca7579a7d75415a3d82cadbefbb697b363a584c8c2e549306057c5c6
 DIST qiskit-aer-0.12.2.gh.tar.gz 6979559 BLAKE2B c7f12c9b8f53a9031844e123b8ef6d723e0099be028c5cfba03143fb8b3c7269768ade99d3ef3b4b82c0b36756bf8e82971a3f70c0f5735891eb77a78a6d9512 SHA512 2a9ed6777e5e4d60a393d5a1b21b44ea3fa90fb791aeafda8bbb4ca8b55c7e8161cd5a275fd14bf968a22537cede099dbd419d1a3c5edebe85fdb82501c4de90
 DIST qiskit-aer-0.13.3.gh.tar.gz 6982603 BLAKE2B 0ecc1929b0fec476b8e80012d78d9a65fcd8994f7c0fd66880e31c44bc3fa3d050774d696a9b5726f18cd401113dc8068e4391002743936baa09c283e06ba9bf SHA512 53d8741ed025ca3155931be6c66bc10618efc7beda69f0d3a2ba9ce8fea5beedfb6384761b64494e92be34ce64391b0f5f08c52945123431ea583d79fa0083e7
-EBUILD qiskit-aer-0.12.2.ebuild 4354 BLAKE2B 2c00ff587b5a072d07019a853067f0a7a7a3a15e8a45bfeef84b7e5a4b79b1a54853abcadac91e7da948ec934a061ad87bf8ebbb18838382296cc1c22137288e SHA512 447c4ece6a909cc9244cf33b6c60a2a4cccaad4216252afa05320a03a2883fd7e88d6235528643be7be89d3990c511542c0d3f1ec1f65adaf19579f765327c0c
-EBUILD qiskit-aer-0.13.3.ebuild 4237 BLAKE2B 5ca92d99a9c2f6e65c2e55264a7c3ff8ce5fc12d03ad7c662a80419df0d137b49b0bb8b093ec7a5954aae76fd0c8e1d1e5b44b727662ad5ef373aa3f433f0ac7 SHA512 c7089624bfd5a1f59a0f29790cbb9fec12103f1e1e4d031b7b6e9f396a4d66d6f5325afe348719803a27ad70719bd9a642f0f6ebd5639897dec50ba2f9a23684
+DIST qiskit-aer-0.14.2.gh.tar.gz 7132159 BLAKE2B bc684f7acca071866bc6413d5fb881cf131fe212be7294922a6861dc526d77d0cfb906d9c2ea57236e42e8a99e137ee0ac5f0c1e11fd027122983ad3d8992f73 SHA512 75a2fadb413fc557f98043cc028b28f6cae65b983fd0f32f1e8b8eda6d5cbc6d9d528c38f765d14ede5909045cef914335a483f762c20c4dd85754449d63371c
+EBUILD qiskit-aer-0.12.2.ebuild 4348 BLAKE2B d2ebc62cf585ce7508701e62c9c712420dc8d873905ef1ecf6c65f710515fcc96cf4fda9b4acb761764a614476622f5d69d18edd0cfc5839dffc7d91584d9e50 SHA512 fb4f3f32f0be4f1ee39b999ba605808d5a304838c66106bb8cc705cd4eb5d41cfb70775bf9c1574619db32895a43d1f8d86440a9ae60583ddc2ed0feb676bd7e
+EBUILD qiskit-aer-0.13.3.ebuild 4231 BLAKE2B c2c9c6e942eb24c4926f68027a6e4d22ad71efa42b9ca9eccf106596ef8a4218476555168661c0d50c65fa1b99c2b6861911d37f3bfbf8e62c7cae1490f0e103 SHA512 3e28ace076b58602ecd86a81beeed21cd783c936ecd13883ff96eecdcdf24c81c54d66459c0f15777878b9e53175d5742c509a5d27011fca882b37252d9d0677
+EBUILD qiskit-aer-0.14.2.ebuild 3631 BLAKE2B 4c92dd1de8c4d1b1700064ab85c758f5ac0ad193d1056a85fe2e757a4555ea02c4bb826683c5547a274b6a95d5b9ca25f68c2f74a19eef494c49300a850be137 SHA512 8a130ac1ee1c930fce69e48c21050c0129bf1a3a3039210597353a3f3b7e9ae9d81dd77159430d0b7b4ad863fbef1cbdc128edab859b9f417388f15aedb7b798
 MISC metadata.xml 1049 BLAKE2B e2118dc211ac8f42115959dde943a32331b4186524ef4a5a1343d8798a329e1d0de5f9a52a9c1212ec6af39392993378c6422424488782747ffbf4ab1e63d25e SHA512 bc4c9a19376938e973bedbdff0bbe95edb98c78b75d03f2a12985558a5cd5d0ceb934c43371438dd597a8d4fb8879d5483aeb8d806ac4d9b73b704d1232086b8
diff --git a/dev-python/qiskit-aer/qiskit-aer-0.12.2.ebuild b/dev-python/qiskit-aer/qiskit-aer-0.12.2.ebuild
index 9616058c1ebf..ab5fdc854b07 100644
--- a/dev-python/qiskit-aer/qiskit-aer-0.12.2.ebuild
+++ b/dev-python/qiskit-aer/qiskit-aer-0.12.2.ebuild
@@ -42,7 +42,7 @@ DEPEND="
 "
 RDEPEND="
 	${DEPEND}
-	>=dev-python/qiskit-terra-0.25.1-r1[${PYTHON_USEDEP}]
+	>=dev-python/qiskit-0.25.1-r1[${PYTHON_USEDEP}]
 	>=dev-python/scipy-1.0[${PYTHON_USEDEP}]
 "
 BDEPEND="
diff --git a/dev-python/qiskit-aer/qiskit-aer-0.13.3.ebuild b/dev-python/qiskit-aer/qiskit-aer-0.13.3.ebuild
index 8a056dfd27a5..407c96850445 100644
--- a/dev-python/qiskit-aer/qiskit-aer-0.13.3.ebuild
+++ b/dev-python/qiskit-aer/qiskit-aer-0.13.3.ebuild
@@ -43,7 +43,7 @@ DEPEND="
 RDEPEND="
 	${DEPEND}
 	>=dev-python/psutil-5[${PYTHON_USEDEP}]
-	>=dev-python/qiskit-terra-0.45.0[${PYTHON_USEDEP}]
+	>=dev-python/qiskit-0.45.0[${PYTHON_USEDEP}]
 	>=dev-python/scipy-1.0[${PYTHON_USEDEP}]
 "
 BDEPEND="
diff --git a/dev-python/qiskit-aer/qiskit-aer-0.14.2.ebuild b/dev-python/qiskit-aer/qiskit-aer-0.14.2.ebuild
new file mode 100644
index 000000000000..be250877d000
--- /dev/null
+++ b/dev-python/qiskit-aer/qiskit-aer-0.14.2.ebuild
@@ -0,0 +1,119 @@
+# Copyright 2022-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..12} )
+
+inherit distutils-r1
+
+DESCRIPTION="High performance simulator for quantum circuits that includes noise models"
+HOMEPAGE="
+	https://github.com/Qiskit/qiskit-aer/
+	https://pypi.org/project/qiskit-aer/
+"
+SRC_URI="
+	https://github.com/Qiskit/qiskit-aer/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64"
+
+# The reference implementation of BLAS/CBLAS is not compatible with qiskit-aer right now,
+# because importing library causes an error.
+# /usr/lib/python3.9/site-packages/qiskit/providers/aer/backends/controller_wrappers.cpython-39-x86_64-linux-gnu.so: undefined symbol: slamch_
+# Using sci-libs/openblas instead here,
+# with the option to switch between reference/openblas implementation runtime (eselect-ldso).
+#
+# <nlohmann_json-3.10.3 for https://github.com/Qiskit/qiskit-aer/issues/1742
+DEPEND="
+	>=dev-python/numpy-1.16.3[${PYTHON_USEDEP}]
+	<dev-cpp/nlohmann_json-3.10.3
+	>=dev-cpp/nlohmann_json-3.1.1
+	>=dev-libs/spdlog-1.9.2:=
+	>=dev-cpp/muParserX-4.0.8
+	virtual/cblas[eselect-ldso]
+	sci-libs/openblas[eselect-ldso]
+"
+RDEPEND="
+	${DEPEND}
+	>=dev-python/psutil-5[${PYTHON_USEDEP}]
+	>=dev-python/qiskit-1.1.0[${PYTHON_USEDEP}]
+	>=dev-python/scipy-1.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	>=dev-build/cmake-3.17
+	>=dev-python/scikit-build-0.11.0[${PYTHON_USEDEP}]
+	>=dev-python/pybind11-2.6[${PYTHON_USEDEP}]
+	test? (
+		dev-python/ddt[${PYTHON_USEDEP}]
+		dev-python/fixtures[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+check_openblas() {
+	local libdir=$(get_libdir) me="openblas"
+
+	# check blas
+	local current_blas=$(eselect blas show ${libdir} | cut -d' ' -f2)
+	if [[ ${current_blas} != "${me}" ]]; then
+		eerror "Current eselect: BLAS/CBLAS ($libdir) -> [${current_blas}]."
+		eerror "To use qiskit-aer, you have to issue (as root):"
+		eerror "\t eselect blas set ${libdir} ${me}"
+		return 1
+	fi
+	return 0
+}
+
+pkg_setup() {
+	if use test; then
+		check_openblas
+		if [[ $? -ne 0 ]]; then
+			die "Set blas implementation to openblas using 'eselect blas set openblas'!"
+		fi
+	fi
+}
+
+python_prepare_all() {
+	export DISABLE_CONAN="ON"
+	export DISABLE_DEPENDENCY_INSTALL="ON"
+	export SKBUILD_CONFIGURE_OPTIONS="-DTEST_JSON=1"
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# requires qiskit_qasm3_import
+		test/terra/backends/aer_simulator/test_save_statevector.py::TestSaveStatevector::test_save_statevector_for_qasm3_circuit_1___automatic____CPU__
+		test/terra/backends/aer_simulator/test_save_statevector.py::TestSaveStatevector::test_save_statevector_for_qasm3_circuit_2___statevector____CPU__
+		test/terra/backends/aer_simulator/test_save_statevector.py::TestSaveStatevector::test_save_statevector_for_qasm3_circuit_3___matrix_product_state____CPU__
+		test/terra/backends/aer_simulator/test_save_statevector.py::TestSaveStatevector::test_save_statevector_for_qasm3_circuit_4___extended_stabilizer____CPU__
+	)
+
+	local EPYTEST_IGNORE=(
+		# TODO: qiskit.providers.aer? wtf?
+		test/terra/expression/test_classical_expressions.py
+	)
+
+	# From tox.ini/tests.yml in CI
+	# Needed to suppress a warning in jupyter-core 5.x by eagerly migrating to
+	# a new internal interface that will be the default in jupyter-core 6.x.
+	# This variable should become redundant on release of jupyter-core 6.
+	local -x JUPYTER_PLATFORM_DIRS=1
+
+	rm -rf qiskit_aer || die
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest -s
+}
+
+pkg_postinst() {
+	check_openblas
+}