reinit the tree, so we can have metadata

1 files changed, 71 insertions, 0 deletions

diff --git a/app-text/zathura/zathura-9999.ebuild b/app-text/zathura/zathura-9999.ebuild
new file mode 100644
index 000000000000..52a3a9c5d867
--- /dev/null
+++ b/app-text/zathura/zathura-9999.ebuild
@@ -0,0 +1,71 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=5
+
+inherit eutils fdo-mime multilib toolchain-funcs virtualx
+[[ ${PV} == 9999* ]] && inherit git-2
+
+DESCRIPTION="A highly customizable and functional document viewer"
+HOMEPAGE="http://pwmt.org/projects/zathura/"
+if ! [[ ${PV} == 9999* ]]; then
+SRC_URI="http://pwmt.org/projects/${PN}/download/${P}.tar.gz"
+fi
+EGIT_REPO_URI="https://git.pwmt.org/pwmt/${PN}.git"
+EGIT_BRANCH="develop"
+
+LICENSE="ZLIB"
+SLOT="0"
+if ! [[ ${PV} == 9999* ]]; then
+KEYWORDS="~amd64 ~arm ~x86 ~amd64-linux ~x86-linux"
+else
+KEYWORDS=""
+fi
+IUSE="+magic sqlite synctex test"
+
+RDEPEND=">=dev-libs/girara-0.2.7:3=
+	>=dev-libs/glib-2.32:2=
+	x11-libs/cairo:=
+	>=x11-libs/gtk+-3.6:3
+	magic? ( sys-apps/file:= )
+	sqlite? ( dev-db/sqlite:3= )
+	synctex? ( >=app-text/texlive-core-2015 )"
+DEPEND="${RDEPEND}
+	sys-devel/gettext
+	virtual/pkgconfig
+	test? ( dev-libs/check )"
+
+pkg_setup() {
+	myzathuraconf=(
+		WITH_MAGIC=$(usex magic 1 0)
+		WITH_SQLITE=$(usex sqlite 1 0)
+		WITH_SYNCTEX=$(usex synctex 1 0)
+		PREFIX="${EPREFIX}"/usr
+		LIBDIR='${PREFIX}'/$(get_libdir)
+		CC="$(tc-getCC)"
+		SFLAGS=''
+		VERBOSE=1
+		DESTDIR="${D}"
+	)
+}
+
+src_compile() {
+	emake "${myzathuraconf[@]}"
+}
+
+src_test() {
+	Xemake "${myzathuraconf[@]}" test
+}
+
+src_install() {
+	emake "${myzathuraconf[@]}" install
+	dodoc AUTHORS
+}
+
+pkg_postinst() {
+	fdo-mime_desktop_database_update
+}
+
+pkg_postrm() {
+	fdo-mime_desktop_database_update
+}