gentoo Easter resync : 12.04.2020

1 files changed, 37 insertions, 0 deletions

diff --git a/app-crypt/jitterentropy/jitterentropy-2.2.0.ebuild b/app-crypt/jitterentropy/jitterentropy-2.2.0.ebuild
new file mode 100644
index 000000000000..f4a146544007
--- /dev/null
+++ b/app-crypt/jitterentropy/jitterentropy-2.2.0.ebuild
@@ -0,0 +1,37 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit toolchain-funcs
+
+DESCRIPTION="Hardware RNG based on CPU timing jitter"
+HOMEPAGE="https://github.com/smuellerDD/jitterentropy-library"
+SRC_URI="https://github.com/smuellerDD/jitterentropy-library/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~mips ~ppc ~ppc64 ~riscv ~x86"
+IUSE="static-libs"
+
+S="${WORKDIR}/${PN}-library-${PV}"
+
+src_prepare() {
+	default
+
+	# Disable man page compression on install
+	sed -e '/\tgzip.*man/ d' -i Makefile || die
+	# Let the package manager handle stripping
+	sed -e '/\tinstall.*-s / s/-s //g' -i Makefile || die
+}
+
+src_compile() {
+	emake AR="$(tc-getAR)" CC="$(tc-getCC)"
+}
+
+src_install() {
+	emake PREFIX="${EPREFIX}/usr" \
+		  LIBDIR="$(get_libdir)" \
+		  DESTDIR="${D}" install
+	use static-libs && dolib.a lib${PN}.a
+}