gentoo resync : 22.05.2021

1 files changed, 51 insertions, 0 deletions

diff --git a/dev-python/libvirt-python/libvirt-python-7.3.0.ebuild b/dev-python/libvirt-python/libvirt-python-7.3.0.ebuild
new file mode 100644
index 000000000000..eb8b2abcbc09
--- /dev/null
+++ b/dev-python/libvirt-python/libvirt-python-7.3.0.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7..9} )
+
+DISTUTILS_USE_SETUPTOOLS=no
+
+MY_P="${P/_rc/-rc}"
+
+inherit distutils-r1 verify-sig
+
+if [[ ${PV} = *9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://libvirt.org/git/libvirt-python.git"
+	RDEPEND="app-emulation/libvirt:=[-python(-)]"
+else
+	SRC_URI="https://libvirt.org/sources/python/${MY_P}.tar.gz
+		verify-sig? ( https://libvirt.org/sources/python/${MY_P}.tar.gz.asc )"
+	KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+	RDEPEND="app-emulation/libvirt:0/${PV}"
+fi
+S="${WORKDIR}/${P%_rc*}"
+
+DESCRIPTION="libvirt Python bindings"
+HOMEPAGE="https://www.libvirt.org"
+LICENSE="LGPL-2"
+SLOT="0"
+VERIFY_SIG_OPENPGP_KEY_PATH=/usr/share/openpgp-keys/libvirt.org.asc
+IUSE="examples test"
+RESTRICT="!test? ( test )"
+
+BDEPEND="
+	virtual/pkgconfig
+	test? (
+		dev-python/lxml[${PYTHON_USEDEP}]
+		dev-python/nose[${PYTHON_USEDEP}]
+	)
+	verify-sig? ( app-crypt/openpgp-keys-libvirt )
+"
+
+distutils_enable_tests setup.py
+
+python_install_all() {
+	if use examples; then
+		dodoc -r examples
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+	distutils-r1_python_install_all
+}