reinit the tree, so we can have metadata

1 files changed, 45 insertions, 0 deletions

diff --git a/dev-python/clang-python/clang-python-5.0.0.ebuild b/dev-python/clang-python/clang-python-5.0.0.ebuild
new file mode 100644
index 000000000000..20a45b1a0c78
--- /dev/null
+++ b/dev-python/clang-python/clang-python-5.0.0.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 )
+inherit python-r1
+
+DESCRIPTION="Python bindings for sys-devel/clang"
+HOMEPAGE="https://llvm.org/"
+SRC_URI="https://releases.llvm.org/${PV/_//}/cfe-${PV/_/}.src.tar.xz"
+
+LICENSE="UoI-NCSA"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="test"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+# The module is opening libclang.so directly, and doing some blasphemy
+# on top of it.
+RDEPEND="
+	>=sys-devel/clang-${PV}:*
+	!sys-devel/llvm:0[clang(-),python(-)]
+	!sys-devel/clang:0[python(-)]
+	${PYTHON_DEPS}"
+DEPEND="${RDEPEND}
+	test? ( dev-python/nose[${PYTHON_USEDEP}] )"
+
+S=${WORKDIR}/cfe-${PV/_/}.src/bindings/python
+
+src_prepare() {
+	default
+
+	# move to the correct subdirectory
+	# https://reviews.llvm.org/D37378
+	mv tests/{,cindex/}test_exception_specification_kind.py || die
+}
+
+src_test() {
+	python_foreach_impl nosetests -v || die
+}
+
+src_install() {
+	python_foreach_impl python_domodule clang
+}