gentoo (leap year) resync : 29.02.2020

1 files changed, 62 insertions, 0 deletions

diff --git a/app-misc/brewtarget/brewtarget-2.3.1-r1.ebuild b/app-misc/brewtarget/brewtarget-2.3.1-r1.ebuild
new file mode 100644
index 000000000000..03780974f84b
--- /dev/null
+++ b/app-misc/brewtarget/brewtarget-2.3.1-r1.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PLOCALES="ca cs da de el en es et eu fr gl hu it lv nb nl pl pt ru sr sv tr zh"
+inherit cmake l10n
+
+DESCRIPTION="Application to create and manage beer recipes"
+HOMEPAGE="http://www.brewtarget.org/"
+SRC_URI="https://github.com/Brewtarget/${PN}/releases/download/v${PV}/${PN}_${PV}.orig.tar.xz"
+
+LICENSE="GPL-3 WTFPL-2"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE=""
+
+BDEPEND="
+	dev-qt/linguist-tools:5
+"
+DEPEND="
+	dev-qt/qtcore:5
+	dev-qt/qtdeclarative:5
+	dev-qt/qtgui:5
+	dev-qt/qtmultimedia:5
+	dev-qt/qtnetwork:5
+	dev-qt/qtprintsupport:5
+	dev-qt/qtsql:5[sqlite]
+	dev-qt/qtsvg:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtxml:5
+"
+RDEPEND="${DEPEND}"
+
+PATCHES=(
+	"${FILESDIR}/${P}-no-qtwebkit.patch"
+	"${FILESDIR}/${P}-no-compress-docs.patch"
+)
+
+remove_locale() {
+	sed -i -e "/bt_${1}\.ts/d" CMakeLists.txt || die
+}
+
+src_prepare() {
+	cmake_src_prepare
+
+	l10n_find_plocales_changes translations bt_ .ts
+	l10n_for_each_disabled_locale_do remove_locale
+
+	# Tests are bogus, don't build them
+	sed -i -e '/Qt5Test/d' CMakeLists.txt || die
+	sed -i -e '/=Tests=/,/=Installs=/d' src/CMakeLists.txt || die
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DDOCDIR="${EPREFIX}"/usr/share/doc/${PF}
+		-DDO_RELEASE_BUILD=ON
+		-DNO_MESSING_WITH_FLAGS=ON
+	)
+	cmake_src_configure
+}