gentoo resync : 27.03.2021

1 files changed, 50 insertions, 0 deletions

diff --git a/dev-libs/jemalloc/jemalloc-5.2.1-r1.ebuild b/dev-libs/jemalloc/jemalloc-5.2.1-r1.ebuild
new file mode 100644
index 000000000000..e66e9eae5177
--- /dev/null
+++ b/dev-libs/jemalloc/jemalloc-5.2.1-r1.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="7"
+
+inherit autotools toolchain-funcs multilib-minimal
+
+DESCRIPTION="Jemalloc is a general-purpose scalable concurrent allocator"
+HOMEPAGE="http://jemalloc.net/ https://github.com/jemalloc/jemalloc"
+SRC_URI="https://github.com/jemalloc/jemalloc/releases/download/${PV}/${P}.tar.bz2"
+
+LICENSE="BSD"
+SLOT="0/2"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~s390 ~x86 ~amd64-linux ~x86-linux ~x64-macos ~x64-solaris"
+IUSE="debug lazy-lock prof static-libs stats xmalloc"
+HTML_DOCS=( doc/jemalloc.html )
+PATCHES=( "${FILESDIR}/${PN}-5.2.0-gentoo-fixups.patch" )
+
+MULTILIB_WRAPPED_HEADERS=( /usr/include/jemalloc/jemalloc.h )
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+multilib_src_configure() {
+	ECONF_SOURCE="${S}" \
+	econf  \
+		$(use_enable debug) \
+		$(use_enable lazy-lock) \
+		$(use_enable prof) \
+		$(use_enable stats) \
+		$(use_enable xmalloc)
+}
+
+multilib_src_install() {
+	# Copy man file which the Makefile looks for
+	cp "${S}/doc/jemalloc.3" "${BUILD_DIR}/doc" || die
+	emake DESTDIR="${D}" install
+}
+
+multilib_src_install_all() {
+	if [[ ${CHOST} == *-darwin* ]] ; then
+		# fixup install_name, #437362
+		install_name_tool \
+			-id "${EPREFIX}"/usr/$(get_libdir)/libjemalloc.2.dylib \
+			"${ED}"/usr/$(get_libdir)/libjemalloc.2.dylib || die
+	fi
+	use static-libs || find "${ED}" -name '*.a' -delete
+}