gentoo resync : 17.02.2021

1 files changed, 45 insertions, 0 deletions

diff --git a/dev-python/pygments/pygments-2.8.0.ebuild b/dev-python/pygments/pygments-2.8.0.ebuild
new file mode 100644
index 000000000000..eb9fa4c20022
--- /dev/null
+++ b/dev-python/pygments/pygments-2.8.0.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DISTUTILS_USE_SETUPTOOLS=rdepend
+PYTHON_COMPAT=( python3_{7..9} pypy3 )
+
+inherit distutils-r1 bash-completion-r1
+
+MY_P=${P^}
+DESCRIPTION="Pygments is a syntax highlighting package written in Python"
+HOMEPAGE="
+	https://pygments.org/
+	https://github.com/pygments/pygments/
+	https://pypi.org/project/Pygments/"
+SRC_URI="mirror://pypi/${MY_P:0:1}/${PN^}/${MY_P}.tar.gz"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-cygwin ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+
+BDEPEND="
+	test? (
+		virtual/ttf-fonts
+	)"
+
+distutils_enable_sphinx doc
+distutils_enable_tests pytest
+
+python_test() {
+	local deselect=()
+	# there is a known bug in regex engine of pypy3.7
+	[[ ${EPYTHON} == pypy3 && $(pypy3 --version) == "Python 3.7"* ]] &&
+		deselect+=( tests/snippets/crystal/test_macro.txt:: )
+
+	pytest -vv ${deselect[@]/#/--deselect } ||
+		die "Tests failed with ${EPYTHON}"
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+	newbashcomp external/pygments.bashcomp pygmentize
+}