gentoo resync : 06.08.2019

1 files changed, 37 insertions, 0 deletions

diff --git a/app-admin/emacs-updater/emacs-updater-1.16.ebuild b/app-admin/emacs-updater/emacs-updater-1.16.ebuild
new file mode 100644
index 000000000000..ef79c178430b
--- /dev/null
+++ b/app-admin/emacs-updater/emacs-updater-1.16.ebuild
@@ -0,0 +1,37 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DESCRIPTION="Rebuild Emacs packages"
+HOMEPAGE="https://wiki.gentoo.org/wiki/Project:Emacs"
+SRC_URI="https://dev.gentoo.org/~ulm/emacs/${P}.tar.xz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos"
+
+DEPEND="|| ( sys-apps/util-linux app-misc/getopt )"
+RDEPEND="${DEPEND}
+	>=app-portage/portage-utils-0.3
+	virtual/emacs"
+
+src_prepare() {
+	default
+
+	if ! has_version sys-apps/util-linux; then
+		# BSD ships a dumb getopt(1), so use getopt-long instead
+		sed -i -e '/^GETOPT=/s/getopt/&-long/' emacs-updater || die
+	fi
+
+	if [[ -n ${EPREFIX} ]]; then
+		sed -i -e "1s:/:${EPREFIX%/}/:" \
+			-e "s:^\([[:upper:]]*=\)/:\1${EPREFIX%/}/:" \
+			emacs-updater || die
+	fi
+}
+
+src_install() {
+	dosbin emacs-updater
+	doman emacs-updater.8
+}