gentoo auto-resync : 10:10:2023 - 12:09:13

3 files changed, 274 insertions, 0 deletions

diff --git a/dev-lisp/Manifest.gz b/dev-lisp/Manifest.gz
index 24ba432fd6b6..ee2c02608111 100644
--- a/dev-lisp/Manifest.gz
+++ b/dev-lisp/Manifest.gz
diff --git a/dev-lisp/sbcl/Manifest b/dev-lisp/sbcl/Manifest
index 2873837316e8..9c91eca9f979 100644
--- a/dev-lisp/sbcl/Manifest
+++ b/dev-lisp/sbcl/Manifest
@@ -21,7 +21,10 @@ DIST sbcl-2.3.7-source.tar.bz2 7495739 BLAKE2B e0116b2f8a01cce77d177e840da23f6b2
 DIST sbcl-2.3.7-x86-64-linux-binary.tar.bz2 11807371 BLAKE2B bfea9daa9b20aad6ab4261af4b6c05fd5fb13d1416df390d240eae8554478eb599d6beefa989ac2904108241ca1971bc33a00bdd615d88833e4a5abec6725718 SHA512 da94e7136026cfedfbb2def7ba727372bc6e7aea47de9366a706cb522031f5c08fe149fd1727db18511f89b1022c1e3790ef3e83bcbfe4a76e4336c476b80079
 DIST sbcl-2.3.8-source.tar.bz2 7562146 BLAKE2B 2a936ff3c59bff059ae763665906beafb669871f0524f259494c605f2edaa91384f2a5489dae004d205b2b4508e72774e85a7af65a87f68e43fc2ac67baea1fc SHA512 ae718151d117df0b1f4a83ffbaa0508cec1bfa686462db3a2e84d06c93ca6cd1fbbaa685d82dc9cb3a2e7ef023df94b291c4160e9a5696e16886c616da645147
 DIST sbcl-2.3.8-x86-64-linux-binary.tar.bz2 11839819 BLAKE2B b01b4decf8860d7f29e8d37a0389e6637318151341840dccdd94e70d912818a9c05be5a4f2116b402732ddfa8113320ff8957348d772990c832de095b781d004 SHA512 ee22c7fbed0e86482e8c743f35c29feeb661f178d2c64e67b912ac47ccd04792ac8a88af724357aeace170dffbd95f41e408b7bc86b995dfec1bf34f75df6eb0
+DIST sbcl-2.3.9-source.tar.bz2 7574665 BLAKE2B 25a21948469d8c2974a19897a7e4c0aa2d2127360979feea76a22286392ce7a0acd37bb1518bb8625756d4b0620b3ecdaebc2e510be5906d92402184399dfe7c SHA512 34f565711e8bf71adb40c752f0bdb53b2e49714c148468ed7f2d2db1c50985513955b2718c49298169727c6cb2149eefd75409846561d446bf434ba7a6fc8545
+DIST sbcl-2.3.9-x86-64-linux-binary.tar.bz2 11859972 BLAKE2B 9defed8597fd0fa2e8ca570dcb3d0690b8b072b7f05b9fd314319a8a27939e06a33394a048c95badb2df3a97a57879d6141e631a087ff1ed87fb6f3e51a4071a SHA512 18d71964643da263a5dccb5e93764f2a679b75955332cfb94b0049aae1ad42efc91b397d787cdbf8a8967a50636a87a0d799e51fd76d9e05ccbfe102d258a868
 EBUILD sbcl-2.3.5.ebuild 9047 BLAKE2B 4d131f13136d90b8a8f09b2328ffe762eea33b28fde2e0195f78e5633c1d6de82c18e70857379eff298ee4a01da5f3e047938ceec234dccd10bd154372ca1b18 SHA512 eec1e639ea47dd37e681db5c897a317148bda2ef34be88fa49d17b931fc16731a204a52a5fab5ae6f4f2b55b78f44bea9885c9e475489e7d0bceb21a4506247d
 EBUILD sbcl-2.3.7.ebuild 9141 BLAKE2B 24d8ed38740c1abc21f1df4072a96eb8af2e2b0d3458f7a352eaaf0c982b700583c6159f90b393fd40be146a841983b0082dbdf65b633a0fef31cc8158eec3e1 SHA512 98bffd6bd815220edfacfbacf3788fb62bdb67f20ca565372155a53b3225a076e258ec1167e15b7965b7690a62bcb7f4abcd1603add3a8552a0ee82e882b0e13
 EBUILD sbcl-2.3.8.ebuild 9141 BLAKE2B 5aa262041023a3389e602216a8e97b4f2491eb331a8e6968db4922556f75846edbc6b5513137ab4d8a3c1e946621f6954db89e6426e342872d99845f0b595d2c SHA512 9645fc1fd0ac884fc75336158d4c88da13e957fdcaf52538cc967cdf6aa5626da7ff40b7770590612c9799fbf4e62665fb233c2f69900834ca7900455d024433
+EBUILD sbcl-2.3.9.ebuild 9141 BLAKE2B 84738d65e3aa35f7a0d10b00b11b0ac2ad7f0333ebabe61629163046e381660b51a2e33a7826e7094073b4308830e988401757e9464680ce81607595ae11e1b7 SHA512 4757bf680021867e27bed20add7f360bb029494cd772012c2900acadbf2a14b7ead3292a3ebe29d42f452ee83446a0f492c3b139d28a49b54d044f29d92033a7
 MISC metadata.xml 1429 BLAKE2B 59750e8f97481ee938def9de21017bb06b89b3ec72914f7d0e30f8b13cccf7124d23a6293d7b3ae3aff00d4e0564a3d20af6a98f9034aa31f24e42e6515ee055 SHA512 5ec54831af483785fd1f613295691380f1827af6cc63fa42e886839efe4dde0ad55f4b7ae655ec57d81500bf9fd6cef2edb62f92d738d55f8103836bbd260303
diff --git a/dev-lisp/sbcl/sbcl-2.3.9.ebuild b/dev-lisp/sbcl/sbcl-2.3.9.ebuild
new file mode 100644
index 000000000000..1c735263a61f
--- /dev/null
+++ b/dev-lisp/sbcl/sbcl-2.3.9.ebuild
@@ -0,0 +1,271 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit flag-o-matic pax-utils toolchain-funcs
+
+#same order as http://www.sbcl.org/platform-table.html
+BV_X86=1.4.3
+BV_AMD64=2.3.9
+BV_PPC=1.2.7
+BV_PPC64LE=1.5.8
+BV_SPARC=1.0.28
+BV_ALPHA=1.0.28
+BV_ARM=2.3.3
+BV_ARM64=1.4.2
+BV_X64_MACOS=1.2.11
+BV_PPC_MACOS=1.0.47
+BV_X86_SOLARIS=1.2.7
+BV_X64_SOLARIS=1.2.7
+BV_SPARC_SOLARIS=1.0.23
+
+DESCRIPTION="Steel Bank Common Lisp (SBCL) is an implementation of ANSI Common Lisp"
+HOMEPAGE="https://www.sbcl.org/ http://sbcl.sourceforge.net/"
+BSD_SOCKETS_TEST_PATCH=bsd-sockets-test-2.3.6.patch
+SRC_URI="mirror://sourceforge/sbcl/${P}-source.tar.bz2
+	https://dev.gentoo.org/~grozin/${BSD_SOCKETS_TEST_PATCH}.gz
+	!system-bootstrap? (
+		x86? ( mirror://sourceforge/sbcl/${PN}-${BV_X86}-x86-linux-binary.tar.bz2 )
+		amd64? ( mirror://sourceforge/sbcl/${PN}-${BV_AMD64}-x86-64-linux-binary.tar.bz2 )
+		ppc? ( mirror://sourceforge/sbcl/${PN}-${BV_PPC}-powerpc-linux-binary.tar.bz2 )
+		ppc64? ( mirror://sourceforge/sbcl/${PN}-${BV_PPC64LE}-ppc64le-linux-binary.tar.bz2 )
+		sparc? ( mirror://sourceforge/sbcl/${PN}-${BV_SPARC}-sparc-linux-binary.tar.bz2 )
+		alpha? ( mirror://sourceforge/sbcl/${PN}-${BV_ALPHA}-alpha-linux-binary.tar.bz2 )
+		arm? ( mirror://sourceforge/sbcl/${PN}-${BV_ARM}-armhf-linux-binary.tar.bz2 )
+		arm64? ( mirror://sourceforge/sbcl/${PN}-${BV_ARM64}-arm64-linux-binary.tar.bz2 )
+		x64-macos? ( mirror://sourceforge/sbcl/${PN}-${BV_X64_MACOS}-x86-64-darwin-binary.tar.bz2 )
+		ppc-macos? ( mirror://sourceforge/sbcl/${PN}-${BV_PPC_MACOS}-powerpc-darwin-binary.tar.bz2 )
+		x64-solaris? ( mirror://sourceforge/sbcl/${PN}-${BV_X64_SOLARIS}-x86-64-solaris-binary.tar.bz2 )
+	)"
+
+LICENSE="MIT"
+SLOT="0/${PV}"
+KEYWORDS="-* ~amd64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux ~x64-macos"
+IUSE="system-bootstrap debug doc source +threads +unicode +zstd"
+
+CDEPEND=">=dev-lisp/asdf-3.3:= \
+	prefix? ( dev-util/patchelf )"
+# bug #843851
+BDEPEND="${CDEPEND}
+		dev-util/strace
+		doc? ( sys-apps/texinfo >=media-gfx/graphviz-2.26.0 )
+		system-bootstrap? ( || ( dev-lisp/clisp dev-lisp/sbcl ) )"
+RDEPEND="${CDEPEND}
+		zstd? ( app-arch/zstd )
+		!prefix? ( elibc_glibc? ( >=sys-libs/glibc-2.6 ) )"
+
+# Disable warnings about executable stacks, as this won't be fixed soon by upstream
+QA_EXECSTACK="usr/bin/sbcl"
+
+CONFIG="${S}/customize-target-features.lisp"
+ENVD="${T}/50sbcl"
+
+# Prevent ASDF from using the system libraries
+CL_SOURCE_REGISTRY="(:source-registry :ignore-inherited-configuration)"
+ASDF_OUTPUT_TRANSLATIONS="(:output-translations :ignore-inherited-configuration)"
+
+usep() {
+	use ${1} && echo "true" || echo "false"
+}
+
+sbcl_feature() {
+	echo "$( [[ ${1} == "true" ]] && echo "(enable ${2})" || echo "(disable ${2})")" >> "${CONFIG}"
+}
+
+sbcl_apply_features() {
+	sed 's/^X//' > "${CONFIG}" <<-'EOF'
+	(lambda (list)
+	X  (flet ((enable  (x) (pushnew x list))
+	X         (disable (x) (setf list (remove x list))))
+	EOF
+	if use x86 || use amd64; then
+		sbcl_feature "$(usep threads)" ":sb-thread"
+	fi
+	sbcl_feature "true" ":sb-ldb"
+	sbcl_feature "false" ":sb-test"
+	sbcl_feature "$(usep unicode)" ":sb-unicode"
+	sbcl_feature "$(usep zstd)" ":sb-core-compression"
+	sbcl_feature "$(usep debug)" ":sb-xref-for-internals"
+	sed 's/^X//' >> "${CONFIG}" <<-'EOF'
+	X    )
+	X  list)
+	EOF
+	cat "${CONFIG}"
+}
+
+src_unpack() {
+	unpack ${A}
+	if ! use system-bootstrap ; then
+		mv sbcl-*-* sbcl-binary || die
+	fi
+	cd "${S}"
+}
+
+src_prepare() {
+	# bug #468482
+	eapply "${FILESDIR}"/concurrency-test-2.0.1.patch
+	# bugs #486552, #527666, #517004
+	eapply "${WORKDIR}"/${BSD_SOCKETS_TEST_PATCH}
+	# bugs #560276, #561018
+	eapply "${FILESDIR}"/sb-posix-test-2.2.9.patch
+	# bug #767742
+	eapply "${FILESDIR}"/etags-2.1.0.patch
+	# Use ${PV} as build-id, bug #797574
+	eapply "${FILESDIR}"/build-id-2.3.6.patch
+
+	eapply "${FILESDIR}"/verbose-build-2.0.3.patch
+
+	eapply_user
+
+	# Make sure the *FLAGS variables are sane.
+	# sbcl needs symbols in resulting binaries, so building with the -s linker flag will fail.
+	strip-unsupported-flags
+	filter-flags -fomit-frame-pointer -Wl,-s
+	filter-ldflags -s
+
+	# original bugs #526194, #620532
+	# this broke no-pie default builds, c.f. bug #632670
+	# Pass CFLAGS down by appending our value, to let users override
+	# the default values.
+	# Keep passing LDFLAGS down via the LINKFLAGS variable.
+	sed -e "s@\(CFLAGS += -g .*\)\$@\1 ${CFLAGS}@" \
+		-e "s@LINKFLAGS += -g\$@LINKFLAGS += ${LDFLAGS}@" \
+		-i src/runtime/GNUmakefile || die
+
+	sed -e "s@SBCL_PREFIX=\"/usr/local\"@SBCL_PREFIX=\"${EPREFIX}/usr\"@" \
+		-i make-config.sh || die
+
+	# Use installed ASDF version
+	cp "${EPREFIX}"/usr/share/common-lisp/source/asdf/build/asdf.lisp contrib/asdf/ || die
+	# Avoid installation of ASDF info page. See bug #605752
+	sed '/INFOFILES/s/asdf.info//' -i doc/manual/Makefile || die
+
+	use source && sed 's%"$(BUILD_ROOT)%$(MODULE).lisp "$(BUILD_ROOT)%' -i contrib/vanilla-module.mk
+
+	# Some shells(such as dash) don't have "time" as builtin
+	# and we don't want to DEPEND on sys-process/time
+	sed "s,^time ,," -i make.sh || die
+	sed "s,/lib,/$(get_libdir),g" -i install.sh || die
+	# #define SBCL_HOME ...
+	sed "s,/usr/local/lib,${EPREFIX}/usr/$(get_libdir),g" -i src/runtime/runtime.c || die
+	# change location of /etc/sbclrc ...
+	sed  "s,/etc/sbclrc,${EPREFIX}/etc/sbclrc,g" -i src/code/toplevel.lisp || die
+
+	find . -type f -name .cvsignore -delete
+}
+
+src_configure() {
+	# customizing SBCL version as per
+	# http://sbcl.cvs.sourceforge.net/sbcl/sbcl/doc/PACKAGING-SBCL.txt?view=markup
+	echo -e ";;; Auto-generated by Gentoo\n\"gentoo-${PR}\"" > branch-version.lisp-expr
+
+	# set interpreter for Prefix
+	if use prefix ; then
+		patchelf --set-interpreter \
+			"${EPREFIX}/$(get_libdir)"/ld-linux-x86-64.so.2 \
+			"${WORKDIR}"/sbcl-binary/src/runtime/sbcl
+	fi
+
+	# applying customizations
+	sbcl_apply_features
+}
+
+src_compile() {
+	local bindir="${WORKDIR}"/sbcl-binary
+	local bootstrap_lisp="sh ${bindir}/run-sbcl.sh --no-sysinit --no-userinit --disable-debugger"
+
+	if use system-bootstrap ; then
+		if has_version "dev-lisp/sbcl" ; then
+			bootstrap_lisp="sbcl --no-sysinit --no-userinit --disable-debugger"
+		else
+			bootstrap_lisp="clisp"
+		fi
+	fi
+
+	# Bug #869434
+	append-cppflags -D_GNU_SOURCE
+
+	# clear the environment to get rid of non-ASCII strings, see bug #174702
+	# set HOME for paludis
+	env - HOME="${T}" PATH="${PATH}" \
+		CC="$(tc-getCC)" AS="$(tc-getAS)" LD="$(tc-getLD)" \
+		CPPFLAGS="${CPPFLAGS}" CFLAGS="${CFLAGS}" ASFLAGS="${ASFLAGS}" LDFLAGS="${LDFLAGS}" \
+		SBCL_HOME="/usr/$(get_libdir)/sbcl" SBCL_SOURCE_ROOT="/usr/$(get_libdir)/sbcl/src" \
+		GNUMAKE=make PV=${PV} ./make.sh \
+		"${bootstrap_lisp}" \
+		|| die "make failed"
+
+	# need to set HOME because libpango(used by graphviz) complains about it
+	if use doc; then
+		env - HOME="${T}" PATH="${PATH}" \
+			CL_SOURCE_REGISTRY="(:source-registry :ignore-inherited-configuration)" \
+			ASDF_OUTPUT_TRANSLATIONS="(:output-translations :ignore-inherited-configuration)" \
+			make -C doc/manual info html || die "Cannot build manual"
+		env - HOME="${T}" PATH="${PATH}" \
+			CL_SOURCE_REGISTRY="(:source-registry :ignore-inherited-configuration)" \
+			ASDF_OUTPUT_TRANSLATIONS="(:output-translations :ignore-inherited-configuration)" \
+			make -C doc/internals info html || die "Cannot build internal docs"
+	fi
+}
+
+src_test() {
+	ewarn "Unfortunately, it is known that some tests fail eg."
+	ewarn "run-program.impure.lisp. This is an issue of the upstream's"
+	ewarn "development and not of Gentoo's side. Please, before filing"
+	ewarn "any bug(s) search for older submissions. Thank you."
+	time ( cd tests && sh run-tests.sh )
+}
+
+src_install() {
+	# install system-wide initfile
+	dodir /etc/
+	sed 's/^X//' > "${ED}"/etc/sbclrc <<-EOF
+	;;; The following is required if you want source location functions to
+	;;; work in SLIME, for example.
+	X
+	(setf (logical-pathname-translations "SYS")
+	X      '(("SYS:SRC;**;*.*.*" #p"${EPREFIX}/usr/$(get_libdir)/sbcl/src/**/*.*")
+	X        ("SYS:CONTRIB;**;*.*.*" #p"${EPREFIX}/usr/$(get_libdir)/sbcl/**/*.*")))
+	X
+	;;; Setup ASDF2
+	(load "${EPREFIX}/etc/common-lisp/gentoo-init.lisp")
+	EOF
+
+	# Install documentation
+	unset SBCL_HOME
+	INSTALL_ROOT="${ED}/usr" LIB_DIR="${EPREFIX}/usr/$(get_libdir)" DOC_DIR="${ED}/usr/share/doc/${PF}" \
+		sh install.sh || die "install.sh failed"
+
+	# bug #517008
+	pax-mark -mr "${D}"/usr/bin/sbcl
+
+	# rm empty directories lest paludis complain about this
+	find "${ED}" -empty -type d -exec rmdir -v {} +
+
+	if use doc; then
+		dodoc -r doc/internals/sbcl-internals
+
+		doinfo doc/manual/*.info*
+		doinfo doc/internals/sbcl-internals.info
+
+		docinto internals-notes
+		dodoc doc/internals-notes/*
+	else
+		rm -Rv "${ED}/usr/share/doc/${PF}" || die
+	fi
+
+	# install the SBCL source
+	if use source; then
+		./clean.sh
+		cp -av src "${ED}/usr/$(get_libdir)/sbcl/" || die
+		for d in contrib/*/; do
+			cp -av "$d" "${ED}/usr/$(get_libdir)/sbcl/" || die
+		done
+	fi
+
+	# necessary for running newly-saved images
+	echo "SBCL_HOME=${EPREFIX}/usr/$(get_libdir)/${PN}" > "${ENVD}"
+	echo "SBCL_SOURCE_ROOT=${EPREFIX}/usr/$(get_libdir)/${PN}/src" >> "${ENVD}"
+	doenvd "${ENVD}"
+}