gentoo resync : 30.09.2018

1 files changed, 57 insertions, 0 deletions

diff --git a/dev-lang/moarvm/moarvm-2018.09.ebuild b/dev-lang/moarvm/moarvm-2018.09.ebuild
new file mode 100644
index 000000000000..55ae9205a866
--- /dev/null
+++ b/dev-lang/moarvm/moarvm-2018.09.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit flag-o-matic
+
+MY_PN="MoarVM"
+if [[ ${PV} == "9999" ]]; then
+	EGIT_REPO_URI="https://github.com/${MY_PN}/${MY_PN}.git"
+	inherit git-r3
+	KEYWORDS=""
+	S="${WORKDIR}/${P}"
+else
+	SRC_URI="http://moarvm.org/releases/${MY_PN}-${PV}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+	S="${WORKDIR}/${MY_PN}-${PV}"
+fi
+
+DESCRIPTION="A 6model-based VM for NQP and Rakudo Perl 6"
+HOMEPAGE="http://moarvm.org"
+LICENSE="Artistic-2"
+SLOT="0"
+IUSE="asan clang debug doc +jit static-libs optimize ubsan"
+
+RDEPEND="dev-libs/libatomic_ops
+		dev-libs/libuv
+		dev-lang/lua:=
+		virtual/libffi"
+DEPEND="${RDEPEND}
+	clang? ( >=sys-devel/clang-3.1 )
+	dev-lang/perl"
+
+DOCS=( CREDITS README.markdown )
+
+# Tests are conducted via nqp
+RESTRICT=test
+
+src_configure() {
+	use doc && DOCS+=( docs/* )
+	local myconfigargs=(
+		"--prefix=/usr"
+		"--has-libuv"
+		"--has-libatomic_ops"
+		"--has-libffi"
+		"--libdir=$(get_libdir)"
+		"--compiler=$(usex clang clang gcc)"
+		"$(usex asan        --asan)"
+		"$(usex debug       --debug            --no-debug)"
+		"$(usex optimize    --optimize=        --no-optimize)"
+		"$(usex static-libs --static)"
+		"$(usex ubsan       --ubsan)"
+	)
+	use optimize && filter-flags '-O*'
+
+	perl Configure.pl "${myconfigargs[@]}" || die
+}