reinit the tree, so we can have metadata

1 files changed, 50 insertions, 0 deletions

diff --git a/app-text/libmspub/libmspub-9999.ebuild b/app-text/libmspub/libmspub-9999.ebuild
new file mode 100644
index 000000000000..83a7b70ff42b
--- /dev/null
+++ b/app-text/libmspub/libmspub-9999.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+EGIT_REPO_URI="https://anongit.freedesktop.org/git/libreoffice/libmspub.git"
+[[ ${PV} == 9999 ]] && inherit autotools git-r3
+
+DESCRIPTION="Library parsing Microsoft Publisher documents"
+HOMEPAGE="https://wiki.documentfoundation.org/DLP/Libraries/libmspub"
+[[ ${PV} == 9999 ]] || SRC_URI="https://dev-www.libreoffice.org/src/libmspub/${P}.tar.xz"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+
+# Don't move KEYWORDS on the previous line or ekeyword won't work # 399061
+[[ ${PV} == 9999 ]] || \
+KEYWORDS="~amd64 ~arm ~x86"
+
+IUSE="doc static-libs"
+
+RDEPEND="
+	dev-libs/icu:=
+	dev-libs/librevenge
+	sys-libs/zlib
+"
+DEPEND="${RDEPEND}
+	dev-libs/boost
+	sys-devel/libtool
+	virtual/pkgconfig
+	doc? ( app-doc/doxygen )
+"
+
+src_prepare() {
+	default
+	[[ -d m4 ]] || mkdir "m4"
+	[[ ${PV} == 9999 ]] && eautoreconf
+}
+
+src_configure() {
+	econf \
+		--disable-werror \
+		$(use_with doc docs) \
+		$(use_enable static-libs static)
+}
+
+src_install() {
+	default
+	find "${D}" -name '*.la' -delete || die
+}