gentoo resync : 15.11.2017

2 files changed, 114 insertions, 0 deletions

diff --git a/app-emacs/emacs-common-gentoo/Manifest b/app-emacs/emacs-common-gentoo/Manifest
index 705cc1385db7..1731c5876565 100644
--- a/app-emacs/emacs-common-gentoo/Manifest
+++ b/app-emacs/emacs-common-gentoo/Manifest
@@ -1,4 +1,5 @@
 DIST emacs-common-gentoo-1.6.tar.xz 61224 SHA256 7f43a198068abba9e0735f7dee3bb642dd1531e33563ded364751319bea8f9ec SHA512 a7daed2241d778ab283482ecc016801e25084eed10fcbbc50e187d5f842df5a0d278a77f94ae950b086c8651e8ca1a18f89c11dffdde9cf9168755288aae926a WHIRLPOOL 7112026dda683d6282807181e7a6e1d666c90df0858b63ae704db05b40ff59b10ab984dd066eeb91fc670cff71eb9bc94cac7b19571409ac166d53a6cec16e39
+EBUILD emacs-common-gentoo-1.6-r1.ebuild 3150 SHA256 fcc65caf77a292ac8ea7701f96fcdf2bbe493fcb5dcf0f4f8b7705debe9d3cbf SHA512 51a7e6afa09eee4f1b16c53117da37ff63512dea99506a412fb91a862002a06f872c1a18ba0d7451a931b3388ccd62e1082dcb763a1f27ce9e52e3fd97bfaaec WHIRLPOOL 6a5357ec5c4f0385ebc5eb44c04ecc859c61b9ec82879037f1f41a30fe6e1e15e6bab5101ff642b4d9fd99219b114a7cbd4ac3a861c3b8e064a712080fe06263
 EBUILD emacs-common-gentoo-1.6.ebuild 3150 SHA256 0cd7c62de7eaf97f05ad7dfbc412eb42e1ff9bfcd8aa838eaba409864d84747c SHA512 690be3a0a5daf9ba2d812e36db2be905c53d292e4cc9f8cefb9d31b03e49961b68603ee8ae1a3cb4e230697825dd2c3f40b3e2ab9c92f21f6a1984b34e4d1af1 WHIRLPOOL 5f18948c13446599093bb5b7319b00f2be7dc1e6aa8a8b99da9a7ac7247154573df96472f41c5452205baabc426cdf839c0fad542b166fa65bf733e6f7305fa2
 MISC ChangeLog 3168 SHA256 49913fea870769b31de205d1ec9ab96e78d61805404b63ca5dcdc391bc46fcb3 SHA512 589569d7a648f1375cbb4aaebc525f8a9db0b3770fa04b212163a85ca68ec23f96da61574078b020aff4450840f8567df1d9654c888b5915753deed14fe65c0a WHIRLPOOL 4d20521431a504c5b8dba2742f70d3c6e355aded97f26ee5c433f68bb0392829d3e494379059251ca20b3775c44088b54571ea8a5471730cf7f9f8011857e221
 MISC ChangeLog-2015 19074 SHA256 6625951d39d971c18ce59f0529cae815ee0ab1a98f21d3e7f8e8f783cab79bde SHA512 bfb7e120b4e670048c0ddc7680c6ae139bb4023442daff3f660e416b87ac8b4793164c7a1037224f9be277712e04708c462916d021e74fe9be41f0eb4ff523aa WHIRLPOOL 1fe9060da48be27afe170f99b77b47377913064b83e1943cdbba863c81f67bb22e769cd8af7836c2d57a5223e76745736f5773d780c861d826779703b15da1b5
diff --git a/app-emacs/emacs-common-gentoo/emacs-common-gentoo-1.6-r1.ebuild b/app-emacs/emacs-common-gentoo/emacs-common-gentoo-1.6-r1.ebuild
new file mode 100644
index 000000000000..d9f2fb9b4503
--- /dev/null
+++ b/app-emacs/emacs-common-gentoo/emacs-common-gentoo-1.6-r1.ebuild
@@ -0,0 +1,113 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit elisp-common eutils xdg-utils gnome2-utils readme.gentoo-r1 user
+
+DESCRIPTION="Common files needed by all GNU Emacs versions"
+HOMEPAGE="https://wiki.gentoo.org/wiki/Project:Emacs"
+SRC_URI="https://dev.gentoo.org/~ulm/emacs/${P}.tar.xz"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x86-solaris"
+IUSE="games X"
+
+PDEPEND="virtual/emacs"
+
+pkg_setup() {
+	use games && enewgroup gamestat 36
+}
+
+src_install() {
+	insinto "${SITELISP}"
+	doins subdirs.el
+	newins site-gentoo.el{,.orig}
+
+	keepdir /etc/emacs
+	insinto /etc/emacs
+	doins site-start.el
+
+	if use games; then
+		keepdir /var/games/emacs
+		fowners 0:gamestat /var/games/emacs
+		fperms g+w /var/games/emacs
+	fi
+
+	if use X; then
+		local i
+		domenu emacs.desktop emacsclient.desktop || die
+
+		pushd icons || die
+		newicon sink.png emacs-sink.png
+		newicon emacs25_48.png emacs.png
+		for i in 16 24 32 48 128; do
+			[[ ${i} -le 48 ]] && newicon -s ${i} emacs22_${i}.png emacs22.png
+			newicon -s ${i} emacs23_${i}.png emacs23.png
+			newicon -s ${i} emacs25_${i}.png emacs.png
+		done
+		doicon -s scalable emacs23.svg
+		newicon -s scalable emacs25.svg emacs.svg
+		popd
+
+		gnome2_icon_savelist
+	fi
+
+	DOC_CONTENTS="All site initialisation for Gentoo-installed packages is
+		added to ${SITELISP}/site-gentoo.el. In order for this site
+		initialisation to be loaded for all users automatically, a default
+		site startup file /etc/emacs/site-start.el is installed. You are
+		responsible for maintenance of this file.
+		\n\nAlternatively, individual users can add the following command:
+		\n\n(require 'site-gentoo)
+		\n\nto their ~/.emacs initialisation files, or, for greater
+		flexibility, users may load single package-specific initialisation
+		files from the ${SITELISP}/site-gentoo.d/ directory."
+	readme.gentoo_create_doc
+}
+
+pkg_preinst() {
+	# make sure that site-gentoo.el exists since site-start.el requires it
+	if [[ ! -f ${ED}${SITELISP}/site-gentoo.el ]]; then		#554518
+		mv "${ED}${SITELISP}"/site-gentoo.el{.orig,} || die
+	fi
+	if [[ -d ${EROOT}${SITELISP} ]]; then
+		elisp-site-regen
+		cp "${EROOT}${SITELISP}/site-gentoo.el" "${ED}${SITELISP}/" || die
+	fi
+
+	if use games; then
+		local f
+		for f in /var/games/emacs/{snake,tetris}-scores; do
+			if [[ -e ${EROOT}${f} ]]; then
+				cp "${EROOT}${f}" "${ED}${f}" || die
+			fi
+			touch "${ED}${f}" || die
+			chgrp gamestat "${ED}${f}" || die
+			chmod g+w "${ED}${f}" || die
+		done
+
+		if has 1.4-r1 ${REPLACING_VERSIONS} \
+				&& [[ -d ${EROOT}/var/games/emacs ]]; then
+			elog "Updating owner and permissions of score file directory."
+			chown 0:gamestat "${EROOT}"/var/games/emacs || die
+			chmod 775 "${EROOT}"/var/games/emacs || die
+		fi
+	fi
+}
+
+pkg_postinst() {
+	if use X; then
+		xdg_desktop_database_update
+		gnome2_icon_cache_update
+	fi
+	readme.gentoo_print_elog
+}
+
+pkg_postrm() {
+	if use X; then
+		xdg_desktop_database_update
+		gnome2_icon_cache_update
+	fi
+}