gentoo auto-resync : 06:01:2024 - 12:54:38

3 files changed, 123 insertions, 3 deletions

diff --git a/dev-python/lxml/Manifest b/dev-python/lxml/Manifest
index 93596afedfc4..523652e7fc7c 100644
--- a/dev-python/lxml/Manifest
+++ b/dev-python/lxml/Manifest
@@ -2,7 +2,9 @@ DIST lxml-4.9.3-patches-2.tar.xz 24288 BLAKE2B 47b7c486a1c1616c875111bd53b14d421
 DIST lxml-4.9.3.gh.tar.gz 958628 BLAKE2B ffdf3fe781a03815f7c026229d313721c93375ebafad9b4a20c5d8a380a631401e546d8701a94d8c49615fb6a71e84940d8ca0299b47a37c1c9596db36659113 SHA512 903bd4935c7708b459aee9befcf3f6e3e3aaa9adc122591ea923b6e3d8fd288f07cab3f5f0edb08e3bf9db80414324f0a1a8e5a5089f9cda82f6c50f5df59423
 DIST lxml-4.9.4.gh.tar.gz 960009 BLAKE2B 7d31095dcf1f73c1026e7378e6adb19a053edc116b119ae415c3324134d3700822bf4611dc3cbf7c216d396e1404b143c8ebfdfb7e5a71b9ef6ec187898cc699 SHA512 528ef4ae057a7ee54d3193a042a6db500ada883d1d506829b6824d91ec979feb69ec79239420112eae0e08a437b2e5da8efc35feb5d04d119bfae2679e918d29
 DIST lxml-5.0.0.gh.tar.gz 964278 BLAKE2B 9c3f026b03bd671545cb039632af9bf1e8b94b8f8d4a20d0e4110f2b2d63cf0a46f983d0fa8eb71867ba9ac8cd46c949714dc7486faf01ecedae858e39799031 SHA512 6562bb68ea677fd9726adff1940034e364be0626dd1c086971cf0b271ca5caf98c96a3c465b98ede76f72248a40cf190fdc4f54c04c7e9c93e6408fde63fbfd3
+DIST lxml-5.0.1.gh.tar.gz 965422 BLAKE2B 4dfc17a0d3920a6785765f7bf5a35b578c8e62419ce6b5288a2899fcbf8b809a235a9b3b23abbcfa84ba5fcabb9ce7a838ff02f3f74e4ae5cb60850b951e3c23 SHA512 09ed4d9fd1396a0fbc2d7b14119545817497a85e632fde6239f6e66921926476e468a9ced227b6575519a2d1a5d03c858319386a5d739ff7aa3f68282d027b63
 EBUILD lxml-4.9.3-r2.ebuild 2995 BLAKE2B f48ccbfdca26f9eb6e03a1823645e32c1815b653d9228c1b87036a16d01c89418765da5b0c0038f2e91eea1e1cc07f4018e8a1f901c79628437514b0d7d7ed6b SHA512 130dabb41404a1ad058c1efd9ff582e0c14441abe6a1733d716353a86167701041c9cc43554358a1ecdd83cba36019d618424421f1602772fe78ac80e6e45947
-EBUILD lxml-4.9.4.ebuild 3003 BLAKE2B cb85c578cf3e284b33987b9b85d7b6e5918a973adf20800fab4822e596b8a51ac56a93f9911fdde382f4857a799e1825cfed96f9c07edf0ad4a03718fa832819 SHA512 4a386eb0b886c0d0c53d2e3029c553034a745a05b0824b8e6fed555db707b4705f1d8ddf4548f1d1efe6f26cf10dfdbfd54aed2df7593c1b033ed98ac5238443
+EBUILD lxml-4.9.4.ebuild 2998 BLAKE2B c61e9d3df916f53c94a2042b927224f20aa32376254ebf758148938a882af6b6682cc8521eb1caabca2717f77d7048a39f36dc9123aef275ab2e5f99cc727e0e SHA512 eb897b1c97d04da02c0449b5579d0a90871106ab11fc746e1a3f5fd9ea900de464c68b0fa235e9c7aa3df58d713003894c4322a9653bd7503466ba53ec46c9f0
 EBUILD lxml-5.0.0.ebuild 3039 BLAKE2B 195bd0b9cff9a9baf30e245c0a04f96fcb783d4986175cef89e875805311b307f3d7cb58aca202af60bb0992d16f78e8c717e62a37a2deeea31bc56b54af01bd SHA512 c063cc906717c823caba0fdad3bb27220a7914b874938801662e7c6bc422b817a1c7d0271785d7dac79b20db3f75dd1e51a7e1d113e2657912f3af944c5c3926
+EBUILD lxml-5.0.1.ebuild 3039 BLAKE2B 5ef86955635e08b2335709ceb284b968ede777513eff3efbe5982b4e9e7ae5ae35d4eec3263731e1ea0f69b2ba22bfed5c9e6b21c667d9d92c41401755f4c08d SHA512 893e69d8f5a36f223897c182c05902eca8a414ec2d9d78a275c705b47cb3c865f07053055ef7f108443027668e18a96018329ae97d44e41678b00a5e9bda0056
 MISC metadata.xml 463 BLAKE2B 9bcd092b61568f5d467230617b101f36245c41078e6a66c7ff63b22a6b4095de2ba3a59e48ce8b7842ce58d1255fa293995652daa3fab4c3af988498eaa30e97 SHA512 2ba5e340b59e0de4e472380e9c19b1f6f573e86e5c3c2e075f6151d369e94eea70e3ce36bfb5ece4da3fa69459e3ff83368f1df8302aa5754ae52f13c8f2312e
diff --git a/dev-python/lxml/lxml-4.9.4.ebuild b/dev-python/lxml/lxml-4.9.4.ebuild
index 2219b76e7dc6..c9d0eb93c054 100644
--- a/dev-python/lxml/lxml-4.9.4.ebuild
+++ b/dev-python/lxml/lxml-4.9.4.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2023 Gentoo Authors
+# Copyright 1999-2024 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=8
@@ -24,7 +24,7 @@ S=${WORKDIR}/lxml-${P}
 
 LICENSE="BSD ElementTree GPL-2 PSF-2"
 SLOT="0"
-KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~arm64-macos ~ppc-macos ~x64-macos ~x64-solaris"
+KEYWORDS="~alpha amd64 arm arm64 ~hppa ~ia64 ~loong ~m68k ~mips ppc ~ppc64 ~riscv ~s390 ~sparc x86 ~amd64-linux ~x86-linux ~arm64-macos ~ppc-macos ~x64-macos ~x64-solaris"
 IUSE="doc examples +threads test"
 RESTRICT="!test? ( test )"
 
diff --git a/dev-python/lxml/lxml-5.0.1.ebuild b/dev-python/lxml/lxml-5.0.1.ebuild
new file mode 100644
index 000000000000..3dfddf8a4054
--- /dev/null
+++ b/dev-python/lxml/lxml-5.0.1.ebuild
@@ -0,0 +1,118 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..12} pypy3 )
+
+inherit distutils-r1 optfeature toolchain-funcs
+
+DESCRIPTION="A Pythonic binding for the libxml2 and libxslt libraries"
+HOMEPAGE="
+	https://lxml.de/
+	https://pypi.org/project/lxml/
+	https://github.com/lxml/lxml/
+"
+SRC_URI="
+	https://github.com/lxml/lxml/archive/${P}.tar.gz
+		-> ${P}.gh.tar.gz
+	https://dev.gentoo.org/~sam/distfiles/${CATEGORY}/${PN}/${PN}-4.9.3-patches-2.tar.xz
+"
+S=${WORKDIR}/lxml-${P}
+
+LICENSE="BSD ElementTree GPL-2 PSF-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~arm64-macos ~ppc-macos ~x64-macos ~x64-solaris"
+IUSE="doc examples +threads test"
+RESTRICT="!test? ( test )"
+
+# Note: lib{xml2,xslt} are used as C libraries, not Python modules.
+DEPEND="
+	>=dev-libs/libxml2-2.10.3
+	>=dev-libs/libxslt-1.1.38
+"
+RDEPEND="
+	${DEPEND}
+"
+BDEPEND="
+	virtual/pkgconfig
+	>=dev-python/cython-3.0.7[${PYTHON_USEDEP}]
+	doc? (
+		$(python_gen_any_dep '
+			dev-python/docutils[${PYTHON_USEDEP}]
+			dev-python/pygments[${PYTHON_USEDEP}]
+			dev-python/sphinx[${PYTHON_USEDEP}]
+			dev-python/sphinx-rtd-theme[${PYTHON_USEDEP}]
+		')
+	)
+	test? (
+		dev-python/cssselect[${PYTHON_USEDEP}]
+	)
+"
+
+PATCHES=(
+	"${WORKDIR}"/${PN}-4.9.3-patches-2/0001-Skip-tests-failing-on-PyPy.patch
+)
+
+python_check_deps() {
+	use doc || return 0
+	python_has_version -b "dev-python/docutils[${PYTHON_USEDEP}]" &&
+	python_has_version -b "dev-python/pygments[${PYTHON_USEDEP}]" &&
+	python_has_version -b "dev-python/sphinx[${PYTHON_USEDEP}]" &&
+	python_has_version -b "dev-python/sphinx-rtd-theme[${PYTHON_USEDEP}]"
+}
+
+python_prepare_all() {
+	# avoid replacing PYTHONPATH in tests.
+	sed -i -e '/sys\.path/d' test.py || die
+
+	# don't use some random SDK on Darwin
+	sed -i -e '/_ldflags =/s/=.*isysroot.*darwin.*None/= None/' \
+		setupinfo.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile() {
+	local DISTUTILS_ARGS=(
+		# by default it adds -w to CFLAGS
+		--warnings
+	)
+	tc-export PKG_CONFIG
+	distutils-r1_python_compile
+}
+
+python_compile_all() {
+	use doc && emake html
+}
+
+python_test() {
+	local dir=${BUILD_DIR}/test$(python_get_sitedir)/lxml
+	local -x PATH=${BUILD_DIR}/test/usr/bin:${PATH}
+
+	cp -al "${BUILD_DIR}"/{install,test} || die
+	cp -al src/lxml/tests "${dir}/" || die
+	cp -al src/lxml/html/tests "${dir}/html/" || die
+	ln -rs "${S}"/doc "${dir}"/../../ || die
+
+	"${EPYTHON}" test.py -vv --all-levels -p || die "Test ${test} fails with ${EPYTHON}"
+}
+
+python_install_all() {
+	if use doc; then
+		local DOCS=( README.rst *.txt doc/*.txt )
+		local HTML_DOCS=( doc/html/. )
+	fi
+	if use examples; then
+		dodoc -r samples
+	fi
+
+	distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+	optfeature "Support for BeautifulSoup as a parser backend" dev-python/beautifulsoup4
+	optfeature "Translates CSS selectors to XPath 1.0 expressions" dev-python/cssselect
+}