gentoo auto-resync : 22:07:2023 - 02:49:03

1 files changed, 69 insertions, 0 deletions

diff --git a/dev-python/pdm/pdm-2.8.0.ebuild b/dev-python/pdm/pdm-2.8.0.ebuild
new file mode 100644
index 000000000000..af490a26b277
--- /dev/null
+++ b/dev-python/pdm/pdm-2.8.0.ebuild
@@ -0,0 +1,69 @@
+# Copyright 2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=pdm-backend
+PYTHON_COMPAT=( python3_{10..11} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Python package and dependency manager supporting the latest PEP standards"
+HOMEPAGE="
+	https://pypi.org/project/pdm/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	dev-python/blinker[${PYTHON_USEDEP}]
+	dev-python/certifi[${PYTHON_USEDEP}]
+	dev-python/packaging[${PYTHON_USEDEP}]
+	dev-python/platformdirs[${PYTHON_USEDEP}]
+	dev-python/rich[${PYTHON_USEDEP}]
+	dev-python/virtualenv[${PYTHON_USEDEP}]
+	dev-python/pyproject-hooks[${PYTHON_USEDEP}]
+	dev-python/requests-toolbelt[${PYTHON_USEDEP}]
+	dev-python/unearth[${PYTHON_USEDEP}]
+	dev-python/findpython[${PYTHON_USEDEP}]
+	dev-python/tomlkit[${PYTHON_USEDEP}]
+	dev-python/shellingham[${PYTHON_USEDEP}]
+	dev-python/python-dotenv[${PYTHON_USEDEP}]
+	>=dev-python/resolvelib-1.0.1[${PYTHON_USEDEP}]
+	dev-python/installer[${PYTHON_USEDEP}]
+	dev-python/cachecontrol[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep 'dev-python/tomli[${PYTHON_USEDEP}]' pypy3 python3_10)
+"
+BDEPEND="
+	${RDEPEND}
+	test? (
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	local -a disable_tests=(
+		# tests that try to reach out to the internet
+		basic_integration
+		build_with_no_isolation
+		search_package
+		show_package_on_pypi
+		show_update_hint
+		build_single_module
+		project_packages_path
+		build_package
+		build_src_package
+		build_with_config_settings
+		cli_build_with_config_settings
+		build_ignoring_pip_environment
+		publish_and_build_in_one_run
+	)
+
+	local textexpr
+	testexpr=$(printf 'not %s and ' "${disable_tests[@]}")
+	epytest -m "not network and not integration and not path" -k "${testexpr%and }" -x
+}