gentoo resync : 06.04.2022

1 files changed, 41 insertions, 0 deletions

diff --git a/dev-cpp/highway/highway-0.16.0-r1.ebuild b/dev-cpp/highway/highway-0.16.0-r1.ebuild
new file mode 100644
index 000000000000..52fb0b16d961
--- /dev/null
+++ b/dev-cpp/highway/highway-0.16.0-r1.ebuild
@@ -0,0 +1,41 @@
+# Copyright 2021-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+CMAKE_ECLASS=cmake
+inherit cmake-multilib
+
+DESCRIPTION="Performance-portable, length-agnostic SIMD with runtime dispatch"
+HOMEPAGE="https://github.com/google/highway"
+
+if [[ "${PV}" == *9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/google/highway.git"
+else
+	SRC_URI="https://github.com/google/highway/archive/refs/tags/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86"
+fi
+
+LICENSE="Apache-2.0"
+SLOT="0"
+IUSE="test"
+
+DEPEND="test? ( dev-cpp/gtest[${MULTILIB_USEDEP}] )"
+
+RESTRICT="!test? ( test )"
+
+PATCHES=(
+	"${FILESDIR}"/${P}-fix-AVX512-detection-on-IceLakeClient.patch
+)
+
+multilib_src_configure() {
+	local mycmakeargs=(
+		-DBUILD_TESTING=$(usex test)
+		-DHWY_WARNINGS_ARE_ERRORS=OFF
+	)
+
+	use test && mycmakeargs+=( "-DHWY_SYSTEM_GTEST=ON" )
+
+	cmake_src_configure
+}