reinit the tree, so we can have metadata

1 files changed, 52 insertions, 0 deletions

diff --git a/app-text/libspectre/libspectre-0.2.7.ebuild b/app-text/libspectre/libspectre-0.2.7.ebuild
new file mode 100644
index 000000000000..7fbb9e521c29
--- /dev/null
+++ b/app-text/libspectre/libspectre-0.2.7.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=4
+inherit autotools eutils
+
+DESCRIPTION="A library for rendering Postscript documents"
+HOMEPAGE="https://www.freedesktop.org/wiki/Software/libspectre"
+SRC_URI="https://libspectre.freedesktop.org/releases/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="alpha amd64 arm hppa ia64 ~mips ppc ppc64 sparc x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~x64-solaris"
+IUSE="debug doc static-libs"
+
+RDEPEND=">=app-text/ghostscript-gpl-8.62"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	doc? ( app-doc/doxygen )"
+
+# does not actually test anything, see bug 362557
+RESTRICT="test"
+
+DOCS="NEWS README TODO"
+
+src_prepare() {
+	epatch "${FILESDIR}"/${PN}-0.2.0-interix.patch
+	has_version \>=app-text/ghostscript-gpl-9.18 \
+		&& epatch "${FILESDIR}"/${PN}-0.2.7-gs918.patch
+	eautoreconf # need new libtool for interix
+}
+
+src_configure() {
+	econf \
+		$(use_enable debug asserts) \
+		$(use_enable debug checks) \
+		$(use_enable static-libs static) \
+		--disable-test
+}
+
+src_compile() {
+	emake
+	if use doc; then
+		doxygen || die
+	fi
+}
+
+src_install() {
+	default
+	use doc && dohtml -r doc/html/*
+	find "${D}" -name '*.la' -exec rm -f {} +
+}