gentoo resync : 14.07.2018

1 files changed, 47 insertions, 0 deletions

diff --git a/dev-python/enzyme/enzyme-9999.ebuild b/dev-python/enzyme/enzyme-9999.ebuild
new file mode 100644
index 000000000000..7f2df624691c
--- /dev/null
+++ b/dev-python/enzyme/enzyme-9999.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python{2_7,3_4,3_5,3_6} )
+PYTHON_REQ_USE='xml(+)'
+
+inherit distutils-r1 git-r3
+
+DESCRIPTION="Python video metadata parser"
+HOMEPAGE="https://github.com/Diaoul/enzyme https://pypi.org/project/enzyme/"
+EGIT_REPO_URI="https://github.com/Diaoul/${PN}.git"
+SRC_URI="test? ( mirror://sourceforge/matroska/test_files/matroska_test_w1_1.zip )"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS=""
+IUSE="test"
+
+RDEPEND="dev-python/setuptools[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}
+	test? (
+		app-arch/unzip
+		dev-python/pyyaml[${PYTHON_USEDEP}]
+		dev-python/requests[${PYTHON_USEDEP}]
+	)
+"
+
+src_unpack() {
+	default_src_unpack
+	git-r3_src_unpack
+}
+
+python_prepare_all() {
+	if use test; then
+		mkdir enzyme/tests/test_{mkv,parsers} || die
+		ln -s "${WORKDIR}"/test*.mkv enzyme/tests/test_mkv/ || die
+		ln -s "${WORKDIR}"/test*.mkv enzyme/tests/test_parsers/ || die
+	fi
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	esetup.py test
+}