gentoo auto-resync : 20:01:2024 - 14:08:56

4 files changed, 173 insertions, 6 deletions

diff --git a/app-text/mupdf/Manifest b/app-text/mupdf/Manifest
index a8a0c06f4ca5..5ffc7125c5d0 100644
--- a/app-text/mupdf/Manifest
+++ b/app-text/mupdf/Manifest
@@ -11,6 +11,8 @@ AUX mupdf-1.23.3-darwin.patch 1282 BLAKE2B 770cf03765a5d0afb55a77a489030a79470c9
 AUX mupdf-1.23.3-openssl-x11.patch 653 BLAKE2B 085eca797ed648becffc348376777d5e2544862b6f1a9b961c11d9421bada63d4f5fd1718474d7fb384346a8f560cbe025bd27138f38b20a83666a89ffb05451 SHA512 ca715f08069fd567d6d85dd27863f688211e47899b384b938dd41d1350bbd3b4ffd56201f973b2f6c996ba4add47129ec16921a6e572b86c6927ef3409b00ffb
 DIST mupdf-1.22.0-source.tar.gz 55043552 BLAKE2B 745a2fd1d0406acf4fa696585bcd21a4ff36e7539c1d45f886dfe5c9bbf966169e5183e89940d81e88db3014f1ebb0446ae1732b6c2fa25a135251853b71f1f7 SHA512 ba073b977306420343c969e6fec37cca4559031ad06cfdee2356edfdfa013ebe7654175aff931684fa48a935bf87f68537754b5e83f767517bc428ac07709a59
 DIST mupdf-1.23.3-source.tar.gz 55144800 BLAKE2B 816e2bf46c2431df9726976efeaa0d7ebd8809cbdd9331a747cca32088aaf21b70e9522614d1dc20c856cc597003be6285f866eae8bbde3098e702acfdea8465 SHA512 37fbebd07680d79a38d289264a4028396ee58fad52c541efa37463e63a45ed8bab71188d6c05eb15e602964d89ee6633575dceb972f7bd8b0b5efdde5af9b737
-EBUILD mupdf-1.22.0.ebuild 4918 BLAKE2B 70d1743638bb667e0ffd9b86a4cdb8b954ba7d27d2fadd01d1fddc7bbf4cd8b25e85c0f5b5606f979091b5346f1eaeb0fbc57e6a950d92dbb4b549142ccd9ea4 SHA512 ccbfb9f03c91db4d6aa90775c99caaa3247275d0480a383a9977fdf0c99f98050a6b40feff7028650f259aa09fd1c767ced508990752accf85ebb2972101dcb4
-EBUILD mupdf-1.23.3.ebuild 4865 BLAKE2B 978182649fb26abe37071150440f888b4a78a772e9eb0d9ae6a9edae02260d471fd3ea4600e2f7475b6bc48653e009e729dc961aae9fb3bfa65b08046e5b1724 SHA512 064936f15d6c714042f294036d0c792dc3ab51cef5cbfbbd2090fa95df96babeb14b99493a6b03a03f4f435e7f5fcf11442a7254286250919761d280dd2dd2ce
+DIST mupdf-1.23.7-source.tar.gz 55312697 BLAKE2B 7ceb7c1871d33b77d4a3d52ed2d1af514c09349df019a189fa7df8ad09648fae313d63de4c1ce6b0666d17f9a897d5ac788d0be2d8896d9b7e4e6ecf679bad7c SHA512 581a4a5a16041bb405fbd7c1b9fba47da5745f00cbdf30e0e0468bfe67ac542884193b5957b293a4cdfc52f043b4f19612086f294b93dbd242d34735a1088777
+EBUILD mupdf-1.22.0-r1.ebuild 4920 BLAKE2B 576906457753cdee6e2713e8ad470b039ea675f7072fbc748b75b567d4ef70ede265af9ce53750dfd7bb8a9365f7b44bed080df5846d45fb65f41f14bb8575a2 SHA512 94921e1a314ae141567271966eecc6baae2c8f84b47e9edaa6a3b23226e3b1a42d8b20cd1bd99d78471dd6a21378ee9a0a88fd87705a4888c2f1eb9c816d3aa2
+EBUILD mupdf-1.23.3-r1.ebuild 4867 BLAKE2B e18313d92b7dadbb96f9cd346fd49e3c3af629c508e9a809954dcdbda084a30bc2a3d89b3f34f069ee8ad4c6c4d6be0fabfee233fe993bc5060daa19f58c2338 SHA512 29644f2828032daab5c1c43103fca0ed768214550b4421b812119543806c1b3a83458ac24f2da609ff15f0b5ed0a4cbe7e9475cfc24839c780a8ef48b5d1bf70
+EBUILD mupdf-1.23.7-r1.ebuild 4960 BLAKE2B 974426abe3d3dcf7441938169ec61e2a6a32c5b6f909d80a0c4e19aaf9419a87e79ff9ea7ff321ce4c39074f2342e86dedd943b685e4b685038b42a89cd71b0d SHA512 dd964c2163d6326f8693c688ea243198d6988f49b5b0ba9deb6f88569f6ce7e041298e48b00f6818afda17052fecf6de717fe704689c8a3a77ef7cbbd3a0c253
 MISC metadata.xml 497 BLAKE2B 35e16ef688aa8b046f3e8ceaa7399da31379ba50b2cbc36d842696d1589aeea5a55eede13d79188f08ae8ff411c16385128633a1fbdaba04ee115158ac7e529b SHA512 225727e22fe2756480f3d502f49a62abbd0fe09d6266c1e00c09b04c2b5da181fc46bb06b19020290fa857b1feb0d557e6a77084f6269b5e0fdfec593cd46709
diff --git a/app-text/mupdf/mupdf-1.22.0.ebuild b/app-text/mupdf/mupdf-1.22.0-r1.ebuild
index 134e69b027cd..fc8bbe571872 100644
--- a/app-text/mupdf/mupdf-1.22.0.ebuild
+++ b/app-text/mupdf/mupdf-1.22.0-r1.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2023 Gentoo Authors
+# Copyright 1999-2024 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=8
@@ -23,7 +23,7 @@ REQUIRED_USE="opengl? ( javascript )"
 # bug #653298), the best way to ensure that its dependencies are present is to
 # install system's freeglut.
 RDEPEND="
-	dev-libs/gumbo
+	dev-libs/gumbo:=
 	media-libs/freetype:2
 	media-libs/harfbuzz:=[truetype]
 	media-libs/jbig2dec:=
diff --git a/app-text/mupdf/mupdf-1.23.3.ebuild b/app-text/mupdf/mupdf-1.23.3-r1.ebuild
index ec538296fd58..7c7e19d9e75c 100644
--- a/app-text/mupdf/mupdf-1.23.3.ebuild
+++ b/app-text/mupdf/mupdf-1.23.3-r1.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2023 Gentoo Authors
+# Copyright 1999-2024 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=8
@@ -23,7 +23,7 @@ REQUIRED_USE="opengl? ( javascript )"
 # bug #653298), the best way to ensure that its dependencies are present is to
 # install system's freeglut.
 RDEPEND="
-	dev-libs/gumbo
+	dev-libs/gumbo:=
 	media-libs/freetype:2
 	media-libs/harfbuzz:=[truetype]
 	media-libs/jbig2dec:=
diff --git a/app-text/mupdf/mupdf-1.23.7-r1.ebuild b/app-text/mupdf/mupdf-1.23.7-r1.ebuild
new file mode 100644
index 000000000000..355cabb0620f
--- /dev/null
+++ b/app-text/mupdf/mupdf-1.23.7-r1.ebuild
@@ -0,0 +1,165 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+# Please check upstream git regularly for relevant security-related commits
+# to backport.
+
+inherit desktop flag-o-matic toolchain-funcs xdg
+
+DESCRIPTION="A lightweight PDF viewer and toolkit written in portable C"
+HOMEPAGE="https://mupdf.com/ https://git.ghostscript.com/?p=mupdf.git"
+SRC_URI="https://mupdf.com/downloads/archive/${P}-source.tar.gz"
+S="${WORKDIR}"/${P}-source
+
+LICENSE="AGPL-3"
+SLOT="0/${PV}"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+IUSE="+javascript opengl ssl X"
+REQUIRED_USE="opengl? ( javascript )"
+
+# Although we use the bundled, patched version of freeglut in mupdf (because of
+# bug #653298), the best way to ensure that its dependencies are present is to
+# install system's freeglut.
+RDEPEND="
+	dev-libs/gumbo:=
+	media-libs/freetype:2
+	media-libs/harfbuzz:=[truetype]
+	media-libs/jbig2dec:=
+	media-libs/libpng:0=
+	>=media-libs/openjpeg-2.1:2=
+	>=media-libs/libjpeg-turbo-1.5.3-r2:0=
+	net-misc/curl
+	javascript? ( >=dev-lang/mujs-1.2.0:= )
+	opengl? ( >=media-libs/freeglut-3.0.0 )
+	ssl? ( >=dev-libs/openssl-1.1:0= )
+	sys-libs/zlib
+	X? (
+		media-libs/libglvnd[X]
+		x11-libs/libX11
+		x11-libs/libXext
+		x11-libs/libXrandr
+	)
+"
+DEPEND="${RDEPEND}
+	X? ( x11-base/xorg-proto )"
+BDEPEND="virtual/pkgconfig"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-1.15-CFLAGS.patch
+	"${FILESDIR}"/${PN}-1.19.0-Makefile.patch
+	"${FILESDIR}"/${PN}-1.21.0-add-desktop-pc-files.patch
+	"${FILESDIR}"/${PN}-1.23.3-darwin.patch
+	# See bugs #662352
+	"${FILESDIR}"/${PN}-1.23.3-openssl-x11.patch
+	# General cross fixes from Debian (refreshed)
+	"${FILESDIR}"/${PN}-1.23.3-cross-fixes.patch
+	"${FILESDIR}"/${PN}-1.21.1-fix-aliasing-violation.patch
+)
+
+src_prepare() {
+	default
+
+	use hppa && append-cflags -ffunction-sections
+
+	append-cflags "-DFZ_ENABLE_JS=$(usex javascript 1 0)"
+
+	sed -e "1iOS = Linux" \
+		-e "1iCC = $(tc-getCC)" \
+		-e "1iCXX = $(tc-getCXX)" \
+		-e "1iLD = $(tc-getLD)" \
+		-e "1iAR = $(tc-getAR)" \
+		-e "1iverbose = yes" \
+		-e "1ibuild = debug" \
+		-i Makerules || die "Failed adding build variables to Makerules in src_prepare()"
+
+	# Adjust MuPDF version in .pc file created by the
+	# mupdf-1.21.0-add-desktop-pc-files.patch file
+	sed -e "s/Version: \(.*\)/Version: ${PV}/" \
+		-i platform/debian/${PN}.pc || die "Failed substituting version in ${PN}.pc"
+}
+
+_emake() {
+	# When HAVE_OBJCOPY is yes, we end up with a lot of QA warnings.
+	#
+	# Bundled libs
+	# * General
+	# Note that USE_SYSTEM_LIBS=yes is a metaoption which will set to upstream's
+	# recommendations. It does not mean "always use system libs".
+	# See [0] below for what it means in a specific version.
+	#
+	# * freeglut
+	# We don't use system's freeglut because upstream has a special modified
+	# version of it that gives mupdf clipboard support. See bug #653298
+	#
+	# * mujs
+	# As of v1.15.0, mupdf started using symbols in mujs that were not part
+	# of any release. We then went back to using the bundled version of it.
+	# But v1.17.0 looks ok, so we'll go unbundled again. Be aware of this risk
+	# when bumping and check!
+	# See bug #685244
+	#
+	# * lmms2
+	# mupdf uses a bundled version of lcms2 [0] because Artifex have forked it [1].
+	# It is therefore not appropriate for us to unbundle it at this time.
+	#
+	# [0] https://git.ghostscript.com/?p=mupdf.git;a=blob;f=Makethird;h=c4c540fa4a075df0db85e6fdaab809099881f35a;hb=HEAD#l9
+	# [1] https://www.ghostscript.com/doc/lcms2mt/doc/WhyThisFork.txt
+	local myemakeargs=(
+		GENTOO_PV=${PV}
+		HAVE_GLUT=$(usex opengl)
+		HAVE_LIBCRYPTO=$(usex ssl)
+		HAVE_X11=$(usex X)
+		USE_SYSTEM_LIBS=yes
+		USE_SYSTEM_MUJS=$(usex javascript)
+		USE_SYSTEM_GLUT=no
+		HAVE_OBJCOPY=no
+		"$@"
+	)
+
+	emake "${myemakeargs[@]}"
+}
+
+src_compile() {
+	tc-export PKG_CONFIG
+
+	_emake XCFLAGS="-fPIC"
+}
+
+src_install() {
+	if use opengl || use X ; then
+		domenu platform/debian/${PN}.desktop
+		doicon -s scalable docs/logo/new-${PN}-icon.svg
+	else
+		rm docs/man/${PN}.1 || die "Failed to remove man page in src_install()"
+	fi
+
+	sed -i \
+		-e "1iprefix = ${ED}/usr" \
+		-e "1ilibdir = ${ED}/usr/$(get_libdir)" \
+		-e "1idocdir = ${ED}/usr/share/doc/${PF}" \
+		-i Makerules || die "Failed adding liprefix, lilibdir and lidocdir to Makerules in src_install()"
+
+	_emake install
+
+	dosym libmupdf.so.${PV} /usr/$(get_libdir)/lib${PN}.so
+
+	if use opengl ; then
+		einfo "mupdf symlink points to mupdf-gl (bug 616654)"
+		dosym ${PN}-gl /usr/bin/${PN}
+	elif use X ; then
+		einfo "mupdf symlink points to mupdf-x11 (bug 616654)"
+		dosym ${PN}-x11 /usr/bin/${PN}
+	fi
+
+	# Respect libdir and EPREFIX (bugs #734898, #911965)
+	sed -i -e "s:/lib:/$(get_libdir):" \
+		-e "s:/usr:${EPREFIX}/usr:" platform/debian/${PN}.pc \
+		|| die "Failed to sed pkgconfig file to respect libdir and EPREFIX in src_install()"
+
+	insinto /usr/$(get_libdir)/pkgconfig
+	doins platform/debian/${PN}.pc
+
+	dodoc README CHANGES CONTRIBUTORS
+}