gentoo auto-resync : 20:12:2022 - 13:51:21

1 files changed, 40 insertions, 0 deletions

diff --git a/dev-libs/roct-thunk-interface/roct-thunk-interface-5.3.3.ebuild b/dev-libs/roct-thunk-interface/roct-thunk-interface-5.3.3.ebuild
new file mode 100644
index 000000000000..d0cf376f0b8d
--- /dev/null
+++ b/dev-libs/roct-thunk-interface/roct-thunk-interface-5.3.3.ebuild
@@ -0,0 +1,40 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake linux-info
+
+if [[ ${PV} == *9999 ]] ; then
+	EGIT_REPO_URI="https://github.com/RadeonOpenCompute/ROCT-Thunk-Interface/"
+	inherit git-r3
+else
+	SRC_URI="https://github.com/RadeonOpenCompute/ROCT-Thunk-Interface/archive/rocm-${PV}.tar.gz -> ${P}.tar.gz"
+	S="${WORKDIR}/ROCT-Thunk-Interface-rocm-${PV}"
+	KEYWORDS="~amd64"
+fi
+
+DESCRIPTION="Radeon Open Compute Thunk Interface"
+HOMEPAGE="https://github.com/RadeonOpenCompute/ROCT-Thunk-Interface"
+CONFIG_CHECK="~HSA_AMD ~HMM_MIRROR ~ZONE_DEVICE ~DRM_AMDGPU ~DRM_AMDGPU_USERPTR"
+LICENSE="MIT"
+SLOT="0/$(ver_cut 1-2)"
+
+RDEPEND="sys-process/numactl"
+DEPEND="${RDEPEND}"
+BDEPEND="x11-libs/libdrm[video_cards_amdgpu]"
+
+CMAKE_BUILD_TYPE=Release
+
+src_prepare() {
+	sed -e "s:get_version ( \"1.0.0\" ):get_version ( \"${PV}\" ):" -i CMakeLists.txt || die
+	sed -e "s:ubuntu:gentoo:" -i CMakeLists.txt || die
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DCPACK_PACKAGING_INSTALL_PREFIX="${EPREFIX}/usr"
+	)
+	cmake_src_configure
+}