gentoo auto-resync : 21:06:2024 - 00:11:18

4 files changed, 106 insertions, 0 deletions

diff --git a/dev-python/btrfsutil/Manifest b/dev-python/btrfsutil/Manifest
new file mode 100644
index 000000000000..590ffa52d0f4
--- /dev/null
+++ b/dev-python/btrfsutil/Manifest
@@ -0,0 +1,7 @@
+DIST btrfs-progs-v6.8.1.tar.sign 566 BLAKE2B 843eada2b00a2370522edc95d79bcfed88bd24233e647946d4807322550593e4d5f5bb5efa6652c754dd0965dc3e389bc97698a0bd8fc5d0e850bea94de98e72 SHA512 84ebaa6ec27aa5bc87a323f5c6cc82a860fada7311ab8319127de3592294c1076d25959e412f8387d54bad3b8ff838ce39c4db4b04a658b2de2eaa7c976e2b09
+DIST btrfs-progs-v6.8.1.tar.xz 2652968 BLAKE2B 34406dedc6d97bd94a498c3bbb424d34a59b8251b37f9a40a87740f96db77780a4cd76c88055b4d9e4f673b4a3621503a6bedb67ceaf20870fb26c10f49b74e0 SHA512 b5f0694e56eecf1956313b3406610c2e22658ace51a636d79efe996780bb0b03fed95e68a8c9a11dd8649958c0e7dbc7417bb479859365d47b52e478f6830d46
+DIST btrfs-progs-v6.9.tar.sign 566 BLAKE2B a2e26047775bcc407b8f5aa8b08b0708a01c84a8cd649e50a935e15d04e2ee917010fc98df0dfb80320ee25a8dbfbbbabbb1f155489f32391544100956ba9636 SHA512 1e8304b3df013a841e82a8656361946914d35f680b5bc547c1599fdd98a75b66e2b1f869c8b043d7532182318c2183e699a9d6101ab4b1544618d2c8a25362e1
+DIST btrfs-progs-v6.9.tar.xz 2663052 BLAKE2B 9fad691327b6290b3ba0e1a638576b65e4e4d6c8f32549ea0f10188fdb40028315abf5e330976ff7a5efb6a258d0008e7602ae81ba0339888f474dc056791798 SHA512 e97907b377040371f4742a45345ec720e0cb8e0cf9ee5fdc60618ce2bc76f572725ec32e1a178fd57534f73affd3eeb5e6cfebf23734f04583bbbef858d913b2
+EBUILD btrfsutil-6.8.1.ebuild 1114 BLAKE2B 5d5971d8c54b2e7b7505377f20b55fdee23d62f912331a65080f368e6f5217107a1a69743c8dcf993990223f240e5bde8dbd06f16d0782e4ad09f6b5f51872cb SHA512 1bcb812baae60803bc00b2084d32635e83c8c235959455e8716a34555b105a4d688a9200f440248774dbcb1d370eb5db329854cf772c4126dbbdd671453eb78a
+EBUILD btrfsutil-6.9.ebuild 1238 BLAKE2B 1904eaec33f42d219dd58c5b51f7089e3e8c576d8115ccfdf1f56f961b8b9a5aeb83d04bb56085feb0888d8485f47e8281366bbec1021de7edb38027a971d73b SHA512 2246a860eaa1de64d17d76cfb27243c914211d1473573be9540883c6eae55cdf2545cb2d56624685c2a75a045bae302baa010cb68bab180584ef38bb6791b9cb
+MISC metadata.xml 306 BLAKE2B 94f20c2598ad4740c885d13b50ea0fed283f2272b3be78bdf31dc69fe536350d6ae709065164a3a4509b0e622f8f9e38723f874a7241312c6a21edfa4f8376b8 SHA512 e86e1320edf5688903321fff7a483de794a5cb4ced4197a8ccecd0cd09a0c5da2a33b73c06d40422f192de2a643b51ff3331d2e83dcf3ebe33bd613377311b9d
diff --git a/dev-python/btrfsutil/btrfsutil-6.8.1.ebuild b/dev-python/btrfsutil/btrfsutil-6.8.1.ebuild
new file mode 100644
index 000000000000..6da2d87766a8
--- /dev/null
+++ b/dev-python/btrfsutil/btrfsutil-6.8.1.ebuild
@@ -0,0 +1,43 @@
+# Copyright 2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..13} )
+VERIFY_SIG_OPENPGP_KEY_PATH=/usr/share/openpgp-keys/dsterba.asc
+
+inherit distutils-r1 verify-sig
+
+DESCRIPTION="Library for managing Btrfs filesystems"
+HOMEPAGE="https://github.com/kdave/btrfs-progs"
+
+MY_PN="btrfs-progs"
+MY_PV="v${PV/_/-}"
+MY_P="${MY_PN}-${MY_PV}"
+SRC_URI="
+	https://mirrors.edge.kernel.org/pub/linux/kernel/people/kdave/${MY_PN}/${MY_P}.tar.xz
+	verify-sig? ( https://mirrors.edge.kernel.org/pub/linux/kernel/people/kdave/${MY_PN}/${MY_P}.tar.sign )
+"
+S="${WORKDIR}/${MY_P}/libbtrfsutil/python"
+
+LICENSE="LGPL-2+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86"
+
+DEPEND="~sys-fs/btrfs-progs-${PV}"
+RDEPEND="${DEPEND}"
+
+distutils_enable_tests unittest
+
+RDEPEND+=" !sys-fs/btrfs-progs[python(-)]"
+
+src_unpack() {
+	if use verify-sig ; then
+		verify-sig_verify_detached \
+			<(xz -cd "${DISTDIR}"/${MY_P}.tar.xz) \
+			"${DISTDIR}"/${MY_P}.tar.sign
+	fi
+	default
+}
diff --git a/dev-python/btrfsutil/btrfsutil-6.9.ebuild b/dev-python/btrfsutil/btrfsutil-6.9.ebuild
new file mode 100644
index 000000000000..15d87b143716
--- /dev/null
+++ b/dev-python/btrfsutil/btrfsutil-6.9.ebuild
@@ -0,0 +1,46 @@
+# Copyright 2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..13} )
+VERIFY_SIG_OPENPGP_KEY_PATH=/usr/share/openpgp-keys/dsterba.asc
+
+inherit distutils-r1 verify-sig
+
+DESCRIPTION="Library for managing Btrfs filesystems"
+HOMEPAGE="https://github.com/kdave/btrfs-progs"
+
+MY_PN="btrfs-progs"
+MY_PV="v${PV/_/-}"
+MY_P="${MY_PN}-${MY_PV}"
+SRC_URI="
+	https://mirrors.edge.kernel.org/pub/linux/kernel/people/kdave/${MY_PN}/${MY_P}.tar.xz
+	verify-sig? ( https://mirrors.edge.kernel.org/pub/linux/kernel/people/kdave/${MY_PN}/${MY_P}.tar.sign )
+"
+S="${WORKDIR}/${MY_P}/libbtrfsutil/python"
+
+LICENSE="LGPL-2+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86"
+
+DEPEND="~sys-fs/btrfs-progs-${PV}"
+RDEPEND="${DEPEND}"
+
+distutils_enable_tests unittest
+
+RDEPEND+=" !sys-fs/btrfs-progs[python(-)]"
+
+src_unpack() {
+	# Upstream sign the decompressed .tar
+	if use verify-sig; then
+		einfo "Unpacking ${MY_P}.tar.xz ..."
+		verify-sig_verify_detached - "${DISTDIR}"/${MY_P}.tar.sign \
+			< <(xz -cd "${DISTDIR}"/${MY_P}.tar.xz | tee >(tar -x))
+		assert "Unpack failed"
+	else
+		default
+	fi
+}
diff --git a/dev-python/btrfsutil/metadata.xml b/dev-python/btrfsutil/metadata.xml
new file mode 100644
index 000000000000..eb3c989f23bf
--- /dev/null
+++ b/dev-python/btrfsutil/metadata.xml
@@ -0,0 +1,10 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="project">
+		<email>base-system@gentoo.org</email>
+	</maintainer>
+	<upstream>
+		<remote-id type="github">kdave/btrfs-progs</remote-id>
+	</upstream>
+</pkgmetadata>