gentoo resync : 10.11.2019

1 files changed, 38 insertions, 0 deletions

diff --git a/app-misc/yq/yq-2.9.2.ebuild b/app-misc/yq/yq-2.9.2.ebuild
new file mode 100644
index 000000000000..3c4174e21d49
--- /dev/null
+++ b/app-misc/yq/yq-2.9.2.ebuild
@@ -0,0 +1,38 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python2_7 python3_{5,6,7} )
+
+inherit distutils-r1
+
+DESCRIPTION="Command-line YAML processor - jq wrapper for YAML documents"
+HOMEPAGE="https://yq.readthedocs.io/ https://github.com/kislyuk/yq/ https://pypi.org/project/yq/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="app-misc/jq
+	>=dev-python/pyyaml-3.11[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	dev-python/xmltodict[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}
+	test? (
+		dev-python/coverage[${PYTHON_USEDEP}]
+		dev-python/flake8[${PYTHON_USEDEP}]
+		dev-python/toml[${PYTHON_USEDEP}]
+		dev-python/wheel[${PYTHON_USEDEP}]
+	)"
+
+python_prepare_all() {
+	distutils-r1_python_prepare_all
+	sed -e 's:unittest.main():unittest.main(verbosity=2):' \
+		-i test/test.py || die
+}
+
+python_test() {
+	./test/test.py || die "tests failed under ${EPYTHON}"
+}