gentoo resync : 14.07.2018

3 files changed, 107 insertions, 0 deletions

diff --git a/app-text/linuxdoc-tools/Manifest b/app-text/linuxdoc-tools/Manifest
new file mode 100644
index 000000000000..721e445382bb
--- /dev/null
+++ b/app-text/linuxdoc-tools/Manifest
@@ -0,0 +1,3 @@
+DIST linuxdoc-tools-0.9.72.tar.gz 614429 BLAKE2B 404b311c0560780bd81f021760d32e47cd6ebe8abc9aa64a181b8ce727dd0edbbd88d286cdfdcc97a51981bd0bd299563d7b1b2945e06f83ff32c7d3e56abb19 SHA512 2d522a99212dab2535786b64e0b404a9bb023d1612d8e57a628de21b5e77b104285713a98591c61a2fb2196e687b34180198ab0dfeda2b44fbbce051e9919408
+EBUILD linuxdoc-tools-0.9.72.ebuild 1777 BLAKE2B b61585eaf79a55b9acc1f4711cbaec19d421db998f091a4fb5827292bb30c5720de9ba5a300ad0cf248b509a8ec4d1a0415a4ee498edb18f49279cf673ff35cb SHA512 40632a82dc9252a4bac966174c4e87f6f1adf075fb2ef125ea07ccc5796b98e74d8823d1afff11f98e042ded4eb5b7da82a8b8c5ab052e4f7d53357b84cbf649
+MISC metadata.xml 911 BLAKE2B a78b50af9faf588a872f75b94f1278ce1ef5e16edb8c6f6c953dcc29b466be53f70a63275e5df54bd46f58d726e80f07b8cd8ae051d93f7c6ee11f0c8e63b8fe SHA512 6afd802552b700006b38a5eee516e5e1f59d0af0dff294bc2807804f8a85823ca2c5a928c0cfe2d5ef74d8c34521ecdd2a54d4ff5a1d322f17d42a6e5e6ad0f4
diff --git a/app-text/linuxdoc-tools/linuxdoc-tools-0.9.72.ebuild b/app-text/linuxdoc-tools/linuxdoc-tools-0.9.72.ebuild
new file mode 100644
index 000000000000..808897c2186f
--- /dev/null
+++ b/app-text/linuxdoc-tools/linuxdoc-tools-0.9.72.ebuild
@@ -0,0 +1,80 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+# EAPI=6 is blocked by Gentoo bugs 497038, 497052.
+EAPI=5
+
+inherit autotools epatch latex-package perl-functions sgml-catalog toolchain-funcs vcs-snapshot
+
+DESCRIPTION="A toolset for processing LinuxDoc DTD SGML files"
+HOMEPAGE="https://gitlab.com/agmartin/linuxdoc-tools"
+SRC_URI="https://gitlab.com/agmartin/${PN}/repository/archive.tar.gz?ref=v${PV} -> ${P}.tar.gz"
+
+LICENSE="GPL-3+ MIT SGMLUG"
+SLOT="0"
+KEYWORDS="amd64 ~ia64 ppc x86 ~x86-fbsd"
+IUSE="doc"
+
+RDEPEND="
+	|| ( app-text/openjade app-text/opensp )
+	app-text/sgml-common
+	dev-lang/perl:=
+	|| ( sys-apps/gawk sys-apps/mawk )
+	sys-apps/groff
+"
+DEPEND="${RDEPEND}
+	sys-devel/flex
+	doc? (
+		dev-texlive/texlive-fontsrecommended
+		virtual/latex-base
+	)
+"
+
+src_prepare() {
+	[[ ${PATCHES} ]] && epatch -p1 "${PATCHES[@]}"
+	epatch_user
+
+	# Update the build system with Gentoo paths.
+	sed -i \
+		-e "s|share/doc/${PN}|share/doc/${PF}|g" \
+		Makefile.in || die
+
+	eautoreconf
+}
+
+src_configure() {
+	perl_set_version
+	tc-export CC
+	local myeconfargs=(
+		--disable-docs
+		--with-texdir="${TEXMF}/tex/latex/${PN}"
+		--with-perllibdir="${VENDOR_ARCH}"
+		--with-installed-iso-entities
+	)
+	use doc && myeconfargs+=(--enable-docs="txt pdf html")
+
+	econf "${myeconfargs[@]}"
+}
+
+src_compile() {
+	# Prevent access violations from bitmap font files generation.
+	use doc && export VARTEXFONTS="${T}/fonts"
+	default_src_compile
+}
+
+src_install() {
+	# Override latex-package.eclass
+	default_src_install
+}
+
+sgml-catalog_cat_include "/etc/sgml/linuxdoc.cat" "/usr/share/${PN}/${PN}.catalog"
+
+pkg_postinst() {
+	latex-package_pkg_postinst
+	sgml-catalog_pkg_postinst
+}
+
+pkg_postrm() {
+	latex-package_pkg_postrm
+	sgml-catalog_pkg_postrm
+}
diff --git a/app-text/linuxdoc-tools/metadata.xml b/app-text/linuxdoc-tools/metadata.xml
new file mode 100644
index 000000000000..c7c7ce7d220b
--- /dev/null
+++ b/app-text/linuxdoc-tools/metadata.xml
@@ -0,0 +1,24 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<email>itumaykin+gentoo@gmail.com</email>
+		<name>Coacher</name>
+	</maintainer>
+	<maintainer type="project">
+		<email>proxy-maint@gentoo.org</email>
+		<name>Proxy Maintainers</name>
+	</maintainer>
+	<longdescription>
+		Linuxdoc-Tools is a small bug-fix version of SGML-Tools 1.0.9,
+		and is a toolset for processing LinuxDoc DTD SGML files.
+		This system is tailored for LinuxDoc DTD sgml files, and other DTDs
+		are not supported. If you need the tool for DocBook DTD (which is
+		now a more popular DTD than LinuxDoc in writing technical software
+		documentation), then you should check SGMLTools-Lite, OpenJade,
+		and docbook-tools.
+	</longdescription>
+	<upstream>
+		<remote-id type="gitlab">agmartin/linuxdoc-tools</remote-id>
+	</upstream>
+</pkgmetadata>