gentoo resync : 02.09.2020

1 files changed, 55 insertions, 0 deletions

diff --git a/app-misc/OpenRGB/OpenRGB-9999.ebuild b/app-misc/OpenRGB/OpenRGB-9999.ebuild
new file mode 100644
index 000000000000..f8119c80c919
--- /dev/null
+++ b/app-misc/OpenRGB/OpenRGB-9999.ebuild
@@ -0,0 +1,55 @@
+# Copyright 2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit qmake-utils udev
+
+if [[ ${PV} == *9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI=${EGIT_REPO_URI:-"https://gitlab.com/CalcProgrammer1/OpenRGB"}
+else
+	SRC_URI="https://gitlab.com/CalcProgrammer1/OpenRGB/-/archive/release_${PV}/OpenRGB-release_${PV}.tar.bz2"
+	S="${WORKDIR}/OpenRGB-release_${PV}"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+DESCRIPTION="Open source RGB lighting control that doesn't depend on manufacturer software"
+HOMEPAGE="https://gitlab.com/CalcProgrammer1/OpenRGB/"
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="udev"
+
+DEPEND="
+	dev-libs/hidapi:=
+	dev-qt/qtcore:5=
+	dev-qt/qtgui:5=
+	dev-qt/qtwidgets:5=
+	virtual/libusb:1
+"
+RDEPEND="${DEPEND}"
+BDEPEND="
+	virtual/pkgconfig
+"
+
+src_prepare() {
+	default
+	rm -rf dependencies/{hidapi,libusb}* || die
+	if [[ ${PV} != *9999* ]]; then
+		eapply "${FILESDIR}/OpenRGB-0.2-build-system.patch"
+	fi
+}
+
+src_configure() {
+	eqmake5
+}
+
+src_install() {
+	emake INSTALL_ROOT="${ED}" install
+
+	dodoc README.md OpenRGB.patch
+
+	if use udev; then
+		udev_dorules 60-openrgb.rules
+	fi
+}