gentoo auto-resync : 20:10:2022 - 07:59:49

1 files changed, 60 insertions, 0 deletions

diff --git a/dev-libs/pmdk/pmdk-1.12.1.ebuild b/dev-libs/pmdk/pmdk-1.12.1.ebuild
new file mode 100644
index 000000000000..697268f890a8
--- /dev/null
+++ b/dev-libs/pmdk/pmdk-1.12.1.ebuild
@@ -0,0 +1,60 @@
+# Copyright 2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit toolchain-funcs flag-o-matic
+
+DESCRIPTION="Persistent Memory Development Kit"
+HOMEPAGE="https://pmem.io/ https://github.com/pmem/pmdk"
+SRC_URI="https://github.com/pmem/pmdk/releases/download/${PV}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0/1"
+KEYWORDS="~amd64"
+
+DEPEND="
+	sys-block/ndctl:=
+	sys-block/libfabric:=
+"
+RDEPEND="${DEPEND}"
+BDEPEND="
+	app-text/pandoc
+	virtual/pkgconfig
+"
+
+DOCS=(
+	CODING_STYLE.md
+	CONTRIBUTING.md
+	ChangeLog
+	README.md
+)
+
+src_prepare() {
+	default
+
+	# don't pre-compress man pages
+	sed -e 's/:=.gz//g ; s:gzip -nc:cat:g' -i doc/Makefile || die
+
+	# remove -Werror
+	find . -name 'Makefile*' -type f -print | xargs sed 's:-Werror::g' -i || die
+}
+
+src_configure() {
+	# doesn't build with -mindirect-branch=thunk
+	filter-flags -mindirect-branch=thunk
+}
+
+src_compile() {
+	emake DEBUG= CC="$(tc-getCC)" CXX="$(tc-getCXX)" LD="$(tc-getLD)" AR="$(tc-getAR)"
+}
+
+src_test() {
+	touch src/test/testconfig.sh || die
+
+	emake CC="$(tc-getCC)" CXX="$(tc-getCXX)" LD="$(tc-getLD)" AR="$(tc-getAR)" test || die
+}
+
+src_install() {
+	emake install prefix=/usr sysconfdir=/etc DESTDIR="${ED}"
+}