reinit the tree, so we can have metadata

4 files changed, 161 insertions, 0 deletions

diff --git a/dev-libs/gmime/Manifest b/dev-libs/gmime/Manifest
new file mode 100644
index 000000000000..e898398b9a9a
--- /dev/null
+++ b/dev-libs/gmime/Manifest
@@ -0,0 +1,7 @@
+DIST gmime-2.6.23.tar.xz 5216588 SHA256 7149686a71ca42a1390869b6074815106b061aaeaaa8f2ef8c12c191d9a79f6a SHA512 2ff6718b7a555cd5b34848399f29c7d0aa5a15e1f3cb46e9258c499e874191ee00f41b737386805d3000bad34367d174a25c45d38ba90cba7902400e733afa14 WHIRLPOOL fe6d32ad46b6743cb7d8ee781d87724dc3ba4519cb98b95bb49ef55d257b28864dbf2fac1ada309dac363761e18f7bb8456933147d9d093ccf52aae4af694044
+DIST gmime-3.0.2.tar.xz 751944 SHA256 0deb460111ffa2ec672677da339b82dedeb28b258ccdb216daa21c81a9472fb2 SHA512 246f489c168ce7e04fab664b7e9ae7772ae52f0063fb0eac9153460d84fa5d9712457d81fbd1bdcdadb7e03007cf71ed3bad5287f1639214f54167427c9209ca WHIRLPOOL ff3c9ee2cdcff33cd6d2406ff72e925915f0901c92d3ba37a8ef5ee82d715c825e8337ecc68071daf5de67463653d91dd7b7a265ac6b6a883d3343e2fe51ca09
+EBUILD gmime-2.6.23.ebuild 1735 SHA256 74928d4f3ffc472ff0a3ddcd8c358ed64683fcbde25891ae194c1f2a51e29dd5 SHA512 2fbc586acb1dea60334039199a75f796bdd222ac5451c47ab76b2f8453adb4a2850d52dabb0c9d30af9a31332d5804bcc7891ceff5c58b78a61b2b54d0dd0354 WHIRLPOOL cd607f509870ab2c3a32344fb73ed5b555d351ac26bee44cb38e79828227d828e12d8594e116fa8a3155f1a44f19f8d174bb55418fc69bb56731fa0da4101646
+EBUILD gmime-3.0.2.ebuild 1565 SHA256 bae17c487fdf0f7c240f6a39337f5b175eedb2aa44b10411870fcca159e5bc50 SHA512 5c887be7059c20a2166771651d5b221e0a228f9b12f0b0f38f1fdf83b00ad3c3d8e94f072c0d00bbff0ee0aef448922acb333b123b5e69f16de75d034eeb8ea3 WHIRLPOOL 8771258187df3a23b24138f730dcc7cf3002d4d4008cb516bcebf907d86e1d3fa8b42c125a9bac66d5bf7fbd67982c1b507c96e552196bf013b306125f43b76c
+MISC ChangeLog 5143 SHA256 92d08f0ccaaad535011cea3a7f5765ca57890ff012ba27a156d53b588567b72a SHA512 df639236608fe530bf4ecb4c0d08d3989240d594070d4f5609fd70167613846ba2480ce1644e524546578ce2c077e9a378b153d6f41a9644e7455612150380a5 WHIRLPOOL 24f5eed00a19ce0fe20b9e6635571f8409fdcf59a6df5f21e8854d45e3d3d57fbdf2d2a783f862ae74310d7aecc376c37283cb125810aedc7f0ea2cbd858f1ae
+MISC ChangeLog-2015 36714 SHA256 2555d210c6604fe119b1a8b111cae198ea96d1bf90f31b3734d76b905cadd4d6 SHA512 94e9f60066e282451eb767b4bbe4fbd82fd93b97471f040123281d7aab1f0a799f02532d440f0e83c42396b8ec9e680d714ac823a75b721249775fec855c1e4d WHIRLPOOL 0a17527277f5352c59fcee06b2888aff0474410b626044fc85f3dc0dd5fb05dd32b65dff8a0496143d7e26ef30d26a2a4536166fdad0598d33e0453a2a94ada5
+MISC metadata.xml 407 SHA256 55d8c2b63403ad24322bab1bd2c3508c5aa9f8ee9e0d327ff588754d283d0105 SHA512 0567710e8d8d0a61a0828325440aa243d8517d94767069d165c106fc5d1b96e5f952738874772ef9f28d1a391d3c47939a2ee32ecf3f8321ec00ee81d646d502 WHIRLPOOL b2f115f647865fac05039a0c2e9c08d314ac7074bab37afe08bcd21cdf0c29bb391ffe8a576b9e46d9a27aeb6dcab9f7b0218dbb5c6718cfc8965c96b72f466d
diff --git a/dev-libs/gmime/gmime-2.6.23.ebuild b/dev-libs/gmime/gmime-2.6.23.ebuild
new file mode 100644
index 000000000000..e9b4bef636fc
--- /dev/null
+++ b/dev-libs/gmime/gmime-2.6.23.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+VALA_USE_DEPEND="vapigen"
+
+inherit mono-env gnome2 vala flag-o-matic
+
+DESCRIPTION="Utilities for creating and parsing messages using MIME"
+HOMEPAGE="http://spruce.sourceforge.net/gmime/ https://developer.gnome.org/gmime/stable/"
+
+SLOT="2.6"
+LICENSE="LGPL-2.1"
+KEYWORDS="alpha amd64 arm ~arm64 hppa ia64 ppc ppc64 sparc x86 ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos ~x64-solaris ~x86-solaris"
+IUSE="doc mono smime static-libs test vala"
+
+RDEPEND="
+	>=dev-libs/glib-2.32.0:2
+	sys-libs/zlib
+	mono? (
+		dev-lang/mono
+		>=dev-dotnet/gtk-sharp-2.12.21:2 )
+	smime? ( >=app-crypt/gpgme-1.1.6:1= )
+	vala? (
+		$(vala_depend)
+		>=dev-libs/gobject-introspection-1.30.0:= )
+"
+DEPEND="${RDEPEND}
+	>=dev-util/gtk-doc-am-1.8
+	virtual/libiconv
+	virtual/pkgconfig
+	doc? ( app-text/docbook-sgml-utils )
+	test? ( app-crypt/gnupg )
+"
+# gnupg is needed for tests if --enable-cryptography is enabled, which we do unconditionally
+
+pkg_setup() {
+	use mono && mono-env_pkg_setup
+}
+
+src_prepare() {
+	gnome2_src_prepare
+	use vala && vala_src_prepare
+}
+
+src_configure() {
+	[[ ${CHOST} == *-solaris* ]] && append-libs iconv
+	gnome2_src_configure \
+		--enable-cryptography \
+		--disable-strict-parser \
+		$(use_enable mono) \
+		$(use_enable smime) \
+		$(use_enable static-libs static) \
+		$(use_enable vala)
+}
+
+src_compile() {
+	MONO_PATH="${S}" gnome2_src_compile
+	if use doc; then
+		emake -C docs/tutorial html
+	fi
+}
+
+src_install() {
+	GACUTIL_FLAGS="/root '${ED}/usr/$(get_libdir)' /gacdir '${EPREFIX}/usr/$(get_libdir)' /package ${PN}" \
+		gnome2_src_install
+
+	if use doc ; then
+		docinto tutorial
+		dodoc -r docs/tutorial/html/
+	fi
+}
diff --git a/dev-libs/gmime/gmime-3.0.2.ebuild b/dev-libs/gmime/gmime-3.0.2.ebuild
new file mode 100644
index 000000000000..8b16292c8a03
--- /dev/null
+++ b/dev-libs/gmime/gmime-3.0.2.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+VALA_USE_DEPEND="vapigen"
+
+inherit flag-o-matic gnome2 vala
+
+DESCRIPTION="Utilities for creating and parsing messages using MIME"
+HOMEPAGE="http://spruce.sourceforge.net/gmime/ https://developer.gnome.org/gmime/stable/"
+
+SLOT="3.0"
+LICENSE="LGPL-2.1"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos ~x64-solaris ~x86-solaris"
+IUSE="crypt doc idn static-libs test vala"
+
+RDEPEND="
+	>=dev-libs/glib-2.32.0:2
+	sys-libs/zlib
+	crypt? ( >=app-crypt/gpgme-1.8.0:1= )
+	idn? ( net-dns/libidn )
+	vala? (
+		$(vala_depend)
+		>=dev-libs/gobject-introspection-1.30.0:= )
+"
+DEPEND="${RDEPEND}
+	>=dev-util/gtk-doc-am-1.8
+	virtual/libiconv
+	virtual/pkgconfig
+	doc? ( app-text/docbook-sgml-utils )
+	test? ( app-crypt/gnupg )
+"
+# gnupg is needed for tests if --enable-cryptography is enabled, which we do unconditionally
+
+src_prepare() {
+	gnome2_src_prepare
+	use vala && vala_src_prepare
+}
+
+src_configure() {
+	if [[ ${CHOST} == *-solaris* ]]; then
+		# bug #???, why not use --with-libiconv
+		append-libs iconv
+	fi
+
+	gnome2_src_configure \
+		$(use_enable crypt crypto) \
+		$(use_enable static-libs static) \
+		$(use_enable vala) \
+		$(use_with idn libidn) \
+		$(usex doc "" DB2HTML=)
+}
+
+src_compile() {
+	gnome2_src_compile
+	if use doc; then
+		emake -C docs/tutorial html
+	fi
+}
+
+src_install() {
+	gnome2_src_install
+
+	if use doc ; then
+		docinto tutorial
+		dodoc -r docs/tutorial/html/
+	fi
+}
diff --git a/dev-libs/gmime/metadata.xml b/dev-libs/gmime/metadata.xml
new file mode 100644
index 000000000000..3faea473b958
--- /dev/null
+++ b/dev-libs/gmime/metadata.xml
@@ -0,0 +1,14 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="project">
+		<email>gnome@gentoo.org</email>
+		<name>Gentoo GNOME Desktop</name>
+	</maintainer>
+	<upstream>
+		<remote-id type="sourceforge">spruce</remote-id>
+	</upstream>
+	<use>
+		<flag name="smime">Enable experimental S/MIME support</flag>
+	</use>
+</pkgmetadata>