gentoo auto-resync : 17:05:2024 - 00:01:35

1 files changed, 48 insertions, 0 deletions

diff --git a/dev-python/fsspec/fsspec-2024.5.0.ebuild b/dev-python/fsspec/fsspec-2024.5.0.ebuild
new file mode 100644
index 000000000000..d5b9c6d035f3
--- /dev/null
+++ b/dev-python/fsspec/fsspec-2024.5.0.ebuild
@@ -0,0 +1,48 @@
+# Copyright 2020-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{10..12} )
+
+inherit distutils-r1 pypi
+
+MY_P=filesystem_spec-${PV}
+DESCRIPTION="A specification that python filesystems should adhere to"
+HOMEPAGE="
+	https://github.com/fsspec/filesystem_spec/
+	https://pypi.org/project/fsspec/
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86"
+
+BDEPEND="
+	dev-python/hatch-vcs[${PYTHON_USEDEP}]
+	test? (
+		dev-python/aiohttp[${PYTHON_USEDEP}]
+		dev-python/numpy[${PYTHON_USEDEP}]
+		dev-python/pytest-asyncio[${PYTHON_USEDEP}]
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+		dev-python/pytest-rerunfailures[${PYTHON_USEDEP}]
+		dev-python/requests[${PYTHON_USEDEP}]
+		dev-python/tqdm[${PYTHON_USEDEP}]
+		dev-vcs/git
+	)
+"
+
+# Note: this package is not xdist-friendly
+distutils_enable_tests pytest
+
+src_test() {
+	git config --global user.email "you@example.com" || die
+	git config --global user.name "Your Name" || die
+	distutils-r1_src_test
+}
+
+python_test() {
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest -p asyncio -p pytest_mock -o tmp_path_retention_policy=all
+}