reinit the tree, so we can have metadata

1 files changed, 40 insertions, 0 deletions

diff --git a/app-emacs/haskell-mode/haskell-mode-2.9.1.ebuild b/app-emacs/haskell-mode/haskell-mode-2.9.1.ebuild
new file mode 100644
index 000000000000..c64e1eed6fa7
--- /dev/null
+++ b/app-emacs/haskell-mode/haskell-mode-2.9.1.ebuild
@@ -0,0 +1,40 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=5
+
+inherit elisp
+
+MY_PV=${PV//./_}
+DESCRIPTION="Mode for editing (and running) Haskell programs in Emacs"
+HOMEPAGE="http://projects.haskell.org/haskellmode-emacs/
+	http://www.haskell.org/haskellwiki/Emacs#Haskell-mode"
+SRC_URI="https://github.com/haskell/${PN}/archive/${MY_PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="amd64 ppc ~sparc x86"
+IUSE=""
+
+S="${WORKDIR}/${PN}-${MY_PV}"
+DOCS="NEWS README.md *.hs examples/init.el"
+SITEFILE="50${PN}-gentoo.el"
+
+src_prepare() {
+	# We install the logo in SITEETC, not in SITELISP
+	# https://github.com/haskell/haskell-mode/issues/102
+	sed -i -e "/defconst haskell-process-logo/{n;" \
+		-e "s:(.*\"\\(.*\\)\".*):\"${SITEETC}/${PN}/\\1\":}" \
+		haskell-process.el || die
+}
+
+src_compile() {
+	elisp-make-autoload-file haskell-site-file.el || die
+	elisp-compile *.el || die
+}
+
+src_install() {
+	elisp_src_install
+	insinto "${SITEETC}/${PN}"
+	doins logo.svg
+}