gentoo resync : 14.07.2018

4 files changed, 181 insertions, 0 deletions

diff --git a/dev-python/blaze/Manifest b/dev-python/blaze/Manifest
new file mode 100644
index 000000000000..b8b3988b90bd
--- /dev/null
+++ b/dev-python/blaze/Manifest
@@ -0,0 +1,5 @@
+DIST blaze-0.10.2.tar.gz 9681767 BLAKE2B 9972d0f9bb00ce462f20673e9e164d504bc1157730bcb36a42b53ed1523a73bde36a1858ba7df1f813c126291251c6170da8ac70aaaac8932206de5f3e063a10 SHA512 01b7c5563f928c336f13eb13c6397f1089bca7c1cf0824da672acdabf28b18356c52678c58b2fa7af303601c6013e9d6f4fe26359ee6ab9a01f8b735c7d24a56
+DIST blaze-0.11.3.tar.gz 9691443 BLAKE2B 13734e3b2f63ad044991644a4c8243b449c5179a80efdaa5faf6ecf443434bec7a00953f0f17d73885b9e9fa506e72a9bc369380d2d7a561f5da064d8339e03f SHA512 030079e5d3f17355dac588154ffb7ba7993935dfd39bce141341b6e2b9a17f812982ce83776ac1e4224649a343b58615621347ba65e5aba2ca2e568d755f276f
+EBUILD blaze-0.10.2.ebuild 3169 BLAKE2B 251c9d778c6a20502395e5eba9d9269a3adfb3a7adc532ae0e41f8c5ec0495fdf9f61dab81de53967d62f80ebaf139e25dcabcb03175a432faeb32ca89454157 SHA512 53c7041857c51de3cc55485f4a235f92c44320ac1c802fa37b6bd716ff0a2e5e275d2814eb7324da169761f096f440d2601b504ecbd2ed5ae50ca90a4778dd98
+EBUILD blaze-0.11.3.ebuild 2170 BLAKE2B e28ec9f152270027a8e1437df60d23d1ed999d3708942d87373e7c96c308bd85a58c9179ebe8210195d7c4b76a074e6cdd6947682a7a3fcca03077c63da68769 SHA512 b42644dc3720168bb1d6fb4b6f818543cc0ccc9a35a345d69606f3d2ef30027f048aa158c98876491333867f919302fe9c141db2c9f66a7a3040ec90c963144f
+MISC metadata.xml 619 BLAKE2B fcf9cafadca88ba8f5465f681c3fc87159a1e8f7fde68007f85d5f424682fcf4fae81b6002c73043f1fcb6c492e618277a2daaa7140086324ad31d84cd97004a SHA512 2fe8804a4e526991e088834f7d3a49a1273c8da255df259a3552b4a4613bf0386bf464e025e191eb0087258b53a003efb0b6ed1afdb5ceb5e9e7c1c9ebeda7b8
diff --git a/dev-python/blaze/blaze-0.10.2.ebuild b/dev-python/blaze/blaze-0.10.2.ebuild
new file mode 100644
index 000000000000..8acdc8f11a4a
--- /dev/null
+++ b/dev-python/blaze/blaze-0.10.2.ebuild
@@ -0,0 +1,84 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=5
+
+PYTHON_COMPAT=( python{2_7,3_4,3_5} )
+
+inherit distutils-r1
+
+DESCRIPTION="Next generation Python numpy"
+HOMEPAGE="http://blaze.pydata.org/"
+SRC_URI="https://github.com/ContinuumIO/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="amd64 x86 ~amd64-linux ~x86-linux"
+
+# Currently doc build fails, reason now, attempt to import mystery modules in datashape
+# Leaving doc build content in case this is fixed
+IUSE="examples test"
+
+# pyspark appears an optional dep not in portage. pyskit appears to be dropped
+# some packages including pyparsing appear required despite their absence from requirements.txt
+
+RDEPEND="
+	dev-python/datashape[${PYTHON_USEDEP}]
+	>=dev-python/dynd-python-0.6.5[${PYTHON_USEDEP}]
+	>=dev-python/numpy-1.7[${PYTHON_USEDEP}]
+	dev-python/pyparsing[${PYTHON_USEDEP}]
+	dev-python/toolz[${PYTHON_USEDEP}]
+	dev-python/cytoolz[${PYTHON_USEDEP}]
+	>=dev-python/pandas-0.15.0[${PYTHON_USEDEP}]
+	dev-python/h5py[${PYTHON_USEDEP}]
+	dev-python/unicodecsv[${PYTHON_USEDEP}]
+	>=dev-python/multipledispatch-0.4.7[${PYTHON_USEDEP}]
+	dev-python/requests[${PYTHON_USEDEP}]
+	>=dev-python/flask-0.10.1[${PYTHON_USEDEP}]
+	dev-python/flask-cors[${PYTHON_USEDEP}]
+	>=dev-python/sqlalchemy-0.8.0[${PYTHON_USEDEP}]
+	>=dev-python/pytables-3.0.0[${PYTHON_USEDEP}]
+	>=dev-python/pymongo-2.8[${PYTHON_USEDEP}]
+	dev-python/xlrd[${PYTHON_USEDEP}]
+	dev-python/psutil[${PYTHON_USEDEP}]
+	dev-python/into[${PYTHON_USEDEP}]
+	dev-python/networkx[${PYTHON_USEDEP}]
+	dev-python/numba[${PYTHON_USEDEP}]
+	dev-python/bcolz[${PYTHON_USEDEP}]
+	>=dev-python/odo-0.4[${PYTHON_USEDEP}]"
+DEPEND="
+	>=dev-python/cython-0.18[${PYTHON_USEDEP}]
+	test? (  ${RDEPEND}
+		dev-python/pytest[${PYTHON_USEDEP}]
+		dev-python/pyyaml[${PYTHON_USEDEP}]
+		dev-python/chardet[${PYTHON_USEDEP}]
+		dev-python/contextlib2[${PYTHON_USEDEP}]
+		dev-python/dask[${PYTHON_USEDEP}] )
+	"
+# It was found on testing that dev-python/chardet is required for tests
+# despite not being inlcuded in requirements.txt
+# The doc build now fails due to dep bokeh failing to emerge. Deleted.
+
+python_test() {
+	# https://github.com/ContinuumIO/blaze/issues/1117
+	# skip test requiring a server daemon
+	# Tally of known failure reduced to one under py2.7 (test_highly_nested_repr)
+	# and 2 under py3. The failure of test_query_with_strings persists
+	# under python3 and appears to be unaddressed upstream.
+	# Changes in the suite in this version require PYTHONPATH set to ${S}
+	# to avoid spurious errors resulting from the change of path set by the eclass.
+
+	einfo "The test suite has 4 additional failures with package numba installed"
+	einfo "Upstream have been informed via /blaze/issues/1117 @ github.com/"
+	einfo "For optimum results, uninstall numba, but it counters protocol to exclude"
+	einfo "dev-python/numba from dependencies in the ebuild"
+
+	PYTHONPATH="${S}" py.test --ignore blaze/compute/tests/test_mongo_compute.py blaze \
+		|| die "Tests failed under ${EPYTHON}"
+}
+
+python_install_all() {
+	use examples && local EXAMPLES=( blaze/examples/. )
+
+	distutils-r1_python_install_all
+}
diff --git a/dev-python/blaze/blaze-0.11.3.ebuild b/dev-python/blaze/blaze-0.11.3.ebuild
new file mode 100644
index 000000000000..0eec45f052ee
--- /dev/null
+++ b/dev-python/blaze/blaze-0.11.3.ebuild
@@ -0,0 +1,75 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python{2_7,3_4,3_5,3_6} )
+
+inherit distutils-r1
+
+DESCRIPTION="Next generation Python numpy"
+HOMEPAGE="http://blaze.readthedocs.io/"
+SRC_URI="https://github.com/blaze/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="amd64 ~x86 ~amd64-linux ~x86-linux"
+
+IUSE="examples test"
+
+RDEPEND="
+	dev-python/bcolz[${PYTHON_USEDEP}]
+	dev-python/cytoolz[${PYTHON_USEDEP}]
+	dev-python/dask[${PYTHON_USEDEP}]
+	dev-python/datashape[${PYTHON_USEDEP}]
+	dev-python/dynd-python[${PYTHON_USEDEP}]
+	dev-python/flask[${PYTHON_USEDEP}]
+	dev-python/flask-cors[${PYTHON_USEDEP}]
+	dev-python/h5py[${PYTHON_USEDEP}]
+	dev-python/into[${PYTHON_USEDEP}]
+	dev-python/multipledispatch[${PYTHON_USEDEP}]
+	dev-python/networkx[${PYTHON_USEDEP}]
+	dev-python/numba[${PYTHON_USEDEP}]
+	dev-python/numpy[${PYTHON_USEDEP}]
+	dev-python/odo[${PYTHON_USEDEP}]
+	dev-python/pandas[${PYTHON_USEDEP}]
+	dev-python/psutil[${PYTHON_USEDEP}]
+	dev-python/pymongo[${PYTHON_USEDEP}]
+	dev-python/pyparsing[${PYTHON_USEDEP}]
+	dev-python/pytables[${PYTHON_USEDEP}]
+	dev-python/requests[${PYTHON_USEDEP}]
+	dev-python/sqlalchemy[${PYTHON_USEDEP}]
+	dev-python/toolz[${PYTHON_USEDEP}]
+	dev-python/unicodecsv[${PYTHON_USEDEP}]
+	dev-python/xlrd[${PYTHON_USEDEP}]
+"
+DEPEND="
+	dev-python/cython[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	test? ( ${RDEPEND}
+		dev-python/chardet[${PYTHON_USEDEP}]
+		dev-python/contextlib2[${PYTHON_USEDEP}]
+		dev-python/pytest[${PYTHON_USEDEP}]
+		dev-python/pyyaml[${PYTHON_USEDEP}]
+	)
+"
+
+python_test() {
+	cd "${BUILD_DIR}"/lib
+	# trying to skip a few tests which spill errors
+	py.test \
+		--ignore blaze/compute/tests/test_mongo_compute.py \
+		--ignore blaze/compute/tests/test_core_compute.py \
+		--ignore blaze/tests/test_interactive.py \
+		blaze || die "Tests failed under ${EPYTHON}"
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+	if use examples; then
+		insinto /usr/share/doc/${PF}
+		doins -r blaze/examples
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+	rm -r "${ED}"usr/lib*/*/*/blaze/examples || die
+}
diff --git a/dev-python/blaze/metadata.xml b/dev-python/blaze/metadata.xml
new file mode 100644
index 000000000000..28e878b0bff7
--- /dev/null
+++ b/dev-python/blaze/metadata.xml
@@ -0,0 +1,17 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="project">
+    <email>python@gentoo.org</email>
+    <name>Python</name>
+  </maintainer>
+  <longdescription lang="en">
+  Blaze is the next-generation of NumPy. It is designed as a
+  foundational set of abstractions on which to build out-of-core and
+  distributed algorithms over a wide variety of data sources and to
+  extend the structure of NumPy itself.
+</longdescription>
+  <upstream>
+    <remote-id type="github">ContinuumIO/blaze</remote-id>
+  </upstream>
+</pkgmetadata>