gentoo xmass resync : 25.12.2021

1 files changed, 67 insertions, 0 deletions

diff --git a/app-portage/portage-utils/portage-utils-0.93.1.ebuild b/app-portage/portage-utils/portage-utils-0.93.1.ebuild
new file mode 100644
index 000000000000..f11ea5afcccd
--- /dev/null
+++ b/app-portage/portage-utils/portage-utils-0.93.1.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DESCRIPTION="Small and fast Portage helper tools written in C"
+HOMEPAGE="https://wiki.gentoo.org/wiki/Portage-utils"
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="nls static openmp +qmanifest +qtegrity"
+
+if [[ ${PV} == *9999 ]]; then
+	inherit git-r3 autotools
+	EGIT_REPO_URI="https://anongit.gentoo.org/git/proj/portage-utils.git"
+else
+	SRC_URI="https://dev.gentoo.org/~grobian/distfiles/${P}.tar.xz"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-cygwin ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+fi
+
+RDEPEND="
+	qmanifest? (
+		openmp? (
+			|| (
+				>=sys-devel/gcc-4.2:*[openmp]
+				sys-devel/clang-runtime:*[openmp]
+			)
+		)
+		static? (
+			app-crypt/libb2:=[static-libs]
+			dev-libs/openssl:0=[static-libs]
+			sys-libs/zlib:=[static-libs]
+			app-crypt/gpgme:=[static-libs]
+		)
+		!static? (
+			app-crypt/libb2:=
+			dev-libs/openssl:0=
+			sys-libs/zlib:=
+			app-crypt/gpgme:=
+		)
+	)
+	qtegrity? (
+		openmp? (
+			|| (
+				>=sys-devel/gcc-4.2:*[openmp]
+				sys-devel/clang-runtime:*[openmp]
+			)
+		)
+		static? (
+			dev-libs/openssl:0=[static-libs]
+		)
+		!static? (
+			dev-libs/openssl:0=
+		)
+	)
+"
+DEPEND="${RDEPEND}"
+
+src_configure() {
+	econf \
+		--disable-maintainer-mode \
+		--with-eprefix="${EPREFIX}" \
+		$(use_enable qmanifest) \
+		$(use_enable qtegrity) \
+		$(use_enable openmp) \
+		$(use_enable static)
+}