gentoo resync : 07.05.2021

2 files changed, 141 insertions, 0 deletions

diff --git a/dev-python/ipython/Manifest b/dev-python/ipython/Manifest
index c6549bca5e58..ebf5a3f6861b 100644
--- a/dev-python/ipython/Manifest
+++ b/dev-python/ipython/Manifest
@@ -2,7 +2,9 @@ AUX 2.1.0-substitute-files.patch 1017 BLAKE2B 70577eb950a18345804a2a4b750bd233dc
 DIST ipython-7.21.0.tar.gz 5141725 BLAKE2B dae44d481e959ef7d002bdb51d0ab1e2f3eca3449071a2e4161aa735c06fef8a948d80bafd3f2bdd066208437b5ed36615cad5885af453771a32a313fba907eb SHA512 200e41d4e06343b6320f3d106925f6c995f39cf88d01250f53885d4e94d0fd9454a6be4cd7c69410f7dced94b05634f6d2269f9737cc563accf85206d4d7fff8
 DIST ipython-7.22.0.tar.gz 5143229 BLAKE2B be78fc7089d620cb9ad437ed8154b37ac8c7cd68ca18a2569cfcf7ea9af968c58eeee18c8d18a1f26459ccef73e59083ac27055c19e4df254836e484ce0a9908 SHA512 2647dcd5e0d9b6afc8d990d2c099ad7ed581b5eff6d657630929e0d0d9f8965e7c7924c51a10a797e7d7406212d7a06c941c163e6f6046aa62130049a9bbc0d0
 DIST ipython-7.23.0.tar.gz 5143701 BLAKE2B 6672ea3a5bbc9afa38c73acef87a8c8f6d1830e3b949543537b522b809b68b80e5369566c8bee68139f9c3213fbe4c07ad36377a686fe2d26d7bbafd5e54fc4a SHA512 b00b71dbb2851f03f72b6c0e93920afc52cdb3cd5b8f27ba8cca4cb062a0f313db359ba83ba3a9608bca22744efab24c27350e06c5884946709b7fd29536820f
+DIST ipython-7.23.1.tar.gz 5188898 BLAKE2B 9713b0f1f75e283e53ba19044c9919f0c4d0b1c120e63d7a79ab9c6b8783499ed115e86a24cab34fc13c46245fb43865b851e6f98a2ee729ee35c3db242fa2ba SHA512 9b35626a8a07c6bd0b93552341e5a61d3d90a60c72ad6e3fc71266d9509134366c46a7ae8aeca9c3acc7509dfeab47b5144f105cb3d1d05ef1c7acca6c2f365d
 EBUILD ipython-7.21.0-r1.ebuild 3719 BLAKE2B 08caa9877f87f6dabd1223f92b2b879f679a4f75816d9876d9cc48bdc290500504a392bd0b520c73576f2fbc8fc3c32a734d83317a078e319fbaba50f0caf963 SHA512 05dff1600bd5c9193d1e6067ea588f30c5c69fe1cd5069f00e42dace5b8be1f6994044a0ff91aa34b97bef57378bfbdc1d455fca0589b140aa99347098bd3e5d
 EBUILD ipython-7.22.0-r1.ebuild 3765 BLAKE2B ec5e5ea2f82cf238e22f86af7548af42756deb360bbd11ddbbed6918de4c39109321a46a95b37b06d67daed4d985384b776a342cf4d042c60e59761a8efc3cc6 SHA512 c20991511bbdccf027f19dcefdfe3abfa6d9ca7c45d47f3afe15eb597d6ac8962336d8586302106da6fe7005ad2f3e518615843aabcedc36ec337218a0bdc20e
 EBUILD ipython-7.23.0.ebuild 3818 BLAKE2B 37d0a0eefd4902d1f5b7d6d54d5c95384d12017f133a1a962646e30e839405f467e2b9856c7c102c9a7d8580033e93daaf6e216a33f7d7eaf97a0557e3b57e5e SHA512 a893b56ec0ea66559d173bad90ddd26857a61eb785be36cf519e5e1a5ab70af55248d5ae802e22dcfb834fb87cbeaab9e055df609a32cd0efdf657aa80e14774
+EBUILD ipython-7.23.1.ebuild 3818 BLAKE2B 37d0a0eefd4902d1f5b7d6d54d5c95384d12017f133a1a962646e30e839405f467e2b9856c7c102c9a7d8580033e93daaf6e216a33f7d7eaf97a0557e3b57e5e SHA512 a893b56ec0ea66559d173bad90ddd26857a61eb785be36cf519e5e1a5ab70af55248d5ae802e22dcfb834fb87cbeaab9e055df609a32cd0efdf657aa80e14774
 MISC metadata.xml 2882 BLAKE2B 189477b4ccde9051b61d2a4ff5134907886795f97c5201fc2bf9c012526333151931a1445b6315f286474b71af84253033cbe9bf89bffa7813bfa49a4a07ef6c SHA512 f54fef4552d09a03a8d186c45f917c091928f1de84dfbdd80f1db80912d616d509f10c588de533916d9c494f5b3ca5e6e50a6d8b8c59ea47781311ad4319442a
diff --git a/dev-python/ipython/ipython-7.23.1.ebuild b/dev-python/ipython/ipython-7.23.1.ebuild
new file mode 100644
index 000000000000..2f2dc34fb24a
--- /dev/null
+++ b/dev-python/ipython/ipython-7.23.1.ebuild
@@ -0,0 +1,139 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DISTUTILS_USE_SETUPTOOLS=no
+PYTHON_COMPAT=( python3_{7..9} )
+PYTHON_REQ_USE='readline,sqlite,threads(+)'
+
+inherit distutils-r1 optfeature virtualx
+
+DESCRIPTION="Advanced interactive shell for Python"
+HOMEPAGE="https://ipython.org/ https://github.com/ipython/ipython/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc examples matplotlib notebook nbconvert qt5 +smp test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-python/backcall[${PYTHON_USEDEP}]
+	dev-python/decorator[${PYTHON_USEDEP}]
+	>=dev-python/jedi-0.16[${PYTHON_USEDEP}]
+	>=dev-python/pexpect-4.3[${PYTHON_USEDEP}]
+	dev-python/pickleshare[${PYTHON_USEDEP}]
+	>=dev-python/prompt_toolkit-2[${PYTHON_USEDEP}]
+	<dev-python/prompt_toolkit-3.1[${PYTHON_USEDEP}]
+	dev-python/pygments[${PYTHON_USEDEP}]
+	dev-python/traitlets[${PYTHON_USEDEP}]
+	matplotlib? (
+		dev-python/matplotlib[${PYTHON_USEDEP}]
+		dev-python/matplotlib-inline[${PYTHON_USEDEP}]
+	)
+"
+
+BDEPEND="
+	test? (
+		app-text/dvipng[truetype]
+		>=dev-python/ipykernel-5.1.0[${PYTHON_USEDEP}]
+		dev-python/matplotlib[${PYTHON_USEDEP}]
+		dev-python/matplotlib-inline[${PYTHON_USEDEP}]
+		dev-python/nbformat[${PYTHON_USEDEP}]
+		dev-python/nose[${PYTHON_USEDEP}]
+		>=dev-python/numpy-1.16[${PYTHON_USEDEP}]
+		dev-python/requests[${PYTHON_USEDEP}]
+		dev-python/testpath[${PYTHON_USEDEP}]
+	)
+	doc? (
+		>=dev-python/ipykernel-5.1.0[${PYTHON_USEDEP}]
+		dev-python/matplotlib[${PYTHON_USEDEP}]
+		>=dev-python/sphinx-2[${PYTHON_USEDEP}]
+		dev-python/sphinx_rtd_theme[${PYTHON_USEDEP}]
+	)"
+
+distutils_enable_tests pytest
+
+RDEPEND+="
+	nbconvert? ( dev-python/nbconvert[${PYTHON_USEDEP}] )"
+PDEPEND="
+	notebook? (
+		dev-python/notebook[${PYTHON_USEDEP}]
+		dev-python/ipywidgets[${PYTHON_USEDEP}]
+		dev-python/widgetsnbextension[${PYTHON_USEDEP}]
+	)
+	qt5? ( dev-python/qtconsole[${PYTHON_USEDEP}] )
+	smp? (
+		>=dev-python/ipykernel-5.1.0[${PYTHON_USEDEP}]
+		>=dev-python/ipyparallel-6.2.3[${PYTHON_USEDEP}]
+	)"
+
+PATCHES=( "${FILESDIR}"/2.1.0-substitute-files.patch )
+
+DISTUTILS_IN_SOURCE_BUILD=1
+
+python_prepare_all() {
+	# Remove out of date insource files
+	rm IPython/extensions/cythonmagic.py || die
+	rm IPython/extensions/rmagic.py || die
+
+	# Prevent un-needed download during build
+	if use doc; then
+		sed -e "/^    'sphinx.ext.intersphinx',/d" -i docs/source/conf.py || die
+	fi
+
+	# Rename the test directory to reduce sys.path pollution
+	# https://github.com/ipython/ipython/issues/12892
+	mv IPython/extensions/{,ipython_}tests || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	if use doc; then
+		emake -C docs html_noapi
+		HTML_DOCS=( docs/build/html/. )
+	fi
+}
+
+src_test() {
+	virtx distutils-r1_src_test
+}
+
+python_install() {
+	distutils-r1_python_install
+
+	# Create ipythonX.Y symlinks.
+	# TODO:
+	# 1. do we want them for pypy? No.  pypy has no numpy
+	# 2. handle it in the eclass instead (use _python_ln_rel).
+	# With pypy not an option the dosym becomes unconditional
+	dosym ../lib/python-exec/${EPYTHON}/ipython \
+		/usr/bin/ipython${EPYTHON#python}
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	if use examples; then
+		dodoc -r examples
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+}
+
+pkg_postinst() {
+	optfeature "sympyprinting" dev-python/sympy
+	optfeature "cythonmagic" dev-python/cython
+	optfeature "%lprun magic command" dev-python/line_profiler
+	optfeature "%mprun magic command" dev-python/memory_profiler
+
+	if use nbconvert; then
+		if ! has_version app-text/pandoc ; then
+			einfo "Node.js will be used to convert notebooks to other formats"
+			einfo "like HTML. Support for that is still experimental. If you"
+			einfo "encounter any problems, please use app-text/pandoc instead."
+		fi
+	fi
+}