gentoo resync : 17.06.2021

2 files changed, 140 insertions, 0 deletions

diff --git a/dev-python/ipython/Manifest b/dev-python/ipython/Manifest
index a42fd708f540..4f05c96c1449 100644
--- a/dev-python/ipython/Manifest
+++ b/dev-python/ipython/Manifest
@@ -4,5 +4,6 @@ DIST ipython-7.23.1.tar.gz 5188898 BLAKE2B 9713b0f1f75e283e53ba19044c9919f0c4d0b
 DIST ipython-7.24.1.tar.gz 5146561 BLAKE2B ae63d024f488f44dbd61eb9f3e14ac5b8ad801b1db195632c184c6106d4c2e6d6143c1524ae6fc5a2f6f631683b73f241c9115c439c0f97a4fe540cc232fb181 SHA512 0ea8843a1f2e7f9357ff9896f2b6da058adb5fcbbad5c3b1fc4138a085eb57034c62c0b50d82dea0e563523649ec112edd4ef0c267a914f6a7d33b44be30b977
 EBUILD ipython-7.22.0-r1.ebuild 3761 BLAKE2B 0fde64e41f1827ffaccc69fcb62db96e81c4c755bf7085d8890499eca01c776ed1ef500c20f277c1597c63c231587d2ddaf3ca68265629bf897d08f75a482cfe SHA512 bb27d30f8fa1fae515f1f92cca52846fe78bda310e35c84053cead7438898ec8b3d30475f36db3808d74e4ac02caf80f7bcabce4c570376a9f8661e6fecdb378
 EBUILD ipython-7.23.1.ebuild 3838 BLAKE2B a48aec0e4fe0de58169bccb994bcf0c19d8973d69496e2c19a4c9f8463ba76aa79312548d59bc7a11bb5a7ec6961c5cbdd97e05094cd7aae4e53928e5637aec8 SHA512 de1faf13bded5832d60748b48e98344a9e8fefc47bc2ff0e0090fc2579ee2d760ba65546691449c1d86d95de1a27681ecd23ac7de42e34f21449060310f79ddc
+EBUILD ipython-7.24.1-r1.ebuild 3825 BLAKE2B e0f9b68972935211f42b9f3ca23e463282a45d0ea9bc4ea758c180a15516f32f20584930a971d99d976da5d8005df7c507df3c25829511c4dfa39b2b527756ba SHA512 7a3c51f00027c4560b8ea7aecf6cfb508817276a2602ff3354c06cf1c945d65979e1a35834ecb3882284397bc5cb6977406009bf0ef9d0d5af5eb3441f8d42b8
 EBUILD ipython-7.24.1.ebuild 3842 BLAKE2B 93e66fbd1e931294001afdad43c3a46f1aa0518fe17b2ba8dd04e928333ac7010f1cf505a67d8a79756f235833a1987027c19892b5b0a212575e8c1012ccce0d SHA512 86423c9f303347a54ba84a1eeeef3d67a4e622b56f4c42c314576056fdee9bf28bd5b19d40340c975d5f72ce34249fc0ef6a3714667ef73dd5b536336825d305
 MISC metadata.xml 2882 BLAKE2B 189477b4ccde9051b61d2a4ff5134907886795f97c5201fc2bf9c012526333151931a1445b6315f286474b71af84253033cbe9bf89bffa7813bfa49a4a07ef6c SHA512 f54fef4552d09a03a8d186c45f917c091928f1de84dfbdd80f1db80912d616d509f10c588de533916d9c494f5b3ca5e6e50a6d8b8c59ea47781311ad4319442a
diff --git a/dev-python/ipython/ipython-7.24.1-r1.ebuild b/dev-python/ipython/ipython-7.24.1-r1.ebuild
new file mode 100644
index 000000000000..54a061fe2da0
--- /dev/null
+++ b/dev-python/ipython/ipython-7.24.1-r1.ebuild
@@ -0,0 +1,139 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DISTUTILS_USE_SETUPTOOLS=no
+PYTHON_COMPAT=( python3_{7..9} )
+PYTHON_REQ_USE='readline,sqlite,threads(+)'
+
+inherit distutils-r1 optfeature virtualx
+
+DESCRIPTION="Advanced interactive shell for Python"
+HOMEPAGE="https://ipython.org/ https://github.com/ipython/ipython/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="doc examples matplotlib notebook nbconvert qt5 +smp test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-python/backcall[${PYTHON_USEDEP}]
+	dev-python/decorator[${PYTHON_USEDEP}]
+	>=dev-python/jedi-0.16[${PYTHON_USEDEP}]
+	>=dev-python/pexpect-4.3[${PYTHON_USEDEP}]
+	dev-python/pickleshare[${PYTHON_USEDEP}]
+	>=dev-python/prompt_toolkit-2[${PYTHON_USEDEP}]
+	<dev-python/prompt_toolkit-3.1[${PYTHON_USEDEP}]
+	dev-python/pygments[${PYTHON_USEDEP}]
+	dev-python/traitlets[${PYTHON_USEDEP}]
+	matplotlib? (
+		dev-python/matplotlib[${PYTHON_USEDEP}]
+		dev-python/matplotlib-inline[${PYTHON_USEDEP}]
+	)
+"
+
+BDEPEND="
+	test? (
+		app-text/dvipng[truetype]
+		>=dev-python/ipykernel-5.1.0[${PYTHON_USEDEP}]
+		dev-python/matplotlib[${PYTHON_USEDEP}]
+		dev-python/matplotlib-inline[${PYTHON_USEDEP}]
+		dev-python/nbformat[${PYTHON_USEDEP}]
+		dev-python/nose[${PYTHON_USEDEP}]
+		>=dev-python/numpy-1.17[${PYTHON_USEDEP}]
+		dev-python/requests[${PYTHON_USEDEP}]
+		dev-python/testpath[${PYTHON_USEDEP}]
+	)
+	doc? (
+		>=dev-python/ipykernel-5.1.0[${PYTHON_USEDEP}]
+		dev-python/matplotlib[${PYTHON_USEDEP}]
+		>=dev-python/sphinx-2[${PYTHON_USEDEP}]
+		dev-python/sphinx_rtd_theme[${PYTHON_USEDEP}]
+	)"
+
+distutils_enable_tests pytest
+
+RDEPEND+="
+	nbconvert? ( dev-python/nbconvert[${PYTHON_USEDEP}] )"
+PDEPEND="
+	notebook? (
+		dev-python/notebook[${PYTHON_USEDEP}]
+		dev-python/ipywidgets[${PYTHON_USEDEP}]
+		dev-python/widgetsnbextension[${PYTHON_USEDEP}]
+	)
+	qt5? ( dev-python/qtconsole[${PYTHON_USEDEP}] )
+	smp? (
+		>=dev-python/ipykernel-5.1.0[${PYTHON_USEDEP}]
+		>=dev-python/ipyparallel-6.2.3[${PYTHON_USEDEP}]
+	)"
+
+PATCHES=( "${FILESDIR}"/2.1.0-substitute-files.patch )
+
+DISTUTILS_IN_SOURCE_BUILD=1
+
+python_prepare_all() {
+	# Remove out of date insource files
+	rm IPython/extensions/cythonmagic.py || die
+	rm IPython/extensions/rmagic.py || die
+
+	# Prevent un-needed download during build
+	if use doc; then
+		sed -e "/^    'sphinx.ext.intersphinx',/d" -i docs/source/conf.py || die
+	fi
+
+	# Rename the test directory to reduce sys.path pollution
+	# https://github.com/ipython/ipython/issues/12892
+	mv IPython/extensions/{,ipython_}tests || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	if use doc; then
+		emake -C docs html_noapi
+		HTML_DOCS=( docs/build/html/. )
+	fi
+}
+
+src_test() {
+	virtx distutils-r1_src_test
+}
+
+python_install() {
+	distutils-r1_python_install
+
+	# Create ipythonX.Y symlinks.
+	# TODO:
+	# 1. do we want them for pypy? No.  pypy has no numpy
+	# 2. handle it in the eclass instead (use _python_ln_rel).
+	# With pypy not an option the dosym becomes unconditional
+	dosym ../lib/python-exec/${EPYTHON}/ipython \
+		/usr/bin/ipython${EPYTHON#python}
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	if use examples; then
+		dodoc -r examples
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+}
+
+pkg_postinst() {
+	optfeature "sympyprinting" dev-python/sympy
+	optfeature "cythonmagic" dev-python/cython
+	optfeature "%lprun magic command" dev-python/line_profiler
+	optfeature "%mprun magic command" dev-python/memory_profiler
+
+	if use nbconvert; then
+		if ! has_version app-text/pandoc ; then
+			einfo "Node.js will be used to convert notebooks to other formats"
+			einfo "like HTML. Support for that is still experimental. If you"
+			einfo "encounter any problems, please use app-text/pandoc instead."
+		fi
+	fi
+}