gentoo auto-resync : 11:10:2022 - 01:37:00

3 files changed, 2 insertions, 174 deletions

diff --git a/dev-python/ipython/Manifest b/dev-python/ipython/Manifest
index c2cabe2bb314..bc20e4ff5029 100644
--- a/dev-python/ipython/Manifest
+++ b/dev-python/ipython/Manifest
@@ -1,6 +1,4 @@
 AUX 2.1.0-substitute-files.patch 1017 BLAKE2B 70577eb950a18345804a2a4b750bd233dc6a0b6bbdb524dfc66e0f4a7c69b0eeb2d35efb9d1845d567a11d1afa7881068b4757e42b9baf24dc01ba3026608a38 SHA512 fc4c9e12267ac5f04a2e16ad27334a093638538b8149ff380099fcbeb674a276ab9eb624a508010e37f82c05d5f7ab527a80e386b3e7b61c123ecb8effd9d542
-DIST ipython-8.4.0.tar.gz 5314601 BLAKE2B 4a5804ad115b45568ddbc0b8fcd181ae0088690ae2d7dda8580588d1e1caa087582a279449142e0144568815270b3a9476893525c0e90320f9ec580a06126d1d SHA512 975915ee64ce6f3fc9bcda383c784759dd8b19151428b10ef92020097718c6e2a9804a00fe02bd541b845eca146c63a672f25ad4f00ec5302b3c61ae0c6935ce
 DIST ipython-8.5.0.tar.gz 5319096 BLAKE2B 6ab330ffe99611478bdcf1211a500c08edd4aff802a1121156c302cb8a49b9c5f2fa98012dbaf80996574789bdb98d87924492181e45f00f46f600789c1ae6e4 SHA512 9339507fbe229d83f4c41b79257a7b40890d9d0601692521a61dc777c040a6d22d131014d660ffc9ba79f7128f579082473642f47b86e59a038f79c6553c8186
-EBUILD ipython-8.4.0.ebuild 5022 BLAKE2B 7fde2660f84fe642531c604f0825d6432e3905cf08325743c220224445aed5db900f052f5bb3e18d53e66c2efe2c669065caa116fc20433c68a1b7e16d6c222b SHA512 02591875dc098943885a53452c3c1669ab9e273d6d229975120ebcbc83a80641df70ace2bd165e8a44950ebafffa0ff9dec33d84083c779ec1f1aa95afb3758a
-EBUILD ipython-8.5.0.ebuild 4767 BLAKE2B 0e3425ab089eb396da2f5c08b91173a188b99db622f8d000962fcb52177e173590e9aeaf764e741d139cfffe4753819a24980f9ba0883a5e6512a2e698110839 SHA512 7eaca963584a2911146e7b3b90ec064b4c1faef86b9ebab26fdb65732da45d39c8fe0d5076e4920e48da1ca7615849935a7e86969c6346de2bdd13021d7ae25c
+EBUILD ipython-8.5.0.ebuild 4759 BLAKE2B fd691661eb3ab9b6b968f5b9613c8439865539cd9d648bbad6bf5b74675ff0b3cf56e947caa669570d361f5e83f14e231efff188a98019fe9df8967528d7f7a5 SHA512 fe71942d900558e00de9bbef66b4d7990e68f773546e604585c39965ea62d18e5f4bd62cde9006b1f267d4a55d6e50d7dbb543bac82a720d584cf6c06cda4f29
 MISC metadata.xml 2882 BLAKE2B 65c42e1947d9ae11468518194986d3ffb3c5f8ba8b5c801e6ca6a01fc2fbbb87e300a5884009caf44ccb326cdc39e07ceb6537a001a1b2ecd5c97dbb5f86ec62 SHA512 f0a488400b4f55827aee200c3ea893a953f45909c8d9a5bf73a551e56a6f120ee732035c7e62ce6cbbb60b1337185306e62123c1527c4f8fe5592751933f2874
diff --git a/dev-python/ipython/ipython-8.4.0.ebuild b/dev-python/ipython/ipython-8.4.0.ebuild
deleted file mode 100644
index 6d7e8a70c07f..000000000000
--- a/dev-python/ipython/ipython-8.4.0.ebuild
+++ /dev/null
@@ -1,170 +0,0 @@
-# Copyright 1999-2022 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-DISTUTILS_USE_PEP517=setuptools
-PYTHON_COMPAT=( python3_{8..10} )
-PYTHON_REQ_USE='readline,sqlite,threads(+)'
-
-inherit distutils-r1 optfeature virtualx
-
-DESCRIPTION="Advanced interactive shell for Python"
-HOMEPAGE="https://ipython.org/ https://github.com/ipython/ipython/"
-SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
-
-LICENSE="BSD"
-SLOT="0"
-KEYWORDS="amd64 arm arm64 hppa ~ia64 ppc ppc64 ~riscv ~s390 sparc x86"
-IUSE="doc examples matplotlib notebook nbconvert qt5 +smp test"
-RESTRICT="!test? ( test )"
-
-RDEPEND="
-	dev-python/backcall[${PYTHON_USEDEP}]
-	dev-python/decorator[${PYTHON_USEDEP}]
-	>=dev-python/jedi-0.16[${PYTHON_USEDEP}]
-	dev-python/matplotlib[${PYTHON_USEDEP}]
-	dev-python/matplotlib-inline[${PYTHON_USEDEP}]
-	>=dev-python/pexpect-4.3[${PYTHON_USEDEP}]
-	dev-python/pickleshare[${PYTHON_USEDEP}]
-	>=dev-python/prompt_toolkit-2[${PYTHON_USEDEP}]
-	<dev-python/prompt_toolkit-3.1[${PYTHON_USEDEP}]
-	>=dev-python/pygments-2.4.0[${PYTHON_USEDEP}]
-	dev-python/setuptools[${PYTHON_USEDEP}]
-	dev-python/stack_data[${PYTHON_USEDEP}]
-	>=dev-python/traitlets-5.0[${PYTHON_USEDEP}]
-"
-
-BDEPEND="
-	test? (
-		app-text/dvipng[truetype]
-		>=dev-python/ipykernel-5.1.0[${PYTHON_USEDEP}]
-		dev-python/matplotlib-inline[${PYTHON_USEDEP}]
-		dev-python/nbformat[${PYTHON_USEDEP}]
-		>=dev-python/numpy-1.19[${PYTHON_USEDEP}]
-		dev-python/requests[${PYTHON_USEDEP}]
-		dev-python/testpath[${PYTHON_USEDEP}]
-	)
-	doc? (
-		>=dev-python/ipykernel-5.1.0[${PYTHON_USEDEP}]
-		dev-python/matplotlib[${PYTHON_USEDEP}]
-		>=dev-python/sphinx-2[${PYTHON_USEDEP}]
-		dev-python/sphinx_rtd_theme[${PYTHON_USEDEP}]
-	)
-"
-
-distutils_enable_tests pytest
-
-RDEPEND+="
-	nbconvert? (
-		dev-python/nbconvert[${PYTHON_USEDEP}]
-	)
-"
-PDEPEND="
-	notebook? (
-		dev-python/notebook[${PYTHON_USEDEP}]
-		dev-python/ipywidgets[${PYTHON_USEDEP}]
-		dev-python/widgetsnbextension[${PYTHON_USEDEP}]
-	)
-	qt5? ( dev-python/qtconsole[${PYTHON_USEDEP}] )
-	smp? (
-		>=dev-python/ipykernel-5.1.0[${PYTHON_USEDEP}]
-		>=dev-python/ipyparallel-6.2.3[${PYTHON_USEDEP}]
-	)
-"
-
-PATCHES=( "${FILESDIR}"/2.1.0-substitute-files.patch )
-
-python_prepare_all() {
-	# Remove out of date insource files
-	#rm IPython/extensions/cythonmagic.py || die
-	#rm IPython/extensions/rmagic.py || die
-
-	# Prevent un-needed download during build
-	if use doc; then
-		sed -e "/^    'sphinx.ext.intersphinx',/d" -i docs/source/conf.py || die
-	fi
-
-	# Rename the test directory to reduce sys.path pollution
-	# https://github.com/ipython/ipython/issues/12892
-	mv IPython/extensions/{,ipython_}tests || die
-
-	if ! grep -q __legacy__ pyproject.toml; then
-		die "pyproject.toml changed, please recheck"
-	fi
-
-	# remove pyproject.toml that specifies incorrect backend; since
-	# the package actually requires the legacy backend, force it implicitly
-	rm pyproject.toml || die
-
-	distutils-r1_python_prepare_all
-}
-
-python_compile_all() {
-	if use doc; then
-		emake -C docs html_noapi
-		HTML_DOCS=( docs/build/html/. )
-	fi
-}
-
-src_test() {
-	virtx distutils-r1_src_test
-}
-
-python_test() {
-	local -x IPYTHON_TESTING_TIMEOUT_SCALE=20
-	local EPYTEST_DESELECT=(
-		# Internet
-		IPython/core/display.py::IPython.core.display.Image.__init__
-		# TODO: looks to be a regression due to a newer dep
-		IPython/core/tests/test_oinspect.py::test_class_signature
-		IPython/core/tests/test_oinspect.py::test_render_signature_long
-		# TODO
-		IPython/extensions/ipython_tests/test_autoreload.py::TestAutoreload::test_smoketest_aimport
-		IPython/extensions/ipython_tests/test_autoreload.py::TestAutoreload::test_smoketest_autoreload
-	)
-	[[ ${EPYTHON} == python3.10 ]] && EPYTEST_DESELECT+=(
-		# TODO
-		IPython/core/tests/test_completer.py::TestCompleter::test_all_completions_dups
-		IPython/core/tests/test_completer.py::TestCompleter::test_deduplicate_completions
-	)
-	# nonfatal implied by virtx
-	nonfatal epytest || die "Tests failed with ${EPYTHON}"
-}
-
-python_install() {
-	distutils-r1_python_install
-
-	# Create ipythonX.Y symlinks.
-	# TODO:
-	# 1. do we want them for pypy? No.  pypy has no numpy
-	# 2. handle it in the eclass instead (use _python_ln_rel).
-	# With pypy not an option the dosym becomes unconditional
-	dosym ../lib/python-exec/${EPYTHON}/ipython \
-		/usr/bin/ipython${EPYTHON#python}
-}
-
-python_install_all() {
-	distutils-r1_python_install_all
-
-	if use examples; then
-		dodoc -r examples
-		docompress -x /usr/share/doc/${PF}/examples
-	fi
-}
-
-pkg_postinst() {
-	optfeature "code formatting" dev-python/black
-	optfeature "sympyprinting" dev-python/sympy
-	optfeature "cythonmagic" dev-python/cython
-	optfeature "%lprun magic command" dev-python/line_profiler
-	optfeature "%mprun magic command" dev-python/memory_profiler
-
-	if use nbconvert; then
-		if ! has_version app-text/pandoc ; then
-			einfo "Node.js will be used to convert notebooks to other formats"
-			einfo "like HTML. Support for that is still experimental. If you"
-			einfo "encounter any problems, please use app-text/pandoc instead."
-		fi
-	fi
-}
diff --git a/dev-python/ipython/ipython-8.5.0.ebuild b/dev-python/ipython/ipython-8.5.0.ebuild
index bf72d46c9cb2..3afaf0497341 100644
--- a/dev-python/ipython/ipython-8.5.0.ebuild
+++ b/dev-python/ipython/ipython-8.5.0.ebuild
@@ -15,7 +15,7 @@ SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
 
 LICENSE="BSD"
 SLOT="0"
-KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+KEYWORDS="amd64 arm arm64 hppa ~ia64 ppc ppc64 ~riscv ~s390 sparc x86"
 IUSE="doc examples matplotlib notebook nbconvert qt5 +smp test"
 RESTRICT="!test? ( test )"