reinit the tree, so we can have metadata

1 files changed, 53 insertions, 0 deletions

diff --git a/dev-python/cairocffi/cairocffi-0.8.0.ebuild b/dev-python/cairocffi/cairocffi-0.8.0.ebuild
new file mode 100644
index 000000000000..00e16dec7530
--- /dev/null
+++ b/dev-python/cairocffi/cairocffi-0.8.0.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="6"
+
+PYTHON_COMPAT=( python2_7 python3_{4,5,6} pypy )
+
+inherit distutils-r1 virtualx
+
+MY_PN="${PN}"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="CFFI-based drop-in replacement for Pycairo"
+HOMEPAGE="https://github.com/Kozea/cairocffi"
+SRC_URI="mirror://pypi/${MY_P:0:1}/${MY_PN}/${MY_P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+IUSE="doc test"
+
+RDEPEND="
+	$(python_gen_cond_dep '>=dev-python/cffi-1.1.0:=[${PYTHON_USEDEP}]' 'python*')
+	>=dev-python/xcffib-0.3.2[${PYTHON_USEDEP}]
+	x11-libs/cairo:0=
+	x11-libs/gdk-pixbuf[jpeg]
+	$(python_gen_cond_dep '>=virtual/pypy-2.6.0' pypy )"
+
+DEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+	test? (
+		${RDEPEND}
+		dev-python/pytest[${PYTHON_USEDEP}]
+	)
+	$(python_gen_cond_dep '>=virtual/pypy-2.6.0' pypy )"
+
+PATCHES=( "${FILESDIR}"/${P}-tests.patch )
+
+S="${WORKDIR}/${MY_P}"
+
+python_compile_all() {
+	use doc && esetup.py build_sphinx
+}
+
+python_test() {
+	virtx py.test -v --pyargs cairocffi || die "testsuite failed under ${EPYTHON}"
+}
+
+python_install_all() {
+	use doc && HTML_DOCS=( docs/_build/html/. )
+	distutils-r1_python_install_all
+}