reinit the tree, so we can have metadata

1 files changed, 53 insertions, 0 deletions

diff --git a/app-misc/grc/grc-1.9.ebuild b/app-misc/grc/grc-1.9.ebuild
new file mode 100644
index 000000000000..8a0b5413f882
--- /dev/null
+++ b/app-misc/grc/grc-1.9.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python{2_7,3_{4,5}} pypy )
+
+inherit eutils python-r1
+
+DESCRIPTION="Generic Colouriser beautifies your logfiles or output of commands"
+HOMEPAGE="http://kassiopeia.juls.savba.sk/~garabik/software/grc.html"
+SRC_URI="https://github.com/garabik/grc/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE=""
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="${PYTHON_DEPS}"
+DEPEND="${RDEPEND}"
+
+PATCHES=(
+	# https://github.com/garabik/grc/pull/44
+	"${FILESDIR}"/${PN}-1.4-support-more-files.patch
+	# https://github.com/garabik/grc/pull/43
+	"${FILESDIR}"/${PN}-1.4-ipv6.patch
+	# https://github.com/garabik/grc/pull/9
+	"${FILESDIR}"/${P}-domain-match.patch
+	# https://github.com/garabik/grc/pull/45
+	"${FILESDIR}"/${P}-python3.patch
+	# https://github.com/garabik/grc/pull/46
+	"${FILESDIR}"/${P}-bash.patch
+	# https://github.com/garabik/grc/pull/47
+	"${FILESDIR}"/${P}-configure.patch
+)
+
+src_install() {
+	python_foreach_impl python_doscript grc grcat
+
+	insinto /usr/share/grc
+	doins \
+		mrsmith/conf.* \
+		conf.* \
+		grc.bashrc
+
+	insinto /etc
+	doins grc.conf
+
+	dodoc README INSTALL TODO debian/changelog CREDITS Regexp.txt
+	doman *.1
+}