gentoo resync : 12.03.2021

1 files changed, 58 insertions, 0 deletions

diff --git a/dev-libs/log4cxx/log4cxx-0.11.0.ebuild b/dev-libs/log4cxx/log4cxx-0.11.0.ebuild
new file mode 100644
index 000000000000..4345b2b1b986
--- /dev/null
+++ b/dev-libs/log4cxx/log4cxx-0.11.0.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit autotools
+
+MY_P=apache-${P}
+
+DESCRIPTION="Library of C++ classes for logging to files, syslog and other destinations"
+HOMEPAGE="https://logging.apache.org/log4cxx/"
+SRC_URI="mirror://apache/logging/${PN}/${PV}/${MY_P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~x86 ~amd64-linux ~ppc-macos"
+IUSE="iodbc unicode odbc smtp"
+REQUIRED_USE="iodbc? ( !odbc )"
+# test suite fails
+RESTRICT="test"
+
+RDEPEND="
+	dev-libs/apr:1=
+	dev-libs/apr-util:1=
+	odbc? (
+		iodbc? ( >=dev-db/libiodbc-3.52.4 )
+		!iodbc? ( dev-db/unixODBC )
+	)
+	smtp? ( net-libs/libesmtp )"
+DEPEND="${RDEPEND}"
+
+S="${WORKDIR}/${MY_P}"
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		--disable-static \
+		--disable-doxygen \
+		--disable-html-docs \
+		--with-apr-util="${ESYSROOT}"/usr \
+		$(use_with smtp SMTP libesmtp) \
+		$(use_with odbc ODBC $(usex iodbc iODBC unixODBC)) \
+		--with-charset=$(usex unicode utf-8 auto)
+}
+
+src_install() {
+	default
+
+	docinto examples
+	dodoc src/examples/cpp/*.cpp
+	docompress -x /usr/share/doc/${PF}/examples
+
+	# package provides .pc files
+	find "${ED}" -name '*.la' -delete || die
+}