gentoo auto-resync : 22:01:2024 - 04:49:56

2 files changed, 109 insertions, 0 deletions

diff --git a/dev-python/python-lsp-server/Manifest b/dev-python/python-lsp-server/Manifest
index 4c4917245f47..df9f7992c9b5 100644
--- a/dev-python/python-lsp-server/Manifest
+++ b/dev-python/python-lsp-server/Manifest
@@ -1,3 +1,5 @@
+DIST python-lsp-server-1.10.0.tar.gz 112917 BLAKE2B 2429e136ea2732d3bdfc2c77424a864364a7eb98bd447273d514fa53238b1ec276d46a51e558be8d959f100cd4dcfadf3a3eac996aa49b6b011babea84e8e3a8 SHA512 342452a5e3b1ae448a993f64501b2162b286f009026f1b5d306621c4befd0188699fc682206d50d06a93d8780862c8476186f8d0e4bb20592ddbbade1276445c
 DIST python-lsp-server-1.9.0.tar.gz 111176 BLAKE2B 8143e7e294e820114d2752ef2a3afe3d0494aab7a3bbc785cf543585531bdb5e7df681f446f2db7d2c05271d06fad94e6850fa0eef244c6ed5d36efeb7606597 SHA512 052ee7b9cf042afc64df34592b4daa2fb4113d78fe538a72db0426618f13ce6a453173a343b62fefeefb47ffa5a026ae0e7d029d65a5a1b235f52dd4b44c6067
+EBUILD python-lsp-server-1.10.0.ebuild 3321 BLAKE2B 1753b371ed7e385643f42e67450991d64ebaf0cefbcd62a9d4a55f5b9bccf5265071b2410ff509ce7d73280a20b3f546b6a23cf63b44e676a321330cedd8d29b SHA512 403c9d7dbd863e6ee0ff80877550b6152f5a437c454e9767ea00f93ade74c7b858379f49a60c89cb7cd2dd37685a812319a571947207f2804ccd5b965940c38c
 EBUILD python-lsp-server-1.9.0.ebuild 3321 BLAKE2B 59b32e80055c4b363db6be366f804dbdd779dedf6851b9c353886483322b889931b78ca7c5d6da89f8513ee8282e64fef7211a3f9a594e8a1eabae529fb87bfb SHA512 af44e45aae562d7f443163646d3f748b8960c211d10c863f8650dda557f6df3f1e3b904fa0d9b0b9db38314fdeeb43f86c0e221f3b0fb8a49c293686afbf2601
 MISC metadata.xml 610 BLAKE2B e111007adc2612409df72955babe0c4725fd5726449435988cf13c1142049d78089d38e54783712e2c70c74437157ffb2049bd9d63322cec084204eb5038e724 SHA512 5e1e4b43a5bfacb6a2fcae57413ebf79c6aed917b00022140d855acd773d82e56b2d73ae8270d42675a34d9f37f9ad53c8f61930c3f447d8a9e45a521a20e9bb
diff --git a/dev-python/python-lsp-server/python-lsp-server-1.10.0.ebuild b/dev-python/python-lsp-server/python-lsp-server-1.10.0.ebuild
new file mode 100644
index 000000000000..8f0c7de51fc0
--- /dev/null
+++ b/dev-python/python-lsp-server/python-lsp-server-1.10.0.ebuild
@@ -0,0 +1,107 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYPI_NO_NORMALIZE=1
+PYTHON_COMPAT=( python3_{10..12} pypy3 )
+
+inherit distutils-r1 optfeature pypi
+
+DESCRIPTION="Python Language Server for the Language Server Protocol"
+HOMEPAGE="
+	https://github.com/python-lsp/python-lsp-server/
+	https://pypi.org/project/python-lsp-server/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+IUSE="all-plugins"
+
+RDEPEND="
+	dev-python/docstring-to-markdown[${PYTHON_USEDEP}]
+	>=dev-python/jedi-0.17.2[${PYTHON_USEDEP}]
+	>=dev-python/python-lsp-jsonrpc-1.1.0[${PYTHON_USEDEP}]
+	dev-python/pluggy[${PYTHON_USEDEP}]
+	all-plugins? (
+		>=dev-python/autopep8-2.0.4[${PYTHON_USEDEP}]
+		>=dev-python/flake8-7[${PYTHON_USEDEP}]
+		>=dev-python/mccabe-0.7.0[${PYTHON_USEDEP}]
+		>=dev-python/pycodestyle-2.9.0[${PYTHON_USEDEP}]
+		>=dev-python/pyflakes-3.2.0[${PYTHON_USEDEP}]
+		>=dev-python/pylint-2.5.0[${PYTHON_USEDEP}]
+		>=dev-python/whatthepatch-1.0.2[${PYTHON_USEDEP}]
+		>=dev-python/yapf-0.33.0[${PYTHON_USEDEP}]
+		$(python_gen_cond_dep '
+			>=dev-python/rope-1.11.0[${PYTHON_USEDEP}]
+		' 'python*')
+	)
+"
+BDEPEND="
+	test? (
+		>=dev-python/autopep8-1.6.0[${PYTHON_USEDEP}]
+		dev-python/flaky[${PYTHON_USEDEP}]
+		>=dev-python/flake8-5.0.0[${PYTHON_USEDEP}]
+		dev-python/matplotlib[${PYTHON_USEDEP}]
+		>=dev-python/mccabe-0.7.0[${PYTHON_USEDEP}]
+		dev-python/numpy[${PYTHON_USEDEP}]
+		>=dev-python/pycodestyle-2.9.0[${PYTHON_USEDEP}]
+		>=dev-python/pyflakes-2.5.0[${PYTHON_USEDEP}]
+		>=dev-python/pylint-2.5.0[${PYTHON_USEDEP}]
+		>=dev-python/whatthepatch-1.0.2[${PYTHON_USEDEP}]
+		>=dev-python/yapf-0.33.0[${PYTHON_USEDEP}]
+		$(python_gen_cond_dep '
+			dev-python/pandas[${PYTHON_USEDEP}]
+			dev-python/QtPy[gui,testlib,${PYTHON_USEDEP}]
+			>=dev-python/rope-1.2.0[${PYTHON_USEDEP}]
+		' 'python*')
+	)
+"
+
+# Note: xdist breaks some tests
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# remove pytest-cov dep
+	sed -i -e '/addopts =/d' pyproject.toml || die
+	# unpin all the deps
+	sed -i -e 's:,<[0-9.]*::' pyproject.toml || die
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# broken by presence of pathlib2
+		'test/plugins/test_autoimport.py'
+	)
+	local EPYTEST_IGNORE=(
+		# pydocstyle is archived upstream and broken with py3.12
+		test/plugins/test_pydocstyle_lint.py
+	)
+
+	if [[ ${EPYTHON} == pypy3 ]] ; then
+		# Not all plugins are available for pypy3
+		EPYTEST_IGNORE+=(
+			test/plugins/test_autoimport.py
+			test/plugins/test_completion.py
+			test/plugins/test_rope_rename.py
+		)
+	fi
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest
+}
+
+pkg_postinst() {
+	optfeature "Automatically format Python code to conform to the PEP 8 style guide" dev-python/autopep8
+	optfeature "A wrapper around PyFlakes, pep8 & mccabe" dev-python/flake8
+	optfeature "flake8 plugin: McCabe complexity checker" dev-python/mccabe
+	optfeature "Python style guide checker (fka pep8)" dev-python/pycodestyle
+	optfeature "Python docstring style checker" dev-python/pydocstyle
+	optfeature "Passive checker for Python programs" dev-python/pyflakes
+	optfeature "Python code static checker" dev-python/pylint
+	optfeature "Python refactoring library" dev-python/rope
+	optfeature "A formatter for Python files" dev-python/yapf
+}