gentoo auto-resync : 06:10:2022 - 01:20:42

3 files changed, 139 insertions, 2 deletions

diff --git a/app-text/poppler/Manifest b/app-text/poppler/Manifest
index 3c2b1878c674..9b896ada06cb 100644
--- a/app-text/poppler/Manifest
+++ b/app-text/poppler/Manifest
@@ -5,7 +5,10 @@ DIST poppler-22.07.0.tar.xz 1838796 BLAKE2B 401573c3bd1e4801ee331e97a3787c88c0c3
 DIST poppler-22.07.0.tar.xz.sig 833 BLAKE2B a73cc36e0c1c20c4f55e4896ae8d880d62d458a0d256022cdac50e48c7993fbf617e9c4de704958d103fae1ccb619d6122a06d2b51e0389f15338d67e34cefdb SHA512 252c34d4f8b7b43255ea5371c35348ac2d3044860d850fd510213a4785c633e230f61aab06b706b173e8e3482c7028a433fccae982adc18681f0da2b6e2bed3d
 DIST poppler-22.09.0.tar.xz 1842704 BLAKE2B 7104dc18582611901e55dbaa84d9ae87121773370b677719c470c9804fd0a74164e72b4f39c5113531736e37327b59abb2d47b9dba58acf127180fed0cd3021c SHA512 bd288b042ad6fa31584d733b941b7ba72d9e68407fda5596827d559be0f46cf27dd8e0b1b7e0d58c997e29b18c5f086486f900965229c61e034e31d8ac474613
 DIST poppler-22.09.0.tar.xz.sig 833 BLAKE2B bda372fa8d8d3d7ebe4263f9f81212d69e09b50e787a853390191c1bfcc38fd65f8e524f3810b6d3d25820ba5b2fe3d337c9e661c0747a73d64cbcdfb06b8205 SHA512 678e374c184e403b85cfbdc954b80fa4132f37d34eb60854f7708d7963b98f4e57997ec9a9aa8e17090ee696ff5821c3479857ef3f93a69e32c3f25744c84e43
+DIST poppler-22.10.0.tar.xz 1844524 BLAKE2B 4784f0aa9bf19beb251e0b7e3a9f42d6e21fea6f9e2ccdffd5ffc59167902466faf4bc13ab20a4e30cb272010416ede61020ab781c601cbe808debcce93013ef SHA512 9f80a08ae7c6c41c2ae9a2f3d2fbd8b65e430f290d2603aaa6df39d1d69f4418f76584c3f20733fb38731e4a57a8b04f55cf0f9753dd8a43be7b6d18f609f116
+DIST poppler-22.10.0.tar.xz.sig 833 BLAKE2B 0714d81b8ded72b239b7e8e8d7a7812336f03a2a37a242270b64c4622e994ad9f2798c49f8f8c2de9a0c3c732bd55a87ce37c66eb35819fa0a26ace072c0dc5a SHA512 6341fbbe65ae8ce132c7384f00ff4cef900854d72bfe2d1aae15767eef0a85e2817527ffea3e089dc08e076af4f72b67f1db559e90d32a9e29949b51abcf5a8d
 EBUILD poppler-22.07.0.ebuild 3648 BLAKE2B d8a3eaa2e381a1a7e047e0cd475f18a00234e602a0c2e2d4e8fe30a95499dff0ef0770ba83a6b2fc0e533419625a47753ff757bf109e540b32dc7c65cb07a9ea SHA512 0059fc5a203855c2139bb56fc379b4f8d4679a81049e253344ddde27d6b0b978ef5a3e0263e0b6c3a93f6cc600284a2f2c433e004931e9a2ce5500fe8b319371
 EBUILD poppler-22.09.0.ebuild 3651 BLAKE2B af542880f53f6383c366aa4158a56e36e474b156b834bad31ef7b464bcf1cf90a2242b4a2c47ca9255ebc77e4a28ab042d693826fadc3ccfc76507d3eff5358c SHA512 a65f6cdf5f5bdc01bbbd34ae83d69b5300dd11e0525f76b82447e4e247db60f300a44e7acf6eacaaf876ac039638caa37583eda7b3b60e8b7e9e4936deff2eb2
-EBUILD poppler-9999.ebuild 3656 BLAKE2B 8c14faaf9c7f78352d0508953ae0d1fe2cfc9c3695c2a40706ae7bb9241738a8bf766d5b0f8ba9fc2eb27f87cd04825fd0d23b65cdd99d30e7f307b1a57b72fb SHA512 7563541cfdbabeaa3b073d081ab2b62a566ebdc87e76df8043c5ca75113c638649d7294781c93943f4df1d2e97fcb915163b582b95b0484e433f7c8246d8d889
+EBUILD poppler-22.10.0.ebuild 3656 BLAKE2B 2da2cabf00caa4729e0fc70f265694a1ae97e6f1fbbf71f462fc79d89f15aa92fdf964cc45c563e4a00dc426f22bd499e41c99459288226d1bdf5b7137bc353e SHA512 1f77e93ca0ab9c18c2f9692b4a51cc81ecae1168a52562eced65bea5b9e8719c25767640812eb90f7d47419d8c04fc3294e11528b0b1dc4923cc34d1f492b0aa
+EBUILD poppler-9999.ebuild 3656 BLAKE2B 2da2cabf00caa4729e0fc70f265694a1ae97e6f1fbbf71f462fc79d89f15aa92fdf964cc45c563e4a00dc426f22bd499e41c99459288226d1bdf5b7137bc353e SHA512 1f77e93ca0ab9c18c2f9692b4a51cc81ecae1168a52562eced65bea5b9e8719c25767640812eb90f7d47419d8c04fc3294e11528b0b1dc4923cc34d1f492b0aa
 MISC metadata.xml 1078 BLAKE2B c5ce2245efedc75eb39a6c649d27698da0ac07b87da3240aeb9fea1435d48c3282a8a3bb9f002c78b79de2a518cb73f3eef563c05f41528bb55ffeca84409e13 SHA512 22c83f7f6a7632fc4fe94223be9e5edac085099bf5c0f6621b0179b16e35b98b0027e467e76c0ca365008d765258e05faf48dbc4b1e8d5eb507f348a533f88f6
diff --git a/app-text/poppler/poppler-22.10.0.ebuild b/app-text/poppler/poppler-22.10.0.ebuild
new file mode 100644
index 000000000000..89fdf77aacf0
--- /dev/null
+++ b/app-text/poppler/poppler-22.10.0.ebuild
@@ -0,0 +1,134 @@
+# Copyright 2005-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake toolchain-funcs xdg-utils
+
+if [[ ${PV} == *9999* ]] ; then
+	inherit git-r3
+	EGIT_REPO_URI="https://anongit.freedesktop.org/git/poppler/poppler.git"
+	SLOT="0/9999"
+else
+	VERIFY_SIG_OPENPGP_KEY_PATH="${BROOT}"/usr/share/openpgp-keys/aacid.asc
+	inherit verify-sig
+
+	SRC_URI="https://poppler.freedesktop.org/${P}.tar.xz"
+	SRC_URI+=" verify-sig? ( https://poppler.freedesktop.org/${P}.tar.xz.sig )"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+	SLOT="0/125"   # CHECK THIS WHEN BUMPING!!! SUBSLOT IS libpoppler.so SOVERSION
+fi
+
+DESCRIPTION="PDF rendering library based on the xpdf-3.0 code base"
+HOMEPAGE="https://poppler.freedesktop.org/"
+
+LICENSE="GPL-2"
+IUSE="boost cairo cjk curl +cxx debug doc +introspection +jpeg +jpeg2k +lcms nss png qt5 tiff +utils"
+
+# No test data provided
+RESTRICT="test"
+
+COMMON_DEPEND="
+	media-libs/fontconfig
+	>=media-libs/freetype-2.8
+	sys-libs/zlib
+	cairo? (
+		dev-libs/glib:2
+		x11-libs/cairo
+		introspection? ( dev-libs/gobject-introspection:= )
+	)
+	curl? ( net-misc/curl )
+	jpeg? ( media-libs/libjpeg-turbo:= )
+	jpeg2k? ( >=media-libs/openjpeg-2.3.0-r1:2= )
+	lcms? ( media-libs/lcms:2 )
+	nss? ( >=dev-libs/nss-3.19:0 )
+	png? ( media-libs/libpng:0= )
+	qt5? (
+		dev-qt/qtcore:5
+		dev-qt/qtgui:5
+		dev-qt/qtxml:5
+	)
+	tiff? ( media-libs/tiff:0 )
+"
+RDEPEND="${COMMON_DEPEND}
+	cjk? ( app-text/poppler-data )
+"
+DEPEND="${COMMON_DEPEND}
+	boost? ( dev-libs/boost )
+"
+BDEPEND="
+	dev-util/glib-utils
+	virtual/pkgconfig
+"
+
+if [[ ${PV} != *9999* ]] ; then
+	BDEPEND+=" verify-sig? ( sec-keys/openpgp-keys-aacid )"
+fi
+
+DOCS=( AUTHORS NEWS README.md README-XPDF )
+
+PATCHES=(
+	"${FILESDIR}/${PN}-20.12.1-qt5-deps.patch"
+	"${FILESDIR}/${PN}-21.09.0-respect-cflags.patch"
+	"${FILESDIR}/${PN}-0.57.0-disable-internal-jpx.patch"
+)
+
+src_prepare() {
+	cmake_src_prepare
+
+	# Clang doesn't grok this flag, the configure nicely tests that, but
+	# cmake just uses it, so remove it if we use clang
+	if tc-is-clang ; then
+		sed -e 's/-fno-check-new//' -i cmake/modules/PopplerMacros.cmake || die
+	fi
+
+	if ! grep -Fq 'cmake_policy(SET CMP0002 OLD)' CMakeLists.txt ; then
+		sed -e '/^cmake_minimum_required/acmake_policy(SET CMP0002 OLD)' \
+			-i CMakeLists.txt || die
+	else
+		einfo "policy(SET CMP0002 OLD) - workaround can be removed"
+	fi
+}
+
+src_configure() {
+	xdg_environment_reset
+	local mycmakeargs=(
+		-DBUILD_GTK_TESTS=OFF
+		-DBUILD_QT5_TESTS=OFF
+		-DBUILD_CPP_TESTS=OFF
+		-DBUILD_MANUAL_TESTS=OFF
+		-DRUN_GPERF_IF_PRESENT=OFF
+		-DENABLE_BOOST="$(usex boost)"
+		-DENABLE_ZLIB=ON
+		-DENABLE_ZLIB_UNCOMPRESS=OFF
+		-DENABLE_UNSTABLE_API_ABI_HEADERS=ON
+		-DUSE_FLOAT=OFF
+		-DWITH_Cairo=$(usex cairo)
+		-DENABLE_LIBCURL=$(usex curl)
+		-DENABLE_CPP=$(usex cxx)
+		-DWITH_JPEG=$(usex jpeg)
+		-DENABLE_DCTDECODER=$(usex jpeg libjpeg none)
+		-DENABLE_LIBOPENJPEG=$(usex jpeg2k openjpeg2 none)
+		-DENABLE_CMS=$(usex lcms lcms2 none)
+		-DWITH_NSS3=$(usex nss)
+		-DWITH_PNG=$(usex png)
+		$(cmake_use_find_package qt5 Qt5Core)
+		-DWITH_TIFF=$(usex tiff)
+		-DENABLE_UTILS=$(usex utils)
+		-DENABLE_QT6=OFF
+	)
+	use cairo && mycmakeargs+=( -DWITH_GObjectIntrospection=$(usex introspection) )
+
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+
+	# live version doesn't provide html documentation
+	if use cairo && use doc && [[ ${PV} != *9999* ]]; then
+		# For now install gtk-doc there
+		insinto /usr/share/gtk-doc/html/poppler
+		doins -r "${S}"/glib/reference/html/*
+	fi
+}
diff --git a/app-text/poppler/poppler-9999.ebuild b/app-text/poppler/poppler-9999.ebuild
index 81157c1a12a0..89fdf77aacf0 100644
--- a/app-text/poppler/poppler-9999.ebuild
+++ b/app-text/poppler/poppler-9999.ebuild
@@ -16,7 +16,7 @@ else
 	SRC_URI="https://poppler.freedesktop.org/${P}.tar.xz"
 	SRC_URI+=" verify-sig? ( https://poppler.freedesktop.org/${P}.tar.xz.sig )"
 	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
-	SLOT="0/124"   # CHECK THIS WHEN BUMPING!!! SUBSLOT IS libpoppler.so SOVERSION
+	SLOT="0/125"   # CHECK THIS WHEN BUMPING!!! SUBSLOT IS libpoppler.so SOVERSION
 fi
 
 DESCRIPTION="PDF rendering library based on the xpdf-3.0 code base"