gentoo auto-resync : 30:06:2023 - 07:42:22

2 files changed, 88 insertions, 0 deletions

diff --git a/dev-python/python-lsp-server/Manifest b/dev-python/python-lsp-server/Manifest
index 436805ded21b..72d20b904352 100644
--- a/dev-python/python-lsp-server/Manifest
+++ b/dev-python/python-lsp-server/Manifest
@@ -1,3 +1,5 @@
 DIST python-lsp-server-1.7.3.tar.gz 97336 BLAKE2B 3b9d206451e59741113db116621594d3329651150f6819c2e1f1956f758f26eb3ff9f5c66e02313ce1693daf2925d62320a749a23921d64d0758891658cdb2ae SHA512 b34b8ae4311f4c8af9379f6a5d94400f34e3221f9bc55a4d95f909a23d0098bab4bd27992792901cea67b01202720b3cc76f89138841b352a49191aa86603c02
+DIST python-lsp-server-1.7.4.tar.gz 97864 BLAKE2B 9832298391d72bf2f035f388694a7879d66546ead5a36837220cb3af5d8181eba198c04dd82747cba75f0478d256b001476c24b02bc679fc07cb41c7aedb0e66 SHA512 7aa96de6e51548e2854b55690698fe6c7bda60103c11ad5982df611c65569cec1ab13691727c92ec47d9ac44c34f233f872211a41041ea0969223e10e87d7e08
 EBUILD python-lsp-server-1.7.3.ebuild 2925 BLAKE2B c2b34897d143b266f394697ba39a032e9440805f17303bd26bfea0ca6430334fb536d892e3afffc01799253b7ce044ca009d171769af92ea94d0bed298997bb1 SHA512 da185520024e72cf0f214cd6a32393b19dda8d4113eac87bafd8604be80881cecff86a6181e6a59cbee6694bd4734caf161c9a4c7f08ce4a50a810532c30fc30
+EBUILD python-lsp-server-1.7.4.ebuild 2928 BLAKE2B 1c4dac97034927b1e6490f4f48f2cab88303d9aa813c77b314322f655a3be1d8d380184523684fb93f41f49ebadd4472b36a65e7352377c59d8f8b6799aac582 SHA512 51e9bbcc9ef8864107705e4a3e12f1afe8fdccdb21d20a29c382c9516dbabaaf8d0aed544f8d7ed21c1270594e71adeebeda3a4fd4da245053b206080292b54b
 MISC metadata.xml 610 BLAKE2B e111007adc2612409df72955babe0c4725fd5726449435988cf13c1142049d78089d38e54783712e2c70c74437157ffb2049bd9d63322cec084204eb5038e724 SHA512 5e1e4b43a5bfacb6a2fcae57413ebf79c6aed917b00022140d855acd773d82e56b2d73ae8270d42675a34d9f37f9ad53c8f61930c3f447d8a9e45a521a20e9bb
diff --git a/dev-python/python-lsp-server/python-lsp-server-1.7.4.ebuild b/dev-python/python-lsp-server/python-lsp-server-1.7.4.ebuild
new file mode 100644
index 000000000000..8144133f5a10
--- /dev/null
+++ b/dev-python/python-lsp-server/python-lsp-server-1.7.4.ebuild
@@ -0,0 +1,86 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYPI_NO_NORMALIZE=1
+PYTHON_COMPAT=( python3_{10..11} )
+
+inherit distutils-r1 optfeature pypi
+
+DESCRIPTION="Python Language Server for the Language Server Protocol"
+HOMEPAGE="https://github.com/python-lsp/python-lsp-server"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+IUSE="all-plugins"
+
+BDEPEND="
+	test? (
+		>=dev-python/autopep8-1.6.0[${PYTHON_USEDEP}]
+		dev-python/flaky[${PYTHON_USEDEP}]
+		>=dev-python/flake8-5.0.0[${PYTHON_USEDEP}]
+		dev-python/matplotlib[${PYTHON_USEDEP}]
+		>=dev-python/mccabe-0.7.0[${PYTHON_USEDEP}]
+		dev-python/numpy[${PYTHON_USEDEP}]
+		dev-python/pandas[${PYTHON_USEDEP}]
+		>=dev-python/pycodestyle-2.9.0[${PYTHON_USEDEP}]
+		>=dev-python/pydocstyle-6.3.0[${PYTHON_USEDEP}]
+		<dev-python/pydocstyle-6.4.0[${PYTHON_USEDEP}]
+		>=dev-python/pyflakes-2.5.0[${PYTHON_USEDEP}]
+		>=dev-python/pylint-2.5.0[${PYTHON_USEDEP}]
+		dev-python/QtPy[gui,testlib,${PYTHON_USEDEP}]
+		>=dev-python/rope-1.2.0[${PYTHON_USEDEP}]
+		>=dev-python/yapf-0.33.0[${PYTHON_USEDEP}]
+		>=dev-python/whatthepatch-1.0.2[${PYTHON_USEDEP}]
+	)
+"
+
+RDEPEND="
+	dev-python/docstring-to-markdown[${PYTHON_USEDEP}]
+	>=dev-python/jedi-0.17.2[${PYTHON_USEDEP}]
+	>=dev-python/python-lsp-jsonrpc-1.0.0[${PYTHON_USEDEP}]
+	dev-python/pluggy[${PYTHON_USEDEP}]
+	all-plugins? (
+		>=dev-python/autopep8-1.6.0[${PYTHON_USEDEP}]
+		>=dev-python/flake8-5.0.0[${PYTHON_USEDEP}]
+		>=dev-python/mccabe-0.7.0[${PYTHON_USEDEP}]
+		>=dev-python/pycodestyle-2.9.0[${PYTHON_USEDEP}]
+		>=dev-python/pydocstyle-6.3.0[${PYTHON_USEDEP}]
+		<dev-python/pydocstyle-6.4.0[${PYTHON_USEDEP}]
+		>=dev-python/pyflakes-2.5.0[${PYTHON_USEDEP}]
+		>=dev-python/pylint-2.5.0[${PYTHON_USEDEP}]
+		>=dev-python/rope-1.2.0[${PYTHON_USEDEP}]
+		>=dev-python/yapf-0.33.0[${PYTHON_USEDEP}]
+		>=dev-python/whatthepatch-1.0.2[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+EPYTEST_DESELECT=(
+	# broken by presence of pathlib2
+	'test/plugins/test_autoimport.py'
+)
+
+python_prepare_all() {
+	# remove pytest-cov dep
+	sed -i -e '/addopts =/d' pyproject.toml || die
+	# unpin all the deps
+	sed -i -e 's:,<[0-9.]*::' pyproject.toml || die
+	distutils-r1_python_prepare_all
+}
+
+pkg_postinst() {
+	optfeature "Automatically format Python code to conform to the PEP 8 style guide" dev-python/autopep8
+	optfeature "A wrapper around PyFlakes, pep8 & mccabe" dev-python/flake8
+	optfeature "flake8 plugin: McCabe complexity checker" dev-python/mccabe
+	optfeature "Python style guide checker (fka pep8)" dev-python/pycodestyle
+	optfeature "Python docstring style checker" dev-python/pydocstyle
+	optfeature "Passive checker for Python programs" dev-python/pyflakes
+	optfeature "Python code static checker" dev-python/pylint
+	optfeature "Python refactoring library" dev-python/rope
+	optfeature "A formatter for Python files" dev-python/yapf
+}